start tok64 d64-VNa1BU
0 REM"{delete*6}-*-*-*-*-*- basic directory -*-*-*-*-*-{141*3}mr.p. of sw 1991-03-23
1 DIMn$(255):OPEN15,8,15
2 POKE53280,15:POKE53281,15:de$="{black}{home}{down}directory entries :{space*3}{left*3}
3 bl$="{black}{home}{down*2}blocks left{space*7}:{space*4}{left*4}
10 PRINT"{black}{clear}insert disk{.*4} press any key{.*3}
11 PRINT"{home}{down*10}{white}basic-dir (c) 1991 mr.p.":POKE198,.:WAIT198,1
20 PRINT"{black}{clear}please wait{.*4} reading directory{.*3}
21 PRINT"{home}{down*10}{white}basic-dir (c) 1991 mr.p.":GOSUB1000
30 PRINT"{black}{clear}disk name : -{reverse on}"n$(.)"{reverse off}-
40 PRINT"# of free blocks :"fr;
41 IF664-z<>frTHENPRINT"{home}{black}warning don't validate {reverse on}"n$(.):PRINT"{home}{down}";
50 PRINT:PRINT"# of files{space*7}:"fl:IFfl=.THEN140
60 PRINT"file name"TAB(20)"blocks
70 PRINT"{cm y*9}"TAB(20)"{cm y*6}
80 r=4:FORi=1TOfl
90 PRINTMID$(n$(i),4)TAB(20)LEFT$(n$(i),3)
100 r=r+1:IFr<>20THENNEXT:GOTO140
110 PRINT"press a key{up}":POKE198,.:WAIT198,1:PRINT"{space*11}"
120 PRINT"{home}{down*5}";:FORx=5TO20:PRINT"{space*16}"TAB(20)"{space*3}":NEXT
130 PRINT"{home}{down*5}";:r=4:NEXT
140 PRINT"press a key{up}":POKE198,.:WAIT198,1:PRINT"{space*11}"
150 CLOSE15:PRINT"{black}{clear}any more diskettes{?*3} press y/n{.*3}
160 PRINT"{home}{down*10}{white}basic-dir (c) 1991 mr.p.":POKE198,.:WAIT198,1
170 GETa$:IFa$<>"y"ANDa$<>"n"THEN150
180 IFa$="y"THENRUN
190 POKE53280,14:POKE53281,6:PRINT"{light blue}{clear}bye bye{.*3} restart with {reverse on}run{reverse off}";:END
1000 q=-1:OPEN1,8,.,"$":GOSUB9998:POKE781,1:GET#1,a$,a$:e$=CHR$(.)
1001 GET#1,a$,a$,h$,l$:IFstTHENCLOSE1:GOTO9999
1002 l=ASC(h$+e$)+256*ASC(l$+e$):IFq>.THENPRINTde$q:PRINTbl$664-z
1003 GET#1,a$:IFa$="b"THEN1011
1004 IFa$<>CHR$(34)THEN1003
1005 n$=""
1006 GET#1,a$:IFa$<>CHR$(34)THENn$=n$+a$:GOTO1006
1007 GET#1,a$:IFa$THEN1007
1008 q=q+1:n$(q)=MID$(STR$(1000+l),3)+n$:IFl=.ANDq>.THENq=q-1:GOTO1001
1009 IFqTHENz=z+l:GOTO1001
1010 n$(q)=MID$(n$(q),4):GOTO1001
1011 fr=l:fl=q:CLOSE1:RETURN
9998 INPUT#15,en$,em$,et$,es$:IFVAL(en$)<2THENRETURN
9999 PRINT"{black}{home}{down*2}disk error:"en$","em$","et$","es$:CLOSE15
stop tok64
(bastext 1.0)