start tok64 d64-J6QeOf
0 REM"{delete*6}{-*40}
1 REM"{delete*6} ** digital klocka **
2 REM"{delete*6}
3 REM"{delete*6} (c) 1990 mr.p. of softwolves
4 REM"{delete*6}
5 REM"{delete*6}{-*40}
6 REM"{delete*6}
7 REM"{delete*6}
8 REM"{delete*6}save band: goto1{0*3}. save disk: goto2{0*3}
9 REM"{delete*6}
10 FORl=679TO730:READa:POKEl,a:NEXT:SYS679:POKE52,128:POKE56,128
11 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
12 POKE648,136:POKE53272,32:PRINT"{142}"
13 DATA120,165,1,41,251,133,1,169,,133,251,169,208,133,252,169,,133,253,169
14 DATA128,133,254,160,,177,251,145,253,200,192,,208,247,230,252,230,254,165
15 DATA252,201,216,208,237,165,1,9,4,133,1,88,96
16 FORi=27TO30:FORj=.TO7:READs:POKE32768+i*8+j,s:POKE33792+i*8+j,255-s:NEXTj,i
17 DATA24,24,24,24,24,,,
18 DATA,,,24,24,24,24,24
19 DATA,,,248,248,,,
20 DATA,,,31,31,,,
21 POKE53280,0:POKE53281,0
22 INPUT"satt tid (hhmmss) return=ingen andring{space*2}";ti$
23 DIMs$(16),si$(19)
24 s$(0)="{white}{right}{reverse on}{sh pound}{space*2}{cm asterisk}{down}{left*4}{reverse off}{cm asterisk}{reverse on}{space*2}{reverse off}{sh pound}
25 s$(1)="{down*2}{white}{reverse on}{sh pound}{cm asterisk}{down}{left*2}{space*2}{down}{left*2}{space*2}{down}{left*2}{reverse off}{cm asterisk}{sh pound}
26 s$(2)="{down*6}"+s$(0)
27 s$(3)="{down*6}"+s$(1)
28 s$(4)="{down*6}"+s$(2)
29 s$(5)="{right*4}"+s$(3)
30 s$(6)="{right*4}"+s$(1)
31 REM 0123456 segm.
32 DATA1101111 :REM 0         00
33 DATA0000011 :REM 1        1  6
34 DATA1011101 :REM 2        1  6
35 DATA1010111 :REM 3         22
36 DATA0110011 :REM 4        3  5
37 DATA1110110 :REM 5        3  5
38 DATA1111110 :REM 6         44
39 DATA1000011 :REM 7
40 DATA1111111 :REM 8
41 DATA1110111 :REM 9
42 s$(10)="{right}{dark gray}N{cm y*2}M{down}{left*4}M{cm p*2}N"
43 s$(11)="{down*2}{dark gray}NM{down}{left*2}{cm h}{cm n}{down}{left*2}{cm h}{cm n}{down}{left*2}MN"
44 s$(12)="{down*6}"+s$(10)
45 s$(13)="{down*6}"+s$(11)
46 s$(14)="{down*6}"+s$(12)
47 s$(15)="{right*4}"+s$(13)
48 s$(16)="{right*4}"+s$(11)
49 REM las siffror
50 FORi=.TO9:READsi$(i):NEXT
51 REM sekunder
52 si$(10)="{cm a}{sh asterisk}{cm s}{down}{left*3}{sh -} {sh -}{down}{left*3}{sh -} {sh -}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm z}{sh asterisk}{cm x}
53 si$(11)="{space*2}{pound}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}[
54 si$(12)="^{sh asterisk}{cm s}{down}{left*3}{space*2}{sh -}{down}{left*3}{cm a}{sh asterisk}{cm x}{down}{left*3}{sh -}{space*2}{down}{left*3}{cm z}{sh asterisk}]
55 si$(13)="^{sh asterisk}{cm s}{down}{left*3}{space*2}{sh -}{down}{left*3} ^{cm w}{down}{left*3}{space*2}{sh -}{down}{left*3}^{sh asterisk}{cm x}
56 si$(14)="{pound} {pound}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm z}{sh asterisk}{cm w}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}[
57 si$(15)="{cm a}{sh asterisk}]{down}{left*3}{sh -}{space*2}{down}{left*3}{cm z}{sh asterisk}{cm s}{down}{left*3}{space*2}{sh -}{down}{left*3}^{sh asterisk}{cm x}
58 si$(16)="{cm a}{sh asterisk}]{down}{left*3}{sh -}{space*2}{down}{left*3}{cm q}{sh asterisk}{cm s}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm z}{sh asterisk}{cm x}
59 si$(17)="^{sh asterisk}{cm s}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}{sh -}{down}{left*3}{space*2}[
60 si$(18)="{cm a}{sh asterisk}{cm s}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm q}{sh asterisk}{cm w}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm z}{sh asterisk}{cm x}
61 si$(19)="{cm a}{sh asterisk}{cm s}{down}{left*3}{sh -} {sh -}{down}{left*3}{cm z}{sh asterisk}{cm w}{down}{left*3}{space*2}{sh -}{down}{left*3}^{sh asterisk}{cm x}
62 REM siffrors plac.
63 DATA"{home}","{home}{right*8}","{home}{right*19}","{home}{right*27}"
64 DATA"{home}{down*17}{right*8}{light gray}"
65 REM las plac.
66 FORi=1TO5:READp$(i):NEXT
67 REM tid
68 PRINT"{clear}"
69 FORi=1TO4:t=ASC(MID$(ti$,i))-48
70 FORj=1TO7
71 s=1-VAL(MID$(si$(t),j,1)):PRINTp$(i)s$(j-1+s*10)
72 NEXT
73 NEXT
74 t1=ASC(MID$(ti$,5))-38:t2=ASC(RIGHT$(ti$,1))-38:PRINT"{home}";
75 IFz=.THENIFt1=10ANDt2=10THENz=-1:PRINTp$((5)):GOTO69
76 PRINTp$(5)si$(t1)"{up*4}"si$(t2):z=.:GOTO74
1000 PRINT"save band":SAVE"digitalklocka":END
2000 PRINT"save disk":SAVE"digitalklocka",8:END
stop tok64
(bastext 1.0)