start tok64 d64-Z8VjYV
0 REM"{delete*6}****** character converter 1.02 ******
1 REM"{delete*6}**************************************
10 POKE52,128:POKE56,128
12 PRINT"{clear}character converter 1.02 f{pound}r character{space*2}master 3.10":GOTO60000
20 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
30 POKE648,136:POKE53272,32:PRINTCHR$(142):PRINT"{clear}"
40 ad=32768
50 READa$:IFa$="x"THENGOTO500
60 FORi=1TOLEN(a$)STEP2
70 h=ASC(MID$(a$,i))-64:l=ASC(MID$(a$,i+1))-64:b=h*16+l
80 POKEad,b:POKEad+1024,255-b:ad=ad+1
90 NEXT:GOTO50
100 REM--h[r blir det datarader--
500 PRINT"{clear}h[r b{pound}rjar ditt eget program{.*4}":STOP
60000 ad=32768:INPUT"filnamn";fi$:fi$=LEFT$(fi$,12)+".fnt"
60010 INPUT"enhet 1/8";en:IFen=1THENOPEN1,1,.,fi$:GOTO60030
60020 OPEN1,8,2,fi$+",s,r"
60030 INPUT#1,a$
60040 IFa$="theend"THEN60100
60050 FORi=1TOLEN(a$)STEP2
60060 h=ASC(MID$(a$,i))-64:l=ASC(MID$(a$,i+1))-64:b=h*16+l
60070 POKEad,b:POKEad+1024,255-b:ad=ad+1
60080 NEXT
60090 GOTO60030
60100 CLOSE1
60110 a=32768:r=100
60120 PRINT"{clear}{down*2}"r"data";
60130 b=PEEK(a):h=INT(b/16):l=b-h*16:PRINTCHR$(h+64)CHR$(l+64);
60140 a=a+1:IFa>33791THEN60180
60150 IFPOS(.)<75THEN60130
60160 PRINT"{down}60110a="a":r="r+10
60170 PRINT"run60110{home}";:GOTO60190
60180 PRINT"{down}"r+10"datax":PRINT"run60200{home}";
60190 POKE198,3:POKE631,13:POKE632,13:POKE633,13:END
60200 PRINT"{clear}{down*2}0{down}1{down}12{down}run60250{home}";
60210 POKE198,4:POKE631,13:POKE632,13:POKE633,13:POKE634,13
60220 END
60250 r=60000
60260 PRINT"{clear}{down*2}60250r="r+50:FORi=.TO40STEP10:PRINTi+r:NEXT:FORi=.TO6:POKE631+i,13:NEXT
60270 PRINT"run60250{home}";:POKE198,7:END
stop tok64
(bastext 1.0)