start tok64 d64-0m9Gn9
0 REM                                   ****************************************programlas v1.4 (c) mr.p. 1990/1991     1990-03-24,-08-03,-04,-12-11,1991-02-20 ****************************************
20 POKE56,64:CLR:POKE53280,6:POKE53281,6:PRINT"{white}{clear}{down}{right}var god vanta":DIMb$(255),k$(255):FORi=1TO255:b$(i)=CHR$(i):k$(i)=CHR$(i):NEXT:FORi=128TO232:READb$(i):NEXT
50 READz,k$:IFz>.THENk$(z)=k$:GOTO50
60 FORi=52992TO53020:READa:POKEi,a:NEXT
70 PRINT"{clear}{down}{right}spola kasseten ratt. tryck sedan pa{space*4}{down}{right}nagon tangent.":POKE198,.:WAIT198,1:SYS52992
100 INPUT"{clear}{down}{right}printer? j{left*3}";d$:PRINT"{clear}";:IFd$="j"THENPRINT"v[nta":OPEN2,4:CMD2:POKE53280,.:POKE53281,.:POKE646,11:PRINT"programnamn: "CHR$(34);:FORi=1TO16:PRINTCHR$(PEEK(832+i));:NEXT:PRINTCHR$(34)
110 ad=16386:sl=PEEK(16384)+PEEK(16385)*256
120 ad=ad+2
130 REM radnummer *********************
140 r=PEEK(ad)+256*PEEK(ad+1):ad=ad+2
150 IFad<=slTHEN190
160 IFd$="j"THENPRINT"listningen [r gjord med programlas 1.4 (c) mr.p. & the softwolves":PRINT#2:CLOSE2
170 POKE198,.:INPUT"{down}{right}fler program? n{left*3}";a$:IFa$="j"THEN70
180 POKE53280,14:POKE53281,6:POKE646,14:PRINT"{clear}";:END
190 r$=STR$(r):PRINTr$" ";
210 x=PEEK(ad):y=PEEK(ad+1):ad=ad+1:s$=b$(x):IFx=34THEN290
230 ONx+1GOTO250:PRINTs$;:GOTO210
250 REM radslut ***********************
260 PRINT:IFd$<>"j"THENPOKE198,.:WAIT198,1
270 GOTO120
290 REM " *****************************
300 PRINTCHR$(34);
310 x=PEEK(ad):y=PEEK(ad+1):z=PEEK(ad+2):ad=ad+1:s$=k$(x)
320 ONx+1GOTO250:IF(x=yAND(LEN(s$)>1ORx=32))OR(x=yANDx=z)GOTO380
340 IFLEN(s$)>1THENPRINT"<"s$">";:GOTO360
350 PRINTs$;
360 ON2+(x=34)GOTO210,310
380 c=.:IFx>47ANDx<58THEN350
390 c=c+1:y=PEEK(ad+c):IFx=yTHEN390
400 IFx=32THENs$="spaces"
410 PRINT"<"+MID$(STR$(c+1),2)+" "+s$+">";:ad=ad+c:GOTO360
420 REM basic
430 DATAend,for,next,data,input#,input,dim,read,let,goto,run,if,restore,gosub,return,rem,stop,on,wait,load,save,verify,def,poke,print#,print,cont,list,clr,cmd,sys,open,close,get,new,tab(,to,fn,spc(,then,not,step,+,-,*,/,{^},and,or,>,=,<,sgn,int,abs,usr
460 DATAfre,pos,sqr,rnd,log,exp,cos,sin,tan,atn,peek,len,str$,val,asc,chr$,left$,right$,mid$,go
470 REM tfc3
471 DATAoff,auto,del,renum,help,find,old,dload,dverify,dsave,append,dappend,dos,kill,mon,pdir,plist,bar,desktop,dump,array,mem,trace,replace,order,pack,unpack,mread,mwrite
480 REM specialtecken
490 DATA5,white,8,ctrl/h,9,ctrl/i,14,ctrl/n,17,down,18,rvs on,19,home,20,delete
500 DATA28,red,29,right,30,green,31,blue,129,orange,133,f1,134,f3,135,f5
510 DATA136,f7,137,f2,138,f4,139,f6,140,f8,142,uppercase,144,black,145,up
520 DATA146,rvs off,147,clear,148,insert,149,brown,150,lt red,151,grey 1
530 DATA152,grey 2,153,lt green,154,lt blue,155,grey 3,156,purple,157,left
540 DATA158,yellow,159,cyan,160,sh space,13,return,141,sh return
550 DATA161,cm k,162,cm i,163,cm t,165,cm g,167,cm m,170,cm m,171,cm q,172,cm d
560 DATA173,cm z,174,cm s,175,cm p,176,cm a,177,cm e,178,cm r,179,cm w,180,cm h
570 DATA181,cm j,182,cm l,183,cm y,184,cm u,185,cm o,187,cm f,188,cm c,189,cm x
580 DATA190,cm v,191,cm b,255,pi,164,cm @
590 DATA193,sh a,194,sh b,195,sh c,196,sh d,197,sh e,198,sh f,199,sh g,200,sh h
600 DATA201,sh i,202,sh j,203,sh k,204,sh l,205,sh m,206,sh n,207,sh o,208,sh p
610 DATA209,sh q,210,sh r,211,sh s,212,sh t,213,sh u,214,sh v,215,sh w,216,sh x
620 DATA217,sh y,218,sh z,186,sh @
999 DATA0,
1000 DATA169,1,170,160,,32,186,255,169,,32,189,255,169,,162,2,160,64,32,213,255,142,,64,140,1,64,96
stop tok64
(bastext 1.0)