start tok64 d64-zgEQnU
100 ba= :s$=MID$(STR$(ba),2):REM            ba(ndnummer)
103 POKE53280,0:POKE53281,0
106 PRINT"{green}{clear}{reverse on}kassettspolare
109 PRINT"{down}band{yellow}"ba"{green}sida a/b
112 PRINT"{space*12}{white}{cm t}";:s=1
115 GETa$:IFa$="{right}"ANDs=1THENPRINT"{left}{space*2}{cm t}";:s=2
118 IFa$="{left}"ANDs=2THENPRINTCHR$(20)"{left*2}{cm t}";:s=1
121 IFa$<>CHR$(13)THEN115
124 t$=CHR$(64+s):s$=s$+t$
127 PRINT"{green}{clear}{reverse on}kassettspolare
130 PRINT"{down}band{yellow}"ba"{green}sida {yellow}"t$
133 READx$:IFx$<>s$+"."THENGOTO133
136 DIMp$(250),p(250)
139 x=1
142 READp$(x),p(x):IFp$(x)<>"slut"THENx=x+1:GOTO142
145 x=x-1
148 pt=1:u1=-100:d1=-100
151 dw=pt-6:up=pt+6:IFdw<1THENdw=0:up=12:GOTO157
154 IFup>xTHENup=x+1:dw=x-11
157 IFup<>u1ANDdw<>d1THEN169
160 PRINT"{home}{down*6} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {down}{left} {green}
163 PRINTLEFT$("{home}{down*16}",7-dw+pt)">
166 u1=up:d1=dw:GOTO214
169 PRINT"{home}{down*3}";:IFdw>1THENPRINT"{green}NM{down}{left*2}{cm y*2}{up} mer NM{down}{left*2}{cm y*2}":GOTO175
172 PRINT"{space*10}{141}{space*10}"
175 PRINT"{yellow} nr{space*3}{green}namn"TAB(35)"{cyan}varv
178 FORi=dwTOup:PRINT" {right*4}{space*33}{up}
181 IFi=ptTHENPRINT"{green}>{left}";
184 IFi=.ORi=x+1THENPRINT" {yellow}{x*3}){space*2}{pink}antal program:"x"{left}.":GOTO199
187 IFi<1ORi>xTHENPRINT" {yellow}{x*3})":GOTO199
190 PRINT"{yellow}{right}"MID$(STR$(1000+i),3)"){right}{green} "p$(i)" ";
193 IFPOS(.)<35THENPRINTTAB(35)"{cyan}"MID$(STR$(1000+p(i)),3):GOTO199
196 PRINT
199 NEXT:IFup<xTHENPRINT"{green}{cm p*2}{down}{left*2}MN mer MN{up}{left*2}{cm p*2}{down}":GOTO205
202 PRINT"{space*10}{141}{space*10}"
205 PRINT"{down}{blue}cursor upp/ner - flytta pekare ett steg
208 PRINT"+/-{space*12}- flytta pekare tio steg
211 PRINT"return{space*9}- spolar fram bandet";:d1=dw:u1=up
214 GETa$:IFa$="{up}"THENpt=pt-1-(pt=1)
217 IFa$="-"THENpt=pt-10:IFpt<1THENpt=1
220 IFa$="+"THENpt=pt+10:IFpt>xTHENpt=x
223 IFa$="{down}"THENpt=pt+1+(pt=x)
226 IFa$=""THEN214
229 IFa$<>CHR$(13)THEN151
232 PRINT"{green}{clear}{reverse on}kassettspolare":x=p(pt)
235 PRINT"{down}band{yellow}"ba"{green}sida {yellow}"t$" {green}varv{yellow}"x:PRINT"{green}program: {yellow}"p$(pt)
238 PRINT"{down}{cyan}press ffwd
241 IFPEEK(1)<>7THEN241
244 ti$="{0*6}":PRINT"{up}{space*10}"
247 c=INT(ti/14.7525)+1+2*INT(x/100+.5)
250 IFc<xTHEN247
253 POKE1,39:POKE192,7:POKE1,39:POKE192,7
256 PRINT"{up}{cyan}press stop
259 IFPEEK(1)=39THEN259
262 POKE53280,14:POKE53281,6:PRINT"{light blue}{clear}";:END
500 REM--------------------------------
503 REM datasatser:
506 REM header: data (bandnr)(sida).
509 REM ex.: data 2a.
512 REM program: data (namn),(varv)
515 REM ex.: data bombo,397
518 REM avslutning:
521 REM data slut,
524 REM---------------------------------
stop tok64
(bastext 1.0)