start tok64 d64-YQuzhK
60000 REM"{141}{up}{reverse on} data line maker deluxe {reverse off} (c) 1991 mr.p. this is a public domain.
60010 POKE53280,11:POKE53281,11:PRINT"{green}{clear}{down}{right}data line maker deluxe (c) mr.p.
60020 PRINT"{home}{down*2}{right}{yellow}{cm y*32}
60030 INPUT"{yellow}{home}{down*4}{right}please enter start address{space*8}{left*7}";sa
60040 IFsa<.ORsa>65535THEN60030
60050 INPUT"{yellow}{home}{down*6}{right}please enter ending address{space*8}{left*7}";ea
60060 IFea<saORea>65535THEN60050
60070 INPUT"{yellow}{home}{down*8}{right}please enter starting line #{space*8}{left*7}";sl
60080 IFsl<.ORsl>50000THEN60070
60090 INPUT"{yellow}{home}{down*10}{right}please enter line # step{space*8}{left*7}";ls
60100 IFls<1ORls>50THEN60090
60110 INPUT"{white}{home}{down*13}{right}is this correct ? no{left*4}";c$
60120 IFc$="no"THEN60030
60140 PRINT"{light gray}{clear}{down*2}"sl"fori="MID$(STR$(sa),2)"to"MID$(STR$(ea),2)":readx:";
60150 PRINT"c=c+x:pokei,x:next
60160 PRINTsl+ls"?"CHR$(34)"{clear}{down*2}"sl+ls"ifc-"CHR$(34)"mid$(str$(c),2)"CHR$(34);
60170 PRINT"thenstop{home}"CHR$(34)";:pO631,13:pO198,1:end
60180 PRINT"60200sa="sa":ea="ea":sl="sl+ls*2":ls="ls:PRINT"goto60200":GOTO63000
60200 REM this line will be overwritten
60210 PRINT"{clear}{down*2}"sl"data";:sa=sa-1:IFsa=eaTHEN60270
60220 sa=sa+1:a$=MID$(STR$(PEEK(sa)),2)+",":IFa$="0,"THENa$=","
60230 IFsa>eaTHEN60250
60240 IFPOS(.)+LEN(a$)<75THENPRINTa$;:GOTO60220
60250 PRINTCHR$(20):PRINT"60200sa="sa":ea="ea":sl="sl+ls":ls="ls:PRINT"gO60200
60260 GOTO63000
60270 PRINT"{clear}data lines ready. please remove lines{space*3}6{0*4}-63{0*3} if not needed.
60280 POKE198,.:END
63000 PRINT"{home}";:POKE198,9:FORi=631TO640:POKEi,13:NEXT:END
stop tok64
(bastext 1.0)