start tok64 d64-9y86CY
10 REM" reconfigure printer 27-aug-92
15 wl=PEEK(776)+256*PEEK(777)-100
20 FORx=1 TO 56:READ a:NEXT
25 nu$="{reverse on}Par":IF PEEK(wl+80)=83 THEN nu$="{reverse on}Ser"
30 nu$=nu$+" {arrow left}C0,"+MID$(STR$(PEEK(wl+1607)),2)+"{space*2}LF"+STR$(PEEK(wl+1736))
35 sp$="{space*2}Fast":IF PEEK(wl+420)>10 THEN sp$="{space*2}Slow"
40 nu$=nu$+sp$:sp$="{space*2}ASCII":IF PEEK(wl+2931)=93 THEN sp$="{space*2}Norsk"
45 nu$=nu$+sp$
50 GOSUB5000:ON nc GOSUB 100,200,300,400,500,600,700,800,900:GOTO25
55 REM ----
100 POKEwl+398,173:POKEwl+399,13:POKEwl+400,221
110 POKEwl+498,32:POKEwl+512,56:POKEwl+540,32:POKEwl+543,56
120 POKEwl+80,80:POKEwl+1536,56:POKEwl+1623,56:POKEwl+2609,133
130 y=wl+1987:x=INT(y/256):POKE wl+187,y-256*x:POKE wl+188,x
140 RETURN
200 POKEwl+398,24:POKEwl+399,144:POKEwl+400,248
210 POKEwl+498,44:POKEwl+512,24:POKEwl+540,44:POKEwl+543,24
220 POKEwl+80,83:POKEwl+1536,24:POKEwl+1623,24:POKEwl+2609,36
230 POKEwl+187,227:POKEwl+188,168
240 RETURN
300 POKEwl+1307,10:POKEwl+1319,5:POKEwl+1602,42:POKEwl+1607,1:REM"{arrow left}c0,1
310 RETURN
400 POKEwl+1307,11:POKEwl+1319,4:POKEwl+1602,27:POKEwl+1607,76:REM"{arrow left}c0,76
410 RETURN
500 lf=PEEK(wl+1736):lf=-23*(lf=24)-20*(lf=23)-24*(lf<>23 AND lf<>24)
510 POKEwl+1736,lf:RETURN
600 x=PEEK(wl+420):y=-127*(x<10)-2*(x>9):POKEwl+420,y:POKEwl+430,y
610 RETURN
700 RESTORE
710 FOR y=wl+2905 TO wl+2905+27:READ a:POKE y,a:NEXT
720 FOR y=1 TO 28:READ a:NEXT
730 DATA 15,20,192,205,165,186,167,186,176,201,174,187,189,188,173,200
740 DATA 219,146,220,157,221,143,91,145,92,155,93,134:REM" norsk
750 RETURN
800 RESTORE:FOR y=1 TO 28:READ a:NEXT
810 FOR y=wl+2905 TO wl+2905+27:READ a:POKE y,a:NEXT
820 DATA 15,20,192,205,165,186,167,186,176,201,174,187,189,188,173,200
830 DATA 221,186,171,204,179,185,177,202,178,203,219,206:REM" ascii
840 RETURN
900 POKE53280,14:POKE53281,6:PRINT CHR$(142);"{clear}{light blue}"
910 PRINT SPC(7);:SYS wl
920 IF NOT(PEEK(wl+80)=83 AND PEEK(wl+1607)>74) THEN960
930 PRINT"{down*2}remember to set {reverse on} {arrow left}c0,76+128 {reverse off} if your"
940 PRINT"printer or serial interface is set for"
950 PRINT"commodore ascii (petscii)!"
960 CLR:END
5000 REM" menu nc
5010 cl=15:cy=151:bl=144:REM"colours
5020 IF no>0 GOTO5060
5030 READ no,nc:DIM n$(no),op$(no)
5040 FORx=0TOno:READ op$(x):NEXT
5060 PRINT"{clear}{ct n}";:POKE 53280,cl:POKE 53281,cl
5070 PRINT"{blue}{cm a}";:FORx=1TO37:PRINT"{sh asterisk}";:NEXT:PRINT"{cm s}"
5080 PRINT"{cm g}{white}{space*3}KA PROGRAM MENU at your service{space*3}{blue}{cm m}
5090 PRINT"{blue}{cm z}";:FORx=1TO37:PRINT"{sh asterisk}";:NEXT:PRINT"{cm x}"
5100 PRINT:PRINTCHR$(bl)" Choose with {reverse on} CURSOR {reverse off}
5110 PRINT "{home}{down*4}"
5120 FORx=1TOno:n$(x)=CHR$(cy)+CHR$(146+128*(x=nc))+CHR$(-bl*(x=nc)):NEXT
5130 PRINTTAB(43)CHR$(146+128*(nc>0))"{orange} RETURN {reverse off}{space*2}to Execute{down}":PRINT"{white}"
5135 PRINT"Status:";nu$;"{down}"
5140 FORx=0TOno:PRINTTAB(19-LEN(op$(x))/2)n$(x)op$(x):NEXT
5150 GETc1$:IFc1$="{down}"THENnc=ABS(nc):nc=1+nc*SGN(no-nc):GOTO5110
5160 IFc1$="{up}"THENnc=ABS(nc):nc=nc-1-no*SGN(nc-1)+no:GOTO5110
5170 z=FRE(8):IFc1$=CHR$(13)THEN nc=ABS(nc):RETURN
5180 nc=-nc:GOTO5110
5190 DATA9,1
5200 DATA"{down} *** Reconfigure KA43/61 ***{down}"
5210 DATA "Parallel Printer","Serial Printer"
5220 DATA "Any Bit Image Mode (e.g. {arrow left}C0,1)"
5230 DATA "Standard Bit Image Mode"
5240 DATA "Line Feed (24, 23 or 20)"
5250 DATA "Transfer Speed (only Par Printer)"
5260 DATA "Norsk IBM (in {arrow left}C2 mode)"
5270 DATA "ASCII 8-bit (in {arrow left}C2 mode)
5280 DATA "- END -"
stop tok64
(bastext 1.0)