start tok64 d64-JAn9Gd
2 POKE631,82:POKE632,85:POKE633,78:POKE634,54:POKE635,13:REM" run6
4 POKE198,5:OPEN15,9,15,"i0":END:" some turbo cart. break with {arrow left}e9"
6 CLOSE15:d=8:IF(st AND 191)=0 THENd=9
8 :
100 REM" print user guide 23-oct-92
110 :
120 {arrow left}e8:ug$="user guide":REM" file to print
130 f$="hint & tips.pic":ht=160*256:pl=6:REM" picture of pl lines
140 h1$="{space*3}OPEN SYSTEM":h2$="{space*5}KA43/61":REM" headlines
150 :
160 adr=PEEK(776)+256*PEEK(777)-100:bit=PEEK(adr+1607):mode=PEEK(adr+227)
170 IF bit<10 THEN bit=6:lm=10:gm=30:GOTO190:REM" 90 chr/line
180 bit=76-(bit>128)*128:lm=15:gm=22:REM" 120 chr/line
190 {arrow left}g gm,ht/256,pl:REM"set graphic.pic
200 IF mode>1 THEN READ a,x:FORx=0 TO a:READ a$:NEXT:GOTO220
210 GOSUB5000:mode=2-(nc=2):REM" 2 for std ascii, 3 for pet ascii
220 lm$=CHR$(lm):l1$=CHR$(1):rm$=CHR$(136):OPEN 4,4,7
230 GOSUB5000:PRINT"{down*2}{reverse on} RUN/STOP {reverse off} if no respons from printer"
240 {arrow left}c3:PRINT#4,"{027}"+CHR$(15);:{arrow left}c mode:REM "chr$(15) may not be accepted in {arrow left}c2
250 ON nc GOTO260,270,280
260 l$="{027}X"+lm$+rm$:PRINT#4,"{027}X"+l1$+rm$:GOTO280
270 l$="{027}l"+lm$:PRINT#4,"{027}l"+l1$
280 cr$=CHR$(13):ch$="exclusive.chr"
290 PRINT#4,cr$;cr$;cr$;cr$:{arrow left}b1 h1$
300 PRINT#4,cr$;cr$;cr$;cr$;cr$:{arrow left}b1 h2$:PRINT#4,l$+CHR$(12);
310 PRINT"{clear}{down}PRESS {reverse on} F7 {reverse off} to stop printing!":PRINT"{down}{reverse on} RUN/STOP {reverse off} break.
320 PRINT"{down}Loading: Norsk chr":{arrow left}x"norsk chr",ch$d
330 IF(st AND 191)<>0 AND d=9 THEN PRINT"{up*2}":{arrow left}e9:PRINT"{up*3}":{arrow left}e8:{arrow left}x,ch$8
340 IF(st AND 191)<>0 THENPRINT:{arrow left}e8:END
350 {arrow left}x"relocate load",f$,ht,d
360 IF(st AND 191)<>0 AND d=9 THEN:{arrow left}e9:PRINT"{up*3}":{arrow left}e8:{arrow left}x,f$,ht,8
370 {arrow left}c0,bit:{arrow left}x"view-file"d
380 PRINT CHR$(14);"{white}{down*4}{space*3}Realign top of paper to print-head."
390 PRINT SPC(46);"Press {reverse on} SPACE {reverse off} when ready!{light blue}":POKE 198,0
400 GET a$:IF a$=CHR$(136) THEN STOP
410 IF a$<>" " THEN400
420 PRINT"{down*4}Printing {reverse on} ";ug$;" {reverse off} from dev";d:{arrow left}x,ug$,4
430 END
5000 REM " menu returns nc
5010 cl=15:cy=151:bl=144:REM"{space*2}colours
5020 REM" if no>0 goto5050
5030 READ no,nc:REM" dim n$(no),op$(no)
5040 FOR x=0 TO no:READ op$(x):NEXT
5050 PRINT CHR$(147);CHR$(14);
5060 POKE 53280,cl:POKE 53281,cl
5070 PRINT"{blue}{cm a}{sh asterisk*37}{cm s}"
5080 PRINT"{cm g}{white}{space*2}USER GUIDE{space*2}TO DOT MATRIX PRINTER{space*2}{blue}{cm m}
5090 PRINT"{blue}{cm z}{sh asterisk*37}{cm x}"
5100 PRINT:PRINT CHR$(bl);" Choose with {reverse on} CURSOR {reverse off}
5110 x=FRE(8):PRINT "{home}{down*4}
5120 FORx=1TOno:n$(x)=CHR$(cy)+CHR$(146+128*(x=nc))+CHR$(-bl*(x=nc)):NEXT
5130 PRINT TAB(43)CHR$(146+128*(nc>0))"{orange} RETURN {reverse off}{space*2}to continue{down}":PRINT"{white}"
5140 FORx=0TOno:PRINT TAB(19-LEN(op$(x))/2)n$(x)op$(x):NEXT
5150 GETc1$:IFc1$="{down}" THEN nc=ABS(nc):nc=1+nc*SGN(no-nc):GOTO5110
5160 IFc1$="{up}" THEN nc=ABS(nc):nc=nc-1-no*SGN(nc-1)+no:GOTO5110
5170 IFc1$<>CHR$(13)THENnc=-nc:GOTO5110
5180 nc=ABS(nc):RETURN
5190 DATA 2,1:REM" printer mode
5200 DATA "Printer or hard-ware interface is for:
5210 DATA "{down}Standard ASCII
5220 DATA "Commodore (PET-) ASCII
5230 DATA 3,3:REM "printer type
5240 DATA "State printer type due to left margin"
5250 DATA "{down}IBM-printer (ESC X)
5260 DATA "Epson-printer (ESC l)
5270 DATA "Do'nt care!
stop tok64
(bastext 1.0)