start tok64 d64-vCOyBS
1 bd=53280:sr=bd+1:POKEbd,0:POKEsr,0:PRINT"{white}{clear}"CHR$(142);TAB(12)"{down*4}this program is"
2 PRINTTAB(12)"{down}contributed to"
3 PRINTTAB(12)"{down}your school by"
4 PRINTTAB(9)"{down}{reverse on}{red}a{cyan}m{156}e{green}r{blue}i{yellow}c{orange}a{brown}n{pink} {light green}p{light blue}e{light gray}r{white}i{red}p{cyan}h{156}e{green}r{blue}a{yellow}l{white}s{reverse off}"
5 PRINTTAB(12)"{down}your source for"
6 PRINTTAB(15)"{down}vic/pet"
7 PRINTTAB(9)"{down}hardware & software.":POKE54296,15
10 FORs=832TO880:READpv:POKEs,pv:NEXT
20 DATA169,25,133,0,169,0,133,251,169,4,133,252,162,0,160,0,177,251,73,128,145
30 DATA251,200,192,40,208,245,232,228,0,240,16,165,251,24,105,40,133,251,165,252
40 DATA105,0,133,252,76,78,3,96
50 POKE54277,9:POKE54284,96:POKE54291,9
55 POKE54278,48:POKE54285,48:POKE54292,48
60 POKE54276,17:POKE54288,17:POKE54290,17
70 g(1)=54273:g(2)=54272:g(3)=54280:g(4)=54279:g(5)=54287:g(6)=54286
80 FORsl=1TO6:POKEg(sl),0:NEXT
100 y=63:z=30:DIMk$(64),p(64),c%(64):READa$
105 u$="{space*21}"
110 DATA"asdfghjkl:[;]=qwertyuiop@*^zxcvbnm,<.>/?{arrow left}1!2 3#4$5%6&7'8(9)0+-{pound}"
120 DATA208,210,212,214,216,218,220,222,224,226,186,228,188,230,127,129,131,133
130 FORk=1TOy:READp(k):p(k)=p(k)+1024:k$(k)=MID$(a$,k,1):c%(k)=ASC(k$(k))
140 c%(k)=c%(k)-(64ANDc%(k)):NEXT:k=0:k$(45)=CHR$(34):c%(45)=34
150 PRINT"{clear}{down}{reverse on}{red}{right*8} {cyan}t{156} {green}y{blue} {yellow}p{orange} {brown}e{pink} {light green} {light blue} {light gray} {white}t{red} {cyan}u{156} {green}t{blue} {yellow}o{orange} {brown}r{white} "
160 PRINT"{down}{right*9}for the commodore-64"
165 FORcz=1TO50
170 dl=INT(RND(1)*255)+1:FORsl=1TO6:POKEg(sl),dl:NEXT:POKEbd,dl:POKEsr,dl
172 NEXT:POKEbd,0:POKEsr,0:FORsl=1TO6:POKEg(sl),0:NEXT
175 PRINTTAB(8)"{reverse on}{down}{right}{light blue} pick a lesson from {white}{down}"
180 h$="":PRINT"{right*13}1 to 16 ? ";:GOSUB60000:x=VAL(in$)
185 IFx>16ORx<1THENPRINT"{up}{right*23}{space*2}":PRINT"{up}";:GOTO180
190 PRINT"{down}{right*10}do you want me to":PRINT"{down}{right*8}flash the keys to type"
200 PRINT"{down}{right*8}{yellow}{space*3}{reverse on} y=yes and n=no {white}"
210 GETd$:IFd$=""THEN210
220 IFd$="y"THEN250
230 IFd$="n"THEN260
240 GOTO210
250 f=1
260 PRINT"{clear}{down}{right*9}this lesson covers":PRINT"{down}{right*9}the following keys:{down}"
270 ONxGOTO280,650,660,670,680,700,720,740,750,760,770,780,790,800,810,820
280 g=1:b=g:h=5:e=h:h$="s":d=5:l=5
320 IFh$="h"THEN360
330 FORc=bTOe:PRINT" "k$(c);:NEXT:PRINT
340 PRINT"{down*2}{right*13}{light green}{reverse on} hit a key {white}{reverse off}":GOTO370
360 FORc=gTOh:PRINT" "k$(c);:NEXT:PRINT:GOTO330
370 POKE198,0:WAIT198,1
375 PRINT"{clear}{up}{reverse on}{right*8}{yellow}!{right} {right}#{right}${right}%{right}&{right}'{right}({right})"
380 PRINT"{right*6}{reverse on}{arrow left}{right}1{right}2{right}3{right}4{right}5{right}6{right}7{right}8{right}9{right}0{right}+{right}-{right}{pound}":POKE1034,162
390 PRINT"{down}{right*6}{reverse on}{pink}{right}q{right}w{right}e{right}r{right}t{right}y{right}u{right}i{right}o{right}p{right}@{right}*{right}^{light green}"
400 PRINT"{down}{right*6}{reverse on}{right*2}a{right}s{right}d{right}f{right}g{right}h{right}j{right}k{right}l{right}{up}[{down}{left}:{right}{up}]{down}{left};{right}={white}":PRINT"{up*2}{right*8}.{right}.{right}.{right}.{right*5}.{right}.{right}."
410 PRINT"{down*2}{reverse on}{right*2}{orange}shift{right*2}{light blue}z{right}x{right}c{right}v{right}b{right}n{right}m{right}{up}<{down}{left},{right}{up}>{down}{left}.{right}{up}?{down}{left}/{right*2}{orange}shift"
415 PRINT
420 PRINT"{reverse on}{right*11}{cyan}{sh space}{space*2}space bar{space*4}{white}{right*2}"
425 PRINT
430 PRINT
432 PRINT"{156}{C*40}{white}":c=0
435 bt=ti
440 IFh$="s"THEN460
450 GOTO470
460 r=INT(RND(1)*d)+g:GOTO520
470 IFh$="h"THEN490
480 GOTO510
490 w=INT(RND(1)*2)+1:IFw=1THEN460
500 GOTO510
510 r=RND(-ti):r=INT(RND(1)*l)+b
520 POKE198,0
525 PRINT"{home}{down*18}{right*9}{green}****** {reverse on}type{reverse off}{white} "k$(r):PRINTTAB(22)"{green}{up} ******{white}"
530 IFf=1THENPOKEp(r),32:FORs=1TO50:NEXT
535 hf=INT((ti-bt)/60)
540 GETr$:POKEp(r),c%(r)+128:FORs=1TO100:NEXT:IFr$=""THEN530
550 FORi=1TO6STEP2:POKEg(i),68:POKEg(i+1),149:NEXT:FORs=1TOz:NEXT:FORi=1TO6:POKEg(i),0:NEXT
555 IFr$=k$(r)THEN590
557 tw$=ti$:FORfl=1TO4
560 POKEbd,1:SYS832:FORs=1TO6:POKEg(s),170:NEXT:FORdl=1TO70:NEXT
565 SYS832:POKEbd,0:FORs=1TO6:POKEg(s),120:NEXT:FORdl=1TO70:NEXT:NEXT
566 FORs=1TO6:POKEg(s),0:NEXT
570 PRINT"{reverse on}{down}{right*9}**sorry about that**{reverse off}"
575 j=j+1:c=c+1:FORs=1TO900:NEXT:PRINT"{up}{right*9}"u$:GOSUB860:ti$=tw$:IFc=50THEN610
580 GOTO520
590 c=c+1:GOSUB860:IFc=50THEN610
600 GOTO440
610 p=c-j:t=p/c*100:PRINT"{clear}{down}{right*10}{space*2}your score was":PRINTTAB(10)"{down}"t"% on lesson"x
615 PRINT"{down}you typed {reverse on}{light green}"c"{white}{reverse off}characters in {reverse on}{light green}"INT((hf/60)*100)/100"{white}{reverse off}mins.{down}"
620 f=0:c=0:t=0:j=0:b=0:e=0
640 c%(5)=7:c%(6)=8:c%(7)=10:c%(8)=11:GOTO165
650 b=6:g=b:e=14:h=e:l=9:d=l:h$="s":GOTO320
660 b=1:g=b:e=14:h=e:l=14:d=l:h$="s":GOTO320
670 b=1:e=5:l=5:g=15:h=20:d=6:h$="h":GOTO320
680 b=6:e=14:l=9
690 g=21:h=27:d=7:h$="h":GOTO320
700 b=1:e=14:l=14
710 g=15:h=27:d=11:h$="h":GOTO320
720 b=1:e=5:l=5
730 g=28:h=32:d=5:h$="h":GOTO320
740 b=6:e=14:l=9:g=33:h=40:d=8:h$="h":GOTO320
750 b=1:e=14:l=14:g=28:h=40:d=13:h$="h":GOTO320
760 b=1:g=b:e=40:h=e:l=40:d=l:h$="s":GOTO320
770 b=1:e=5:l=5:g=41:h=53:d=13:h$="h":GOTO320
780 b=6:e=14:l=9:g=54:h=63:d=10:h$="h":GOTO320
790 b=1:e=14:l=14:g=41:h=63:d=23:h$="h":GOTO320
800 b=1:e=27:l=27:g=41:h=63:d=23:h$="h":GOTO320
810 b=1:e=14:l=14:g=28:h=63:d=36:h$="h":GOTO320
820 b=1:g=b:e=y:h=e:l=y:d=l:h$="s":GOTO320
860 POKE1689,32:PRINT"{yellow}{home}{down*16}"TAB(12)"keys left ={white}"50-c
861 PRINT"{down*2}":RETURN
870 DATA135,137,139,141,143,145,147,149,151,289,291,293,295,297,299,301,303,263
880 DATA305,265,307,267,46,48,8,50,10,52,12,54,14,56,16,58,18,60,20,62,22,64,24
890 DATA66,68,70,72
60000 in$=" ":zc=1:zd$=CHR$(20):cr$=CHR$(13)
60010 GETz$:IFz$<>""THEN60070
60020 POKE646,INT(RND(1)*15)+1:PRINTMID$("{cm v}{cm d}{cm f}{cm c}",zc,1);"{left}";:zc=(3ANDzc)+1
60030 POKE646,1:GOTO60010
60070 z=ASC(z$):zl=LEN(in$):IF(zAND127)<32THENPRINT" {left}";:GOTO60110
60090 IFzl>2THEN60010
60100 in$=in$+z$:PRINTz$;zd$;z$;
60110 IFz=13THENin$=MID$(in$,2):PRINTcr$;:RETURN
60120 IFz=20ANDzl>1THENin$=LEFT$(in$,zl-1):PRINT"{left}";:GOTO60010
60130 IFz=141THENz$=CHR$(-20*(zl>1)):FORz=2TOzl:PRINTz$;:NEXTz:GOTO60000
60140 GOTO60010
stop tok64
(bastext 1.0)