start tok64 d64-S4Luzw
0 IFPEEK(52)=128THEN21
1 REM ****** hyper worm ******
2 POKE53280,14:POKE53281,14:PRINT"{white}{clear}";:GOTO5
3 a$=LEFT$(a$+"{space*39}",39):FORi=.TO39
4 PRINT"{up}"TAB(39-i)LEFT$(a$,i):FORz=.TO25:NEXT:NEXT:PRINT:RETURN
5 a$="hyper worm{.*4} (c) 1990 mr.p{.*3}":GOSUB3
6 a$="a club64 public domain{.*3} greetings to:":GOSUB3
7 a$="ulf tidstrand, henrik karnell and ":GOSUB3
8 a$="stefan bergdahl{.*3}":GOSUB3
9 a$="anti-greetings to: roger karlsson..":GOSUB3
15 FORi=.TO2000:NEXT:PRINT:PRINT:PRINT
20 a$="please wait{.*3}":GOSUB3:CLR
21 FORl=679TO730:READa:POKEl,a:NEXT
22 SYS679:POKE52,128:POKE56,128
23 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
24 POKE648,136:POKE53272,32:PRINT"{142}{clear}":POKE53280,0:POKE53281,0
25 DATA120,165,1,41,251,133,1,169,0,133,251,169,208,133,252,169,0,133,253,169
26 DATA128,133,254,160,0,177,251,145,253,200,192,0,208,247,230,252,230,254,165
27 DATA252,201,216,208,237,165,1,9,4,133,1,88,96
28 READch:IFch<0THEN55
29 FORby=.TO7:READa:POKE32768+(ch*8)+by,a:POKE33792+(8*ch)+by,255-a:NEXT:GOTO28
30 DATA81,126,255,255,195,195,255,255,126
40 DATA87,126,153,153,255,195,255,255,126
41 DATA90,0,24,52,122,126,60,24,0
50 DATA-1
55 FORi=1TO5:READhi$(i):sc(i)=300:NEXT
56 le$="a":ri$="=":st$="p":qu$="q"
57 g$="fast":g=.:vi=34816:cm=55296
58 DATAmr.p.,ulf.t.,"{yellow}W{white}club{down}{left*2}64{up}","{yellow}Q{orange}QQ{white}64","{light blue}softwolves
59 DIMse(500)
60 PRINT"{clear}{yellow}Q{space*2}Q Q{space*2}Q {Q*3}{space*2}{Q*3} {Q*3}"
70 PRINT"Q{space*2}Q Q Q{space*2}Q{space*2}Q Q{space*3}Q{space*2}Q
80 PRINT"{Q*4} QQ{space*3}{Q*3}{space*2}QQ{space*2}{Q*3}
90 PRINT"Q{space*2}Q Q{space*4}Q{space*4}Q{space*3}Q{space*2}Q
100 PRINT"Q{space*2}Q Q{space*4}Q{space*4}{Q*3} Q{space*2}Q{down}
110 PRINT"Q{space*3}Q {Q*3}W {Q*3}{space*2}Q{space*3}Q{space*5}{light blue}programmed by{yellow}
120 PRINT"Q{space*3}Q Q{space*2}Q Q{space*2}Q QQ QQ
130 PRINT"Q{space*3}Q Q{space*2}Q Q{space*2}Q Q Q Q{space*5}{light blue}mr.p. of{yellow}
140 PRINT"Q{space*3}Q Q{space*2}Q Q Q{space*2}Q{space*3}Q
150 PRINT"Q W Q Q{space*2}Q Q{space*2}Q Q{space*3}Q{space*5}{light blue}softwolves{yellow}
160 PRINT"QQ QQ Q{space*2}Q Q{space*2}Q Q{space*3}Q
170 PRINT"Q{space*3}Q {Q*4} Q{space*2}W Q{space*3}{Q*4}W{down}
180 PRINT"{home}{down*13}{cyan}{Z*5} hall of fame {Z*5}
190 FORi=1TO5
200 PRINT"{red}{space*3}"i"{green}"RIGHT$(STR$(1e8+sc(i)),8)" {blue}"hi$(i)
210 NEXT
220 PRINT"{down}{light blue}f1 {blue}game speed: {green}"g$,"{light blue}f3 {blue}key definion{light blue}
240 PRINTst$"{space*2}{blue}pause/start{light blue}",qu$"{space*2}{blue}quit game
245 PRINT"{cyan}W{Q*9} {light blue}"le$" {cyan}left right {light blue}"ri$" {cyan}{Q*9}W";
250 GETa$:IFa$="{f1}"THEN300
260 IFa$="{f3}"THEN400
270 IFa$=st$THEN500
280 GOTO250
290 REM**game speed**
300 IFg$="slow"THENg=.:g$="fast":GOTO180
310 g=100:g$="slow":GOTO180
390 REM**keys**
400 PRINT"{clear}W{Q*4} press key for rotate left: ";
410 GETle$:IFle$=""THEN410
411 IFle$<"!"ORle$>"{arrow left}"THEN410
420 PRINTle$
430 PRINT"{up}{space*5}{down}{left*5}{Q*4}W press key for rotate right:";
440 GETri$:IFri$=""THEN440
441 IFri$<"!"ORri$>"{arrow left}"ORri$=le$THEN440
450 PRINTri$
460 PRINT"{up}{space*5}{down}{left*5}QstopQpress key for pause/start: ";
470 GETst$:IFst$=""THEN470
471 IFst$<"!"ORst$>"{arrow left}"ORst$=le$ORst$=ri$THEN470
480 PRINTst$
481 PRINT"{up}{space*6}{down}{left*6}QquitQpress key for quit game:{space*3}";
482 GETqu$:IFqu$=""THEN482
483 IFqu$<"!"ORqu$>"{arrow left}"ORqu$=le$ORqu$=ri$ORqu$=ri$THEN482
484 PRINTqu$:GOTO60
490 REM**game**
500 d$="{home}{down*24}"
501 FORi=22TO38:PRINTLEFT$(d$,13)TAB(i-1)" {yellow}"LEFT$("{Q*3}W",39-i)
502 FORs=.TO50:NEXT:NEXT
509 PRINT"{yellow}{clear}";
510 FORi=1TO38:POKEvi+i,100:POKEvi+23*40+i,99:POKEcm+i,6:POKEcm+23*40+i,6
511 IFi<23THENPOKEvi+i*40,103:POKEvi+39+i*40,101:POKEcm+i*40,6:POKEcm+39+i*40,6
512 NEXT
530 PRINTd$"{green} score:{space*9}{156} segments: {yellow}{0*3}1 {light blue}"qu$"{blue} quit{home}
540 PRINT"{home}{down*2}{right*2}{yellow}QW":se(499)=vi+83:se(500)=vi+82:se=500:fi=499:ri=1:sg=1:p=.
550 FORd=1TO3:GOSUB1000:NEXT
560 IFg=.THEN590
565 FORs=1TOg
570 REM       ** fordrojning **
580 NEXT
590 GETq$:IFq$=st$THENPOKE198,0:WAIT198,1:POKE198,0:GOTO590
595 IFq$=qu$THEN2000
600 IFq$=le$THENGOSUB1100:REMrot. left
610 IFq$=ri$THENGOSUB1200:REMrot. right
620 q=se(fi)+ri:p=p+(200-g)/200
630 IFPEEK(q)=90THENGOSUB1300:GOTO650
640 IFPEEK(q)<>32THEN2000
650 PRINTd$"{green} score: {yellow}"RIGHT$(STR$(1e8+INT(p)),8)"{home}
660 w=fi:fi=fi-1:IFfi<.THENfi=500
670 se(fi)=q
680 POKEse(fi),87
690 POKEse(w),81:POKEse(se),32
695 se=se-1:IFse<.THENse=500
700 GOTO560
1000 di(d)=INT(RND(.)*879)+vi:IFPEEK(di(d))<>32THEN1000
1001 IFdi(d)=viORdi(d)=vi+39THEN1000
1010 POKEdi(d),90:RETURN
1100 IFri=40THENri=1:RETURN
1101 IFri=1THENri=-40:RETURN
1102 IFri=-40THENri=-1:RETURN
1103 IFri=-1THENri=40:RETURN
1104 STOP
1200 IFri=1THENri=40:RETURN
1201 IFri=-40THENri=1:RETURN
1202 IFri=-1THENri=-40:RETURN
1203 IFri=40THENri=-1:RETURN
1204 STOP
1300 p=p+5
1301 IFq=di(1)THENd=1:GOSUB1000
1302 IFq=di(2)THENd=2:GOSUB1000
1303 IFq=di(3)THENd=3:GOSUB1000
1304 s=se:se=se+1:IFse>500THENse=.
1305 se(se)=se(s):se=se+1:IFse>500THENse=.
1306 se(se)=se(s):se=se+1:IFse>500THENse=.
1307 se(se)=se(s):sg=sg+3
1308 PRINTd$"{green} score: {yellow}"RIGHT$(STR$(1e8+INT(p)),8)" {156}segments: {yellow}"RIGHT$(STR$(1e4+sg),4)"{home}
1309 RETURN
2000 FORi=.TO32:POKE53280,i:NEXT
2001 PRINT"{clear}{cyan}{Q*3}W {Q*4} {Q*5} {Q*3}W":p=INT(p)
2002 PRINT"Q{space*4}Q{space*2}Q Q Q Q Q
2003 PRINT"Q QQ Q QQ Q W Q {Q*3}
2004 PRINT"Q{space*2}Q Q{space*2}Q Q{space*3}Q Q
2005 PRINT"Q{space*2}Q Q{space*2}Q Q{space*3}Q Q
2006 PRINT"{white}{Q*4} Q{space*2}W Q{space*3}Q {Q*4}{down}{cyan}
2007 PRINT"{Q*4} Q{space*3}W {Q*3}W {Q*3}
2008 PRINT"Q{space*2}Q Q{space*3}Q Q{space*4}Q{space*2}W
2009 PRINT"Q{space*2}Q Q{space*3}Q {Q*3}{space*2}{Q*3}
2010 PRINT"Q{space*2}Q{space*2}Q Q{space*2}Q{space*4}Q{space*2}Q{white}
2011 PRINT"{Q*3}W{space*3}Q{space*3}{Q*4} Q{space*2}Q
2020 PRINT"{gray}{down}your score:"p:POKE198,.
2030 IFp>sc(5)THEN2100
2040 PRINT"{blue}press {light blue}"st$"{blue} to go to title screen
2050 GETq$:IFq$=st$THEN60
2060 GOTO2050
2100 PRINT"{blue}you're qualified for hall of fame:
2110 PRINT"please enter your name:
2120 PRINTLEFT$(d$,20)"{gray}{cm @*5}{left*5}{dark gray}";
2130 GETa$:IFa$=""THEN2130
2140 IFa$<" "ORa$>"]"THEN2130
2150 PRINTa$;
2160 GETb$:IFb$=""THEN2160
2165 IFb$=CHR$(20)THEN2120
2170 IFb$<" "ORb$>"]"THEN2160
2180 PRINTb$;
2190 GETc$:IFc$=""THEN2190
2195 IFc$=CHR$(20)THEN2120
2200 IFc$<" "ORc$>"]"THEN2160
2210 PRINTc$;
2220 GETe$:IFe$=""THEN2220
2225 IFe$=CHR$(20)THEN2120
2230 IFe$<" "ORe$>"]"THEN2220
2240 PRINTe$;
2250 GETf$:IFf$=""THEN2250
2255 IFf$=CHR$(20)THEN2120
2260 IFf$<" "ORf$>"]"THEN2220
2270 PRINTf$;
2280 m$=a$+b$+c$+e$+f$
2290 FORi=5TO1STEP-1
2300 IFp>sc(i)THENsc(i)=sc(i-1):hi$(i)=hi$(i-1):NEXT
2310 hi$(i+1)=m$:sc(i+1)=p
2320 GOTO60
stop tok64
(bastext 1.0)