start tok64 d64-BRPIky
0 DIMs(1000),t(1000),t$(1000),y(1000),d(1000),m(1000):GOSUB60000
10 POKE53280,0:POKE53281,0:PRINT"{gray}";
20 PRINT"{clear}{reverse on}databudget (c) 1989 mr.p.{space*14}"
30 GOSUB1000:REMmeny
50 ONaGOSUB3000,4000,5000,6000,7000,8000,9000:REMval
90 GOTO30
1000 PRINT"{home}{down*3}{right*4}{cm a}{sh asterisk*21}{cm s}
1010 PRINT"{right*4}{sh -}***** huvudmeny *****{sh -}
1020 PRINT"{right*4}{sh -}1) l[sa in fil (band){sh -}
1030 PRINT"{right*4}{sh -}2) spara fil{space*3}(band){sh -}
1040 PRINT"{right*4}{sh -}3) nya transaktioner {sh -}
1050 PRINT"{right*4}{sh -}4) nytt konto{space*8}{sh -}
1051 PRINT"{right*4}{sh -}5) visning av trans. {sh -}
1052 PRINT"{right*4}{sh -}6) f{pound}rkorta konto{space*4}{sh -}
1053 PRINT"{right*4}{sh -}7) avsluta{space*11}{sh -}
1060 PRINT"{right*4}{cm z}{sh asterisk*21}{cm x}
1080 PRINT"{home}{down*13}{right}{cm a}{sh asterisk*32}{cm s}
1090 PRINT"{right}{sh -}nuvarande uppgifter:{space*12}{sh -}
1100 PRINT"{right}{sh -}kontonummer:{space*20}{sh -}{left*21}"kn$
1110 PRINT"{right}{sh -}innehavare:{space*21}{sh -}{left*22}"ki$
1120 PRINT"{right}{sh -}kontoform:{space*22}{sh -}{left*23}"kf$
1130 PRINT"{right}{sh -}bank:{space*27}{sh -}{left*28}"ba$
1140 PRINT"{right}{sh -}kontor:{space*25}{sh -}{left*24}";
1141 PRINT"{left*2}"ko$","kt$
1142 PRINT"{right}{sh -}saldo:{space*26}{sh -}{left*27}"s(z)
1150 PRINT"{right}{cm z}{sh asterisk}{cm r}{sh asterisk*16}{cm r}{sh asterisk*13}{cm x}
1152 PRINT"{right*3}{sh -}fyllt minne:{space*3}%{sh -}{left*5}";MID$(STR$(1000+INT(z/10)),3)
1153 PRINT"{right*3}{cm z}{sh asterisk*16}{cm x}
1155 SYS49408
1160 PRINT"{home}"TAB(33)"{cm a}{sh asterisk*4}{cm s}"
1170 PRINTTAB(33)"{sh -}v[lj{sh -}":PRINTTAB(33)"{cm z}{sh asterisk*4}{cm x}"
1180 GETa$:IFa$<"1"ORa$>"7"THEN1180
1190 a=VAL(a$)
1200 SYS49440
1210 PRINT"{home}{down*3}{right*4}{down}{right}";:FORi=1TOa:PRINT"{down}";:NEXT:PRINT"{light gray}"a$"){gray}"
1220 RETURN
3000 SYS49408:PRINT"{home}{down*2}{cm a}{sh asterisk*22}{cm s}
3010 PRINT"{sh -}namn?{space*17}{sh -}
3020 PRINT"{cm z}{sh asterisk*22}{cm x}
3030 INPUT"{home}{down*3}{right}namn";a$:a$=LEFT$(a$,16)
3040 PRINT"{home}{down*2}{cm a}{sh asterisk*22}{cm s}
3050 PRINT"{sh -}l[ser data{.*8}{space*4}{sh -}
3060 PRINT"{cm z}{sh asterisk*22}{cm x}
3065 PRINT"{sh asterisk*18}{cm s}
3066 PRINT"{space*18}{sh -}
3067 PRINT"{space*18}{sh -}
3068 PRINT"{sh asterisk*18}{cm x}{home}{down*4}
3070 OPEN1,1,0,a$
3080 INPUT#1,kn$,ki$,kf$,ba$,ko$,kt$
3090 INPUT#1,z
3100 FORi=1TOz
3110 : INPUT#1,s(i),t$(i),t(i),y(i),m(i),d(i)
3120 NEXT:PRINT"{home}{down*3}{right}{space*18}":SYS49440
3130 CLOSE1:RETURN
4000 SYS49408:PRINT"{home}{down*2}{cm a}{sh asterisk*22}{cm s}
4010 PRINT"{sh -}namn?{space*17}{sh -}
4020 PRINT"{cm z}{sh asterisk*22}{cm x}
4030 INPUT"{home}{down*3}{right}namn";a$:a$=LEFT$(a$,16)
4040 PRINT"{home}{down*2}{cm a}{sh asterisk*22}{cm s}
4050 PRINT"{sh -}skriver data{.*6}{space*4}{sh -}
4060 PRINT"{cm z}{sh asterisk*22}{cm x}
4065 PRINT"{cm a}{sh asterisk*27}{cm s}
4066 PRINT"{sh -}{space*27}{sh -}
4067 PRINT"{sh -}{space*27}{sh -}
4068 PRINT"{cm z}{sh asterisk*27}{cm x}{home}{down*6}{right}";
4070 OPEN1,1,1,a$:PRINT"{home}{down*7}{sh -}ok":b$=CHR$(13)
4080 PRINT#1,kn$b$ki$b$kf$b$ba$b$ko$b$kt$
4090 PRINT#1,z
4100 FORi=1TOz
4110 : PRINT#1,s(i)b$t$(i)b$t(i)b$y(i)b$m(i)b$d(i)
4120 NEXT:PRINT"{home}{down*3}{right}{space*18}"
4130 CLOSE1:SYS49440:RETURN
5000 SYS49408:PRINT"{clear}{down*2}{cm a}{sh asterisk*18}{cm s}
5010 PRINT"{sh -}saldo:{space*12}{sh -}{left*12}"s(z)
5020 PRINT"{cm z}{sh asterisk*18}{cm x}{home}databudget. nya transaktioner.sluta:0
5030 PRINT"{home}{down*7}{right}datum:"TAB(11)"text:"TAB(22)"trans:"TAB(32)"saldo:"
5035 IFz=0THENPRINTTAB(32)"0":GOTO5050
5040 FORi=1TOz:PRINTMID$(STR$(10000+y(i)),3)"-"MID$(STR$(100+m(i)),3)"-";
5045 PRINTMID$(STR$(100+d(i)),3)TAB(11)t$(i)TAB(21)t(i)TAB(31)s(i):NEXT
5050 PRINT"komma mellan ]r,m]n,dat:":z=z+1
5055 IFz>1000THENz=1000:GOTO5140
5060 INPUTy(z),m(z),d(z):IFy(z)=0THENz=z-1:GOTO5130
5062 PRINT"{up*2}text? (max 10 tecken):{space*2}"
5064 INPUT"{space*13}{left*4}";t$(z):t$(z)=LEFT$(t$(z),10)
5070 PRINT"{up*2}ange transaktionens storlek:
5080 INPUT"(naturligtvis i kr){space*3}{left*2}";t(z)
5090 PRINT"{up*2}{space*28}"
5091 PRINT"{space*39}"
5100 s(z)=s(z-1)+t(z)
5105 PRINT"{up*2}"MID$(STR$(10000+y(z)),3)"-"MID$(STR$(100+m(z)),3)"-";
5106 PRINTMID$(STR$(100+d(z)),3)TAB(11)t$(z)TAB(21)t(z)TAB(31)s(z)
5110 IFs(z)<=0THENPRINT"*** varning *** {pound}verbelastat konto ***
5115 IFz=1000THEN5140
5120 PRINT"st[mmer det?":POKE198,0:WAIT198,1:GETa$
5122 PRINT"{up}{space*12}{up}":IFa$="n"THENz=z-1
5124 GOTO5050
5130 PRINT"{home}";:SYS49440:RETURN
5140 PRINT"{home}{down}{cm a}{sh asterisk*34}{cm s}
5150 PRINT"{sh -}slut p] minne. jag f{pound}resl]r att du{sh -}
5160 PRINT"{sh -}sparar kontot och sedan f{pound}rkortar {sh -}
5170 PRINT"{sh -}det. tryck *return* s] ]terg]r jag{sh -}
5180 PRINT"{sh -}till huvudmenyn.{space*18}{sh -}
5190 PRINT"{cm z}{sh asterisk*34}{cm x}
5200 GETa$:IFa$<>CHR$(13)THEN5200
5210 SYS49440:RETURN
6000 PRINT"{home}{down}{cm a}{sh asterisk*10}{cm s}
6010 PRINT"{sh -}nytt konto{sh -}
6020 PRINT"{cm z}{sh asterisk*10}{cm x}
6030 PRINT"{home}{down*4}{cm a}{sh asterisk*29}{cm s}
6040 PRINT"{sh -}{space*29}{sh -}
6050 PRINT"{sh -}{space*29}{sh -}
6060 PRINT"{cm z}{sh asterisk*29}{cm x}
6070 RESTORE:z=.:s(.)=.
6080 READa$:IFa$<>"nykont"THEN6080
6105 READa$,a,x$:IFa$="slut"THENRETURN
6110 PRINT"{home}{down*5}{sh -}mata in{space*22}{sh -}"
6120 PRINT"{up}{right*9}";a$":
6130 PRINT"{sh -}?{space*28}{sh -}{up}
6140 PRINT"{right*3}{reverse on}";:FORi=1TOa:PRINT" ";:NEXT:PRINT
6150 PRINT"{up}{right}";:INPUTy$
6160 FORi=aTO1STEP-1:IFMID$(y$,i,1)=" "THENNEXT
6165 y$=LEFT$(y$,i)
6170 IFx$="kn"THENkn$=y$
6180 IFx$="ki"THENki$=y$
6190 IFx$="kf"THENkf$=y$
6200 IFx$="ba"THENba$=y$
6210 IFx$="ko"THENko$=y$
6220 IFx$="kt"THENkt$=y$
6230 GOTO6105
7000 SYS49408:PRINT"{home}{down}{cm a}{sh asterisk*37}{cm s}
7010 PRINT"{sh -}tryck space f{pound}r forts. return stoppar{sh -}
7020 PRINT"{sh -}datum:{space*5}text:{space*6}trans: saldo:{space*2}{sh -}
7025 PRINT"{sh -}{space*37}{sh -}{up}
7026 IFz=0THENPRINTTAB(29)0:GOTO7120
7030 FORi=1TOz:PRINT"{sh -}"MID$(STR$(10000+y(i)),3)"-"MID$(STR$(100+m(i)),3)"-";
7040 PRINTMID$(STR$(100+d(i)),3)TAB(12)t$(i)TAB(22)t(i)TAB(29)s(i)TAB(38)"{sh -}
7050 IFi<zTHEN7070
7060 PRINT"{sh -}{space*8}tryck return f{pound}r meny{space*8}{sh -}
7070 PRINT"{cm z}{sh asterisk*37}{cm x}
7080 GETa$:IFa$=CHR$(13)THENPRINT"{clear}":SYS49440:RETURN
7090 IFi<zANDa$=" "THENPRINT"{up}{sh -}{space*37}{sh -}{up}"
7100 IFa$<>" "THEN7080
7110 NEXT:PRINT"{clear}":SYS49440:RETURN
7120 PRINT"{sh -}{space*8}tryck return f{pound}r meny{space*8}{sh -}
7130 PRINT"{cm z}{sh asterisk*37}{cm x}
7140 GETa$:IFa$=CHR$(13)THENPRINT"{clear}":SYS49440:RETURN
7150 GOTO7140
8000 PRINT"{home}{down}{right*3}{cm a}{sh asterisk*14}{cm s}
8010 PRINT"{right*3}{sh -}f{pound}rkorta konto{sh -}
8020 PRINT"{right*3}{sh -}[r du s[ker{?*3}{sh -}
8030 PRINT"{right*3}{sh -}{space*14}{sh -}
8040 PRINT"{right*3}{sh -}{space*14}{sh -}
8045 PRINT"{right*3}{sh -}{space*14}{sh -}
8050 PRINT"{right*3}{cm z}{sh asterisk*14}{cm x}
8060 GETa$:IFa$<>"j"ANDa$<>"n"THEN8060
8070 IFa$="n"THENPRINT"{sh -}nej{space*11}{sh -}":RETURN
8080 PRINT"{home}{down*4}{right*3}{sh -}ja{space*12}{sh -}
8090 PRINT"{right*3}{sh -}f{pound}rkortar{.*5}{sh -}
8100 PRINT"{right*3}{sh -}var god v[nta.{sh -}
8110 y(1)=y(z):m(1)=m(z):d(1)=d(z):s(1)=s(z):t(1)=t(z)
8120 FORi=2TOz:y(iu=0:m(i)=0:d(i)=0:s(i)=0:t(i)=0:NEXT:z=1
8130 RETURN
9000 PRINT"{home}{down*2}{right}{cm a}{sh asterisk*24}{cm s}
9010 PRINT"{right}{sh -}vill du verkligen sluta?{sh -}
9020 PRINT"{right}{cm z}{sh asterisk*24}{cm x}
9030 GETa$:IFa$="j"THENPRINT"{clear}";:END
9040 IFa$="n"THENRETURN
9050 GOTO9030
60000 ON(PEEK(49408)=162)+1GOSUB60040:IFPEEK(49152)=120THENSYS49152:RETURN
60001 PRINT"{clear}{ct n}{white}PLEASE WAIT. Reading swedish characters."
60002 READy:IFy=>0THENPOKE49152+a,y:s=s-y*(a<178):a=a+1:GOTO60002
60003 IFs-23434THENPRINT"fel i data!":STOP
60004 SYS49152:RETURN
60005 DATA120,169,51,133,1,160,0,185
60006 DATA0,208,153,0,240,200,208,247
60007 DATA238,9,192,238,12,192,208,239
60008 DATA169,208,141,9,192,169,240,141
60009 DATA12,192,169,55,133,1,32,45
60010 DATA192,88,76,68,229,173,2,221
60011 DATA9,3,141,2,221,173,0,221
60012 DATA41,252,141,0,221,169,200,141
60013 DATA136,2,169,45,141,24,208,169
60014 DATA8,133,44,32,139,192,169,89
60015 DATA141,24,3,169,192,141,25,3
60016 DATA96,72,138,72,152,72,169,127
60017 DATA141,13,221,32,188,246,32,225
60018 DATA255,32,163,253,32,24,229,160
60019 DATA3,185,48,253,153,20,3,136
60020 DATA16,247,160,25,185,54,253,153
60021 DATA26,3,136,16,247,32,45,192
60022 DATA108,2,160,160,23,185,178,192
60023 DATA153,216,240,153,216,250,73,255
60024 DATA153,216,244,153,216,254,136,16
60025 DATA236,160,23,185,202,192,153,216
60026 DATA248,73,255,153,216,252,136,16
60027 DATA242,96
60028 DATA102,24,60,102,126,102,102,0
60029 DATA102,60,102,102,102,102,60,0
60030 DATA60,102,60,102,126,102,102,0
60031 DATA102,0,60,6,62,102,62,0
60032 DATA102,0,60,102,102,102,60,0
60033 DATA60,102,60,6,62,102,62,0,-1
60040 READa$:IFa$<>"scopy"THEN60040:DATAscopy
60041 FORi=49408TO49471:READa:POKEi,a:NEXT:RESTORE:a=0:RETURN
60042 DATA162,0,189,0,200,157,0,4,189,0,201,157,0,5,189,0,202,157,0,6,189,0
60043 DATA203,157,0,7,232,224,0,208,227,96
60044 DATA162,0,189,0,4,157,0,200,189,0,5,157,0,201,189,0,6,157,0,202,189,0
60045 DATA7,157,0,203,232,224,0,208,227,96
60100 DATAnykont
60101 DATAkontonummer,20,kn,innehavare,21,ki,kontoform,22,kf,bank(ej kontor),27
60102 DATAba,kontor(ort),15,ko,kontor(tele),10,kt,slut,,
stop tok64
(bastext 1.0)