start tok64 d64-aQEYcT
1 PRINTCHR$(142)CHR$(9)"{black}{clear}"TAB(5)"{down}omvandlare av jerry sandstedt."
2 POKE53280,12:POKE53281,12:PRINTTAB(5)"{cm t*30}{down}"
3 DIMd(200)
4 PRINT"vilken bas har du{space*5}(2-36): ";
5 GOSUB24:PRINT
6 a=INT(c):IFa<2ORa>36THENRUN
7 PRINT"vilken bas vill du ha (2-36): ";
8 c=0:d=0:e=0:GOSUB24:PRINT
9 b=INT(c):IFb<2ORb>36THENRUN
10 PRINT"ditt tal med basen"aTAB(28)": ";
11 c=0:d=0:e=0:GOSUB33:PRINT
12 FORi=eTO1STEP-1:g=g+d(i)*a^(e-i):NEXTi:t=INT(g)
13 h=g/b:j=INT(h)
14 k=h-SGN(h)*INT(ABS(h)):k=k*b:k=k+.003*b:k=INT(k)
15 GOSUB17:IFj=0THEN20
16 g=j:GOTO13
17 IFk>9THENz$=z$+CHR$(INT(k+55))
18 IFk<10THENu$=STR$(k):u$=MID$(u$,2,1):z$=z$+u$
19 RETURN
20 PRINT"{down}svar ";:FORi=LEN(z$)TO1STEP-1:PRINTMID$(z$,i,1);:NEXTi
21 PRINT:IFa<>10ANDb<>10THENPRINT"{down}("t")"
22 GETa$:IFa$=""THEN22
23 RUN
24 REM subrutin f{pound}r koll av tangent-       bordet med siffror 0-9
25 GETa$:IFa$=""THEN25
26 IFASC(a$)=13THENRETURN
27 IFASC(a$)<48ORASC(a$)>57THEN25
28 e=e+1:IFe=3THENe=0:RETURN
29 d=ASC(a$)-48
30 IFe=1THENc=d
31 IFe=2THENc=c*10+d
32 PRINTa$;:GOTO25
33 REM subrutin f{pound}r koll av tangent-       bordet med siffror 0-9 + a-z
34 GETa$:IFa$=""THEN34
35 IFASC(a$)=13THENRETURN
36 y=ASC(a$):IFy<48ORy>90ORy<65ANDy>57THEN34
37 x=y-48:IFx>9THENx=x-7
38 IFx>=aTHEN34
39 PRINTa$;:e=e+1
40 d(e)=ASC(a$)-48:IFd(e)>9THENd(e)=d(e)-7
41 GOTO34
stop tok64
(bastext 1.0)