start tok64 d64-8V2knA
1 REM - this is the program called "personal finances" as of 9/19/87.  - rer
2 DIM x(50),y(50),d(75),z(50),m(50),e(75),a$(50),b$(75),p(30)
3 POKE 53280,16:POKE53281,16:PRINT"{green}"
5 s=54272:FOR sw=s TO s+24:POKE sw,0:NEXT sw:a$(1)="checkbook":j=1
7 GOTO470
10 POKE s+24,15
20 POKE s+24,15
30 POKE s+2,0
40 POKE s+3,0
50 POKE s+5,0
60 POKE s+6,240
70 RETURN
210 REM - loading data
230 IF j>1 OR  u OR bb OR ba THEN 460
290 OPEN 2,8,2,"@0:finances,s,r":u=0:bb=0
295 PRINT"{clear}{down*5}{right*2}{space*2}{right*7}loading data"
300 INPUT#2,j:INPUT#2,u:INPUT#2,bb:ba=bb:IF j=0 THEN j=1
310 IF u=0 AND j=1 AND ba=0 AND bb=0 THEN GOSUB7000:GOTO440
355 IFj=1 THEN a$(j)="checkbook":z(j)=bb:GOTO397
370 FOR n=1 TO j:INPUT#2,a$(n):NEXT n
380 FOR n=1 TO j
390 INPUT#2,x(n):INPUT#2,y(n):INPUT#2,z(n):INPUT#2,p(n):INPUT#2,m(n)
395 NEXT n
397 IF u=0 THEN 440
400 FOR n=1 TO u:INPUT#2,b$(n):NEXT n
410 FOR n=1 TO u
420 INPUT#2,d(n):INPUT#2,e(n)
430 NEXT n
440 CLOSE2
460 RETURN
470 GOSUB 2550
500 PRINT"{green}{clear}{down*2}{right*5}select by number"
510 PRINT"{down}{right*8}1. update accounts"
520 PRINT"{down}{right*8}2. review accounts"
530 PRINT"{down}{right*8}3. enter bills"
540 PRINT"{down}{right*8}4. review bills"
550 PRINT"{down}{right*8}5. pay bills"
560 PRINT"{down}{right*8}6. save"
570 PRINT"{down}{right*8}7. initiate accounts"
580 PRINT"{down}{right*8}8. close accounts"
590 PRINT"{down}{right*8}9. access check book"
592 PRINT"{down}{right*8}0. exit"
595 GOSUB 2620
600 GET y$:IF y$=""THEN 600
605 IF y$="0"THEN 62000
610 IF y$<"1" OR y$>"9"THEN 600
615 GOSUB210
620 ON VAL(y$) GOTO 720,1280,1690,1980,2280,1560,2870,3230,3560
720 REM - updating accounts
770 FOR n=1 TO j:GOSUB 840:NEXT
800 FOR n= 1 TO j:GOSUB 1110:NEXT
830 GOTO 470
840 IF m(n)<>0 THEN 970
845 IF a$(n)="checkbook"THEN 1020
850 GOSUB 2710
860 PRINT"{clear}{down*5}{right*5}account{space*4}";a$(n)
870 PRINT"{down}{right*5}dollars{space*3}";
875 IF z(n)<0 THEN PRINT" ";
876 PRINTz(n)
880 INPUT"{up}{right*14}";z(n)
960 GOTO 1090
970 GOSUB2710
980 PRINT"{clear}{down*5}{right*4}security{space*4}";a$(n)
990 PRINT"{down}{right*5} shares{space*3}";x(n)
1010 INPUT"{up}{right*14}";x(n)
1020 RETURN
1040 IF x$<>"y"THEN 1820
1090 REM
1110 IF m(n)=0 THEN 1250
1120 GOSUB 2710
1130 PRINT"{clear}{down*5}{right*4}security{space*4}";a$(n)
1140 PRINT"{down}{right*5} shares{space*3}";x(n)
1150 PRINT"{down}{right*5}$/share{space*3}";y(n)
1160 INPUT"{up}{right*14}";y(n)
1240 z(n)=.01*INT(x(n)*y(n)*100+.5)
1250 RETURN
1280 REM - summarizing accounts
1300 q=0:r=0
1320 PRINTCHR$(150)"{clear}{down*2}{right}{space*2}{right*3}account"," amount"CHR$(154)
1330 FOR n=1 TO j
1335 IF a$(n)="checkbook"THEN z(n)=ba
1340 IF p(n)=1 THEN 1380
1350 a5=z(n):GOSUB11000
1360 IF z(n)<>0 THEN PRINT"{space*2}{right*4}";a$(n);TAB(17);a6$
1370 GOSUB 2810:q=q+z(n)
1380 NEXT n
1390 a5=q:GOSUB11000
1400 PRINTCHR$(30)"{space*2}{right*4}subtotal";TAB(17);a6$CHR$(154)
1405 GOSUB2830
1410 FOR n=1 TO j
1420 IF p(n)=1 THEN 1440
1430 GOTO 1480
1440 a5=z(n):GOSUB11000
1450 PRINT"{space*2}{right*4}";a$(n);TAB(17);a6$
1470 GOSUB2810:r=r+z(n)
1480 NEXT n
1490 a5=r:GOSUB11000
1500 PRINTCHR$(30)"{space*2}{right*4}subtotal";TAB(17);a6$CHR$(150)
1505 GOSUB2830
1510 a5=q+r:GOSUB11000
1520 PRINT"{space*2}{right*4}total";TAB(17);a6$CHR$(30)
1525 GOSUB2844
1530 GET x$:IF x$=""THEN 1530
1540 GOTO 470
1560 PRINT"{clear}{down*5}{right*12}saving data"
1570 OPEN 2,8,2,"@0:finances,s,w"
1580 PRINT#2,j:PRINT#2,u:PRINT#2,ba
1590 FOR n=1 TO j:PRINT#2,a$(n):NEXT n
1600 FOR n=1 TO j
1610 PRINT#2,x(n):PRINT#2,y(n):PRINT#2,z(n):PRINT#2,p(n):PRINT#2,m(n)
1620 NEXT n
1625 IF u=0 THEN 1670
1630 FOR n=1 TO u:PRINT#2,b$(n):NEXT n
1640 FOR n=1 TO u
1650 PRINT#2,d(n):PRINT#2,e(n):PRINT#2
1660 NEXT n
1670 CLOSE2
1680 GOTO 470
1690 REM - entering bills
1715 ac$=""
1720 PRINT"{clear}{down*5}{right*5}account ";
1725 GOSUB 2710
1727 INPUT ac$
1730 IF ac$="" THEN 470
1760 PRINT"{down}{right*5}amount{space*2}";
1765 GOSUB 2710
1770 INPUT am
1790 PRINT"{down}{right*5}week{space*4}";
1795 GOSUB 2710
1797 INPUT we
1800 IF we>5 THEN 1710
1810 PRINT"{down*2}{right*8}ok? y/n?
1815 GOSUB2760
1820 GET x$:IF x$=""THEN 1820
1825 IF x$="n"THEN 1715
1830 IF x$<>"y"THEN 1820
1850 u=u+1
1860 b$(u)=ac$:d(u)=am:e(u)=we
1870 GOTO 1715
1980 REM - reviewing bills
2010 PRINT"{clear}{down*20}{right*5} if none enter '0'{up*21}"
2020 PRINT"{down*6}{right*8}which week?"
2025 GOSUB 2710
2030 GET x$:IF x$=""THEN 2030
2035 IF x$="0"THEN 470
2040 IF x$<"1" OR x$>"5"THEN 2030
2050 w=VAL(x$)
2090 PRINT"{clear}{down*5}{right*8}week{right*5}";w:PRINT
2100 t=0
2110 PRINT"{down}{right*4}account"," amount"
2120 FOR v=1 TO u
2130 IF e(v)<>w THEN 2190
2140 a5=d(v):GOSUB11000
2165 PRINT"{right*4}";
2170 PRINT b$(v);TAB(17);a5$:a5$=""
2175 GOSUB 2710:FOR tm=1 TO 300:NEXT
2180 t=t+d(v)
2190 NEXT v
2200 a5=t:GOSUB11000
2220 PRINT"{down}{right*4}total";TAB(17);a5$:a5$=""
2225 GOSUB 2760
2230 GET x$:IF x$=""THEN 2230
2240 IF x$="0"OR (x$>="1" AND x$=<"5")THEN2035
2270 GOTO 2020
2280 REM - paying bills
2290 GOSUB 2710
2300 INPUT"{clear}{down*5}{right*5}which week ";w
2310 IF w>5 THEN 2300
2320 we=w:wk=w
2340 FOR v=1 TO u
2350 IF e(v)<>w THEN 2480
2360 tp=tp+d(v)
2370 d(v)=0:e(v)=0:b$(v)=""
2400 cl=v
2410 FOR h=cl TO u
2420 b$(h)=b$(h+1):e(h)=e(h+1):d(h)=d(h+1)
2450 NEXT h
2460 u=u-1:v=v-1
2480 NEXT v
2490 GOTO 5200
2500 GOSUB 2810
2510 q=0:r=0
2530 RETURN
2550 GOSUB10
2552 PRINT"{clear}":FOR t=1 TO 50:NEXT t
2555 FOR n=1 TO 3
2557 POKEs+1,20:POKEs,169:POKE s+4,17
2559 FOR z=1 TO 75:NEXT z
2560 POKEs+4,16
2561 FOR t=1 TO 40:NEXT t
2563 NEXT n
2565 POKE s+1,16:POKE2,101:POKEs+4,17
2567 FOR z=1 TO 750: NEXT z:POKEs+4,16
2570 RETURN
2620 REM - music
2622 FOR n=1 TO 3
2624 POKEs+1,18:POKEs,104:POKE s+4,17
2626 FOR z=1 TO 75:NEXT z
2628 POKEs+4,16
2630 FOR t=1 TO 40:NEXT t
2632 NEXT n
2634 POKE s+1,15:POKE2,122:POKEs+4,17
2636 FOR z=1 TO 750: NEXT z:POKEs+4,16
2638 RETURN
2710 REM - music
2711 GOSUB10000
2712 FOR q=1 TO 3
2714 POKEs+1,20:POKEs,169:POKE s+4,65
2716 FOR z=1 TO 45:NEXT z
2718 POKEs+4,64
2720 FOR tm=1 TO 30:NEXT tm
2722 NEXT q
2724 POKE s+1,20:POKE2,169:POKEs+4,65
2726 FOR z=1 TO 100: NEXT z:POKEs+4,64
2730 RETURN
2760 REM - music
2761 GOSUB10000
2762 POKEs+1,24:POKEs,146:POKE s+4,65
2764 FOR z=1 TO 45:NEXT z
2766 POKEs+4,64
2768 FOR t=1 TO 30:NEXT t
2770 POKEs+1,21:POKEs,227:POKE s+4,65
2772 FOR z=1 TO 45:NEXT z
2774 POKEs+4,64
2776 FOR t=1 TO 30:NEXT t
2778 POKEs+1,20:POKEs,169:POKE s+4,65
2780 FOR z=1 TO 45:NEXT z
2782 POKEs+4,64
2784 FOR t=1 TO 30:NEXT t
2786 POKEs+1,18:POKEs,104:POKE s+4,65
2788 FOR z=1 TO 75:NEXT z
2790 POKEs+4,64
2792 FOR t=1 TO 30:NEXT t
2794 RETURN
2810 GOSUB10
2815 POKEs+1,16:POKEs,101:POKEs+4,17
2816 FOR z=1 TO 100:NEXT z
2817 POKEs+4,16
2820 RETURN
2830 GOSUB10
2831 POKEs+1,16:POKEs,101:POKEs+4,17
2832 FOR z=1 TO 200:NEXT z
2833 POKEs+4,16
2834 FOR t=1 TO 50:NEXT t
2835 POKEs+1,20:POKEs,169:POKEs+4,17
2836 FOR z=1 TO 200:NEXT z
2837 POKEs+4,16
2838 FOR t=1 TO 50:NEXT t
2839 POKEs+1,24:POKEs,146:POKEs+4,17
2840 FOR z=1 TO 200:NEXT z
2841 POKEs+4,16
2842 FOR t=1 TO 50:NEXT t
2843 RETURN
2844 POKEs+1,21:POKEs,227:POKEs+4,17
2845 FOR z=1 TO100:NEXT z
2846 POKEs+4,16
2847 FOR t=1 TO 40:NEXT t
2848 POKEs+1,20:POKEs,169:POKEs+4,17
2849 FOR z=1 TO100:NEXT z
2850 POKEs+4,16
2851 FOR t=1 TO 40:NEXT t
2852 POKEs+1,18:POKEs,104:POKEs+4,17
2853 FOR z=1 TO100:NEXT z
2854 POKEs+4,16
2855 FOR t=1 TO 40:NEXT t
2856 POKEs+1,16:POKEs,101:POKEs+4,17
2857 FOR z=1 TO100:NEXT z
2858 POKEs+4,16
2859 FOR t=1 TO 40:NEXT t
2860 POKEs+1,18:POKEs,104:POKEs+4,17
2861 FOR z=1 TO100:NEXT z
2862 POKEs+4,16
2863 FOR t=1 TO 40:NEXT t
2864 POKEs+1,16:POKEs,101:POKEs+4,17
2865 FOR z=1 TO300:NEXT z
2866 POKEs+4,16
2867 RETURN
2870 REM - initiating accounts
2875 INPUT"{clear}{down*5}{right*5}account name{space*3}";x$
2880 ac$(nc)=ac$:am(nc)=am:ch(nc)=ch
2900 INPUT"{down}{right*3}stock or money{space*3}";y$
2910 IF y$<>"stock" AND y$<>"money"THEN PRINT"{up*3}":GOTO2900
2930 INPUT"{down}{right}retirement? y/n?{space*3}";z$
2935 z$=LEFT$(z$,1)
2940 IF z$<>"y"AND z$<>"n"THEN PRINT"{up*3}":GOTO 2930
2944 IF z$="y"THEN z$="long"
2945 IF z$="n"THEN z$="short"
2950 j=j+1
2960 FOR h=1 TO j
2970 IF a$(j-h)<x$ THEN 3050
2980 a$(j-h+1)=a$(j-h):x(j-h+1)=x(j-h):y(j-h+1)=y(j-h)
3010 z(j-h+1)=z(j-h):m(j-h+1)=m(j-h):p(j-h+1)=p(j-h)
3040 GOTO 3210
3050 a$(j-h+1)=x$
3070 IF y$="stock" THEN 3110
3080 INPUT"{down}{right*3}{space*7}dollars{space*3}";z(j-h+1)
3090 m(j-h+1)=0
3100 GOTO 3160
3110 INPUT"{down}{right*3}{space*8}shares{space*3}";x(j-h+1)
3120 m(j-h+1)=1
3140 INPUT"{down}{right*3} dollars/share{space*3}";y(j-h+1)
3150 z(j-h+1)=x(j-h+1)*y(j-h+1)
3160 IF z$="short"THEN 3190
3170 p(j-h+1)=1
3180 GOTO 470
3190 p(j-h+1)=0
3200 GOTO 470
3210 NEXT h
3220 GOTO 470
3230 REM - closing accounts
3240 INPUT"{clear}{down*5}{right*5}closed account{space*3}";x$
3250 FOR n=1 TO j
3260 IF a$(n)<>x$THEN 3350
3270 cl=n
3280 a$(n)="":x(n)=0:y(n)=0:z(n)=0:m(n)=0:p(n)=0:in=1
3350 NEXT n
3360 FOR n=cl TO j
3370 IF in=0 THEN 470
3380 a$(n)=a$(n+1):x(n)=x(n+1):y(n)=y(n+1):z(n)=z(n+1):m(n)=m(n+1):p(n)=p(n+1)
3440 NEXT n
3450 in=0
3460 j=j-1
3470 GOTO 470
3560 REM - accessing checkbook
3570 GOSUB 2550
3590 PRINT"{clear}{down*4}{right*5}select by number"
3600 PRINT"{down}{right*8}1. write checks"
3610 PRINT"{down}{right*8}2. make withdrawals"
3620 PRINT"{down}{right*8}3. make deposits"
3630 PRINT"{down}{right*8}4. enter adjustment"
3640 PRINT"{down}{right*8}5. enter service charge"
3650 PRINT"{down}{right*8}6. summarize"
3660 PRINT"{down}{right*8}7. exit"
3665 GOSUB2620
3670 GET x$:IF x$=""THEN 3670
3680 IF x$<"1" OR x$>"7"THEN 3670
3690 ON VAL(x$) GOTO 3700,3920,4100,4280,4440,4580,5200
3700 REM
3710 GOSUB 2710
3715 ac$=""
3720 INPUT"{clear}{down*5}{right*5}account{right*4}";ac$
3730 IF ac$=""THEN 3560
3740 GOSUB 2710
3760 INPUT"{down}{right*5}amount{right*4}";am
3780 GOSUB 2710
3790 INPUT"{down}{right*3}check no{right*4}";ch
3800 GOSUB 2760
3810 PRINT"{down*4}{right*7}ok? y/n"
3830 GET x$
3850 IF x$="n"THEN 3700
3860 IF x$<>"y"THEN 3830
3870 nc=nc+1
3880 ac$(nc)=ac$:am(nc)=am:ch(nc)=ch
3910 GOTO 3700
3920 REM
3930 GOSUB 2710
3935 da$=""
3940 INPUT"{clear}{down*5}{right}withdrawal date{right*3}";da$
3950 IF da$=""THEN 3560
3960 GOSUB 2710
3980 INPUT"{down}{right*2}{space*5}{right*3}amount{right*3}";am
4000 GOSUB 2760
4010 PRINT"{down*4}{right*3}{space*6}{right*4}ok? y/n"
4020 GET x$
4030 IF x$="n"THEN 3920
4040 IF x$<>"y"THEN 4020
4060 nw=nw+1
4070 da$(nw)=da$
4080 aw(nw)=am
4090 GOTO 3920
4100 REM
4110 GOSUB 2710
4115 da$=""
4120 INPUT"{clear}{down*5}{right}{space*3}deposit date{right*3}";da$
4130 IF da$=""THEN 3560
4140 GOSUB 2710
4160 INPUT"{down}{right*2}{space*5}{right*3}amount{right*3}";am
4170 GOSUB 2760
4190 PRINT"{down*4}{right*3}{space*6}{right*4}ok? y/n"
4200 GET x$
4210 IF x$="n"THEN 4100
4230 IF x$<>"y"THEN 4200
4240 nd=nd+1
4250 dd$(nd)=da$
4260 ad(nd)=am
4270 GOTO 4100
4280 REM
4290 GOSUB 2710
4300 ad=0
4310 INPUT"{clear}{down*5}{right*2}adjustment{right*4}";ad
4320 IF ad=0 THEN 3560
4340 GOSUB 2760
4350 PRINT"{down*4}{right*7}ok? y/n"
4360 GET x$
4380 IF x$="n"THEN 4280
4390 IF x$<>"y"THEN 4360
4400 na=na+1
4420 aa(na)=ad
4430 GOTO 4280
4440 REM
4450 GOSUB 2710
4455 se=0
4460 INPUT"{clear}{down*5}{right}serv charge{right*4}";se
4470 IF se=0 THEN 3560
4480 GOSUB 2760
4490 PRINT"{down*4}{right*7}ok? y/n"
4500 GET x$
4510 IF x$="n"THEN 4440
4540 IF x$<>"y"THEN 4500
4550 ns=ns+1
4560 as(ns)=se
4570 GOTO 4440
4580 REM - summarizing checkbook events
4590 ba=bb
4605 a5=ba:GOSUB11000
4610 PRINT"{clear}{down*2}{right*2}beginning balance";TAB(29);a5$
4615 GOSUB 2810
4620 PRINT"{right*2}checks:"
4625 IF nc=0THEN 4690
4630 ct=0
4640 FOR n=1 TO nc
4650 a5=am(n):GOSUB11000
4660 PRINT"{right*4}"ch(n);TAB(11);ac$(n);TAB(22);a5$
4665 GOSUB 2810
4670 ct=ct+am(n)
4680 NEXT n
4690 a5=ct:GOSUB11000
4700 PRINT"{right*6}total";TAB(29);a5$
4701 GOSUB 2810
4710 ba=ba-ct
4730 PRINT"{right*2}withdrawals:"
4740 wt=0
4745 IF nw=0THEN 4800
4750 FOR n=1 TO nw
4760 a5=aw(n):GOSUB11000
4770 PRINT" {right*4}"da$(n);TAB(22);a5$
4775 GOSUB 2810
4780 wt=wt+aw(n)
4790 NEXT n
4800 a5=wt:GOSUB11000
4810 PRINT"{right*6}total";TAB(29);a5$
4815 GOSUB 2810
4820 ba=ba-wt
4840 PRINT"{right*2}deposits:"
4845 IF nd=0 THEN 4910
4850 dt=0
4860 FOR n=1 TO nd
4870 a5=ad(n):GOSUB11000
4880 PRINT" {right*4}"dd$(n);TAB(22);a5$
4885 GOSUB 2810
4890 dt=dt+ad(n)
4900 NEXT n
4910 a5=dt:GOSUB11000
4920 PRINT"{right*6}total";TAB(29);a5$
4925 GOSUB 2810
4930 ba=ba+dt
4950 IF aa(1)=0 THEN 5010
4960 FOR n=1 TO na
4970 a5=aa(n):GOSUB11000
4980 PRINT"{right*2}adjustment";TAB(29);a5$
4985 GOSUB 2810
4990 ba=ba+aa(n)
5000 NEXT n
5010 IF as(1)=0 THEN 5060
5020 FOR n=1 TO ns
5030 a5=as(n):GOSUB11000
5040 PRINT"{right*2}serv charge";TAB(29);a5$
5045 GOSUB 2810
5050 ba=ba-as(n):NEXT n
5060 IF tp=0 THEN 5135
5090 a5=tp:GOSUB11000
5100 PRINT"{right*2}week";wk;"bills";TAB(29);a5$
5102 GOSUB 2810
5120 ba=ba-tp
5130 REM
5135 a5=ba:GOSUB11000
5140 PRINT"{down*2}{right*2}closing balance";TAB(29);a5$:ba=VAL(a5$)
5145 GOSUB2830:GOSUB2844
5150 GET x$:IF x$=""THEN 5150
5170 GOTO3560
5200 REM - totaling checkbook
5210 ba=bb
5220 IF nc=0THEN 5260
5230 FOR n=1 TO nc
5240 ba=ba-am(n)
5250 NEXT n
5260 IF nw=0THEN 5300
5270 FOR n=1 TO nw
5280 ba=ba-aw(n)
5290 NEXT n
5300 IF nd=0 THEN 5340
5310 FOR n=1 TO nd
5320 ba=ba+ad(n)
5330 NEXT n
5340 IF aa(1)=0 THEN 5380
5350 FOR n=1 TO na
5360 ba=ba+aa(n)
5370 NEXT n
5380 IF as(1)=0 THEN 5410
5390 FOR n=1 TO ns
5400 ba=ba-as(n):NEXT n
5410 ba=ba-tp
5420 GOTO470
6000 DATA 20,169,125,20,169,125,20,169,125,16,101,500
7000 REM - giving initial instructions
7020 PRINT"{clear}{down}{space*3}to initiate investment accounts hit"
7030 PRINT"7{right}on menu.{space*2}follow instructions.{space*2}"
7031 PRINT"status of accounts is updated (e.g."
7032 PRINT"current stock values are entered) by"
7033 PRINT"hitting 1.{space*2}hit 2 for tabular summary"
7034 PRINT"broken down into ira and non-ira "
7035 PRINT"assets."
7040 PRINT"{down}{right*3}to enter bills to be paid hit 3,"
7050 PRINT"computer will call{right}for account name,"
7060 PRINT"amount of bill and week number (1 - 5)"
7070 PRINT"in which it is to be paid.{space*2}bills are"
7080 PRINT"reviewed or paid by week number."
7090 PRINT"once paid, they are subtracted from"
7100 PRINT"the checkbook balance."
7110 PRINT"{down}{right*3}if your disc has its own 'menu'"
7120 PRINT"program, hit{right}9 to return to it."
7130 PRINT"{down}{right*3}hit any key to continue.{space*2}when the"
7135 PRINT"computer has data it no longer will"
7137 PRINT"screen this message."
7140 GET x$:IF x$=""THEN 7140
7150 RETURN
10000 POKE s+24,7
10030 POKE s+2,225
10040 POKE s+3,0
10050 POKE s+5,9
10060 POKE s+6,0
10070 RETURN
11000 a5$="":a6$="":l5=0:b5$="":a5$=STR$(a5)
11010 FOR n5=1 TO LEN(a5$)
11020 IF MID$(a5$,n5,1)="."THEN l5=n5
11030 NEXT n5
11040 IF l5=0 THEN l5=LEN(a5$)+1
11050 IF MID$(a5$,l5+1,2)=""THEN a5$=a5$+".00":GOTO11200
11060 IF MID$(a5$,l5+2,1)=""THEN a5$=a5$+"0":GOTO11200
11070 IF VAL(MID$(a5$,l5+3,1))<4THEN 11110
11078 a5=VAL(a5$):a5=a5+.01:a5$=STR$(a5):GOTO11110
11080 a5=ASC(MID$(a5$,l5+2,1))
11090 a5=a5+1 :b5$=CHR$(a5)
11100 a5$=LEFT$(a5$,l5+1)+b5$:GOTO11200
11110 a5$=LEFT$(a5$,l5+2)
11200 FOR n5=1 TO10-LEN(a5$):a5$=" "+a5$:NEXT n5
11205 a6=VAL(LEFT$(a5$,8)):IF ASC(RIGHT$(a5$,2))>52 THEN a6=a6+1
11206 a6$=STR$(a6)
11208 FOR n5=1 TO10-LEN(a6$):a6$=" "+a6$:NEXT n5
11210 RETURN
62000 REM - exiting
62010 PRINT"{clear}{down*5}{right*8}returning to menu{black}"
62040 PRINT"{down*5}"
62050 PRINT"load"CHR$(34)"menu"CHR$(34)",8{down*4}"
62060 PRINT"run":PRINT"{up*9}"
62070 POKE631,13:POKE 632,13:POKE 198,2:END
stop tok64
(bastext 1.0)