start tok64 d64-CSx5Rj
5 REM: namechanger by jim cooper
6 REM: qs! alliance
7 REM: box 1403
8 REM: new albany in 47150
9 :
10 in$="{space*16}":FORi=1TO3:in$=in$+in$:NEXT:in$=in$+LEFT$(in$,126)
20 in=828:FORi=in TOin+37:READn:POKEi,n:NEXT:FORr=1TO18:r$=r$+CHR$(160):NEXT
30 POKE53280,0:POKE53281,0:PRINT"{clear}{green}{space*5}namechanger from qs! alliance"
40 PRINTSPC(47)"{yellow}insert a disk in drive #8"SPC(19)"then press return"
50 GOSUB1000:IFv$<>CHR$(13)THEN50
60 PRINTSPC(46)"{light blue}please wait.{space*2}checking disk."
70 CLOSE15:OPEN15,8,15,"u;":PRINT#15,"i0":INPUT#15,er,em$,tk,sr
80 PRINTSPC(46)"{white}"er;em$,tk,sr:IFerTHEN999
90 PRINTSPC(43)"{light blue}please wait. getting header & id"
100 CLOSE1:OPEN1,8,2,"#":PRINT#15,"u1";2;0;18;0:SYSin
110 i1$=LEFT$(in$,144):n$=MID$(in$,145,18):d$=MID$(in$,163,3)
120 l$=MID$(in$,166,2):i2$=RIGHT$(in$,87)
130 PRINTSPC(46)"{pink}disk name : "n$:PRINTSPC(6)"disk i.d. : "d$
140 PRINTSPC(9)"status : ";:IFl$="2a"THENPRINT"unlocked ";l$
150 IFl$<>"2a"THENPRINT"locked ";l$
160 PRINT:INPUT"{yellow}enter new name :";nn$
170 INPUT"enter new i.d. :";nd$
180 INPUT"enter {reverse on}l{reverse off}ock or {reverse on}u{reverse off}nlock :";ul$
190 IFnn$=""THEN210
200 n$=LEFT$(nn$+r$,18)
210 IFnd$=""THEN230
220 d$=LEFT$(nd$+"++",2)+CHR$(160)
230 IFul$=""ORul$="u"THENl$="2a":GOTO250
240 l$="lk"
250 PRINTSPC(46)"{white}"n$" "d$" "l$
260 PRINTSPC(51)"{pink}okay?{space*2}{reverse on}y{reverse off}/{reverse on}n{reverse off} {?*3}"
270 GOSUB1000:IFv$="n"THEN130
275 IFv$<>"y"THEN270
280 PRINTSPC(46)"{light blue}please wait.{space*2}writing data."
290 PRINT#15,"b-p";2;0
300 PRINT#1,i1$+n$+d$+l$+i2$
310 PRINT#15,"u2";2;0;18;0
320 CLOSE1:CLOSE15:GOTO30
999 PRINT"{white}disk error.{space*2}program aborted.":STOP
1000 POKE198,0
1010 GETv$:IFv$=""THEN1010
1020 RETURN
3900 DATA 160,2,177,45,153,137,0
4000 DATA 200,192,6,208,246,162
4100 DATA 1,32,198,255,32,228,255
4200 DATA 164,142,145,140,200
4300 DATA 132,142,196,139,240,4,165
4400 DATA 144,240,234,76,204,255
4500 RETURN
stop tok64
(bastext 1.0)