start tok64 d64-1Uf4VU
10 SYS 51744
20 POKE53281,0:POKE53280,0:REM poke808,234
30 PRINT"{clear}{down*2}"
40 READn$:IFn$="end"THENRESTORE:GOTO110
50 mm=LEN(n$):IFmm/2<>INT(m/2)THENn$=" "+n$
60 nn=LEN(n$)
70 FORx=1TO(nn/2)
80 PRINTTAB(20-x)"{up}"MID$(n$,1,x)
90 PRINTTAB(20)"{up}"MID$(n$,nn+1-x,x)
100 NEXTx:PRINT:GOTO40
110 FORt=1TO2000:NEXT:POKE53281,1:POKE53280,1
120 DIM aa$(1100):n=0
130 PRINTTAB(8)"{reverse on}{brown}{down*3}{space*3}load old file? (y/n){space*2}"
140 GETof$:IFof$=""THEN140
150 IFof$="n"THEN230
160 IFof$="y"THEN180
170 GOTO 140
180 PRINTTAB(8)"{reverse on}{space*3}disk directory? (y/n) {blue}"
190 GETgg$:IFgg$=""THEN190
200 IFgg$="y"THEN2570
210 IFgg$="n"THEN1470
220 GOTO190
230 PRINT"{light blue}{clear}{reverse on}{space*11}word limit - 1{0*3}{space*12}";
240 PRINT"{reverse on} enter: {arrow left} to sort, {pound} for spelling check ":PRINT"{black}{down}"
250 m=n+1:IFm>99THENq=0
260 IFm=1001 THEN PRINT"{down}{reverse on}{red} file full {blue}":FORw=1TO2000:NEXT:GOTO340
270 IFm>9ANDm<100THENq=1
280 IFm<10THENq=2
290 GOSUB1800
300 IFa$="{arrow left}"THEN 340
310 IFa$="{pound}"THEN 1870
320 n=n+1
330 j=FRE(0):aa$(n)=a$:GOTO250
340 PRINT"{clear}{down*9}"TAB(6)"please wait{.*3}i'm thinking!"
350 SYS49152,n,aa$(1):GOTO 970
360 :
370 PRINT"{black}{down*2}{reverse on}f1{reverse off}-send to screen"
380 PRINT"{down*2}{reverse on}f3{reverse off}-send to printer"
390 GETgg$:IFgg$=""THEN390
400 IFgg$="{f3}"THENno$="":INPUT"{clear}{down*3}name of list";no$:GOTO490
410 IFgg$="{f1}"THENPRINT"{clear}{down*3}":GOTO430
420 GOTO 390
430 PRINT"{reverse on} hold down space bar to list{space*2}{down*4}":FORi=1TOn
440 PRINTaa$(i)
450 GETgg$:IFgg$=""THEN450
460 NEXTi:PRINT"{reverse on}{down*3}{black} that's all - hit return {blue}"
470 GETgg$:IFgg$<>CHR$(13)THEN470
480 GOTO 970
490 INPUT"{clear}{down*3} input left margin (0-12)";ta:IFta>12THEN490
500 PRINT"{clear}"TAB(6)"{down*5}make sure perforation is at"
510 PRINTTAB(9)"{down}the top of the ribbon"
520 PRINTTAB(8)"{down*4}push any key when ready"               "
530 GETgg$:IFgg$=""THEN530
540 OPEN15,4,15:CLOSE15
550 IFst=0THEN600
560 PRINTTAB(6)"{reverse on}{red}{down*2}{space*3}printer is not ready!{space*3}"
570 PRINTTAB(6)"{reverse on} hit any key and try again {blue}"
580 GETgg$:IFgg$=""THEN580
590 GOTO 490
600 CLOSE1:OPEN1,4:PRINT#1:PRINT#1,SPC(ta)no$" page 1":PRINT#1:FORx=1TO60
610 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
620 NEXT x
630 PRINT#1:PRINT#1:PRINT#1:IFn<121THEN890
640 PRINT#1:PRINT#1,SPC(ta)no$" page 2":PRINT#1:FORx=121TO180
650 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
660 NEXT x
670 PRINT#1:PRINT#1:PRINT#1:IFn<241THEN890
680 PRINT#1:PRINT#1,SPC(ta)no$" page 3":PRINT#1:FORx=241TO300
690 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
700 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<361THEN890
710 PRINT#1:PRINT#1,SPC(ta)no$" page 4":PRINT#1:FORx=361TO420
720 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
730 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<481THEN890
740 PRINT#1:PRINT#1,SPC(ta)no$" page 5":PRINT#1:FORx=481TO540
750 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
760 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<601THEN890
770 PRINT#1:PRINT#1,SPC(ta)no$" page 6":PRINT#1:FORx=601TO660
780 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
790 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<721THEN890
800 PRINT#1:PRINT#1,SPC(ta)no$" page 7":PRINT#1:FORx=721TO780
810 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
820 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<841THEN890
830 PRINT#1:PRINT#1,SPC(ta)no$" page 8":PRINT#1:FORx=841TO900
840 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
850 NEXT x:PRINT#1:PRINT#1:PRINT#1:IFn<961THEN890
860 PRINT#1:PRINT#1,SPC(ta)no$" page 9":PRINT#1:FORx=961TO1020
870 PRINT#1,SPC(ta)aa$(x)SPC(35-LEN(aa$(x)))aa$(x+60)
880 NEXT x:PRINT#1:PRINT#1:PRINT#1
890 PRINT"{clear}{reverse on}{pink}{down*2} another copy? (y/n){blue}"
900 GETac$:IFac$=""THEN900
910 IFac$="y"THEN370
920 PRINT"{clear}{reverse on}{dark gray}{down*2} save list on disk? (y/n){blue}"
930 GETss$:IFss$=""THEN930
940 IFss$="y"THEN PRINT"{clear}{down*2} enter file name (15 char.max.)"
950 IF ss$="y"THENPRINT"{down}{space*2}{R*15}":INPUTf$:IFLEN(f$)<16THEN1340
960 IFss$="y"ANDLEN(f$)>15THEN940
970 me$(1)="{space*11}print list{space*10}"
980 me$(2)="{space*7}add to / sort list{space*6}"
990 me$(3)=" check spelling / delete entry "
1000 me$(4)="{space*2}load file / start new list{space*3}"
1010 me$(5)="{space*9}exit program{space*10}"
1020 me$(6)="{space*11}save list{space*11}"
1030 me$(7)="{space*9}scratch a file{space*8}"
1040 me$(8)="{space*9}disk directory{space*8}"
1050 PRINT"{light blue}{clear}{down*2}":FORc=1TO8:PRINTTAB(5)me$(c):PRINT:NEXT:PRINT
1060 c=1
1070 PRINT"{red}{reverse on}{home}{down*3}"TAB(5)me$(c)
1080 GETg$:IFg$=""THEN1080
1090 IFg$="{down}"THEN 1120
1100 IFg$="{up}"ORg$="{right}"THEN 1150
1110 IFg$=CHR$(13)THEN1190
1120 c=c+1:IFc>8THENPRINTTAB(5)"{up}{reverse off}{light blue}"me$(c-1):GOTO  1060
1130 PRINTTAB(5)"{up}{reverse off}{light blue}"me$(c-1)
1140 PRINTTAB(5)"{red}{down}{reverse on}"me$(c):GOTO1080
1150 c=c-1
1160 IFc<1THENc=8:PRINTTAB(5)"{up}{reverse off}{light blue}"me$(1)
1170 IFc=8THENPRINT"{red}{reverse on}{home}{down*17}"TAB(5)me$(c):GOTO 1080
1180 PRINTTAB(5)"{up}{light blue}{reverse off}"me$(c+1):PRINTTAB(5)"{red}{up*3}{reverse on}"me$(c):GOTO1080
1190 :
1200 IFc=4THEN2220:REM start new list
1210 IFc=2THEN230:REM add to list
1220 IFc=3THEN1870:REM spelling check
1230 IFc=1THENPRINT"{cyan}{clear}{down*5}":GOTO370:REM print list
1240 IFc=5THEN1280:REM end
1250 IFc=6THEN920:REM save  list
1260 IFc=7THEN2280:REM scratch file
1270 IFc=8THEN2570:REM directory
1280 PRINT"{clear}{down*2} quit program? (y/n)"
1290 GETg$:IFg$=""THEN1290
1300 IFg$="y"THEN1330
1310 IFg$="n"THEN970
1320 GOTO 1290
1330 CLOSE1:SYS64738
1340 OPEN15,8,15:CLOSE15
1350 IFst=0THEN1400
1360 PRINT"{clear}"TAB(8)"{down*7}{reverse on}{red}{space*3}disk drive not ready{space*3}"
1370 PRINTTAB(8)"{reverse on}{red} hit any key to try again {blue}"
1380 GETgg$:IFgg$=""THEN1380
1390 GOTO 1340
1400 OPEN15,8,15,"s0:S"+f$:CLOSE15
1410 PRINT"{clear}{down*5} saving "f$:OPEN8,8,8,"@0:S"+f$+",s,w"
1420 PRINT#8,n
1430 FORt=1TOn
1440 PRINT#8,CHR$(34)+aa$(t)
1450 NEXT t
1460 CLOSE8:GOTO970
1470 PRINT"{clear}"
1480 PRINT"{reverse on}{down*3} enter file name ":GOSUB2150:no$=a$
1490 OPEN15,8,15:CLOSE15
1500 IFst=0THEN1550
1510 PRINT"{clear}"TAB(6)"{reverse on}{down*6}{space*4}drive is not ready{space*4}"
1520 PRINTTAB(6)"{reverse on} hit any key to try again "
1530 GETgg$:IFgg$=""THEN1530
1540 GOTO 1490
1550 OPEN15,8,15,"ui+":CLOSE15
1560 OPEN2,8,2,"0:S"+no$+",s,r"
1570 INPUT#2,r$
1580 IFr$<>""THENCLOSE2:PRINT"{reverse on}{clear}{down*3}loading: "no$:GOTO 1620
1590 CLOSE2
1600 OPEN15,8,15,"ui+":CLOSE15
1610 PRINT"{clear}{reverse on}{down*3}"no$" not found on this disk ":GOTO130
1620 OPEN8,8,8,"0:S"+no$+",s,r"
1630 INPUT#8,n:PRINT"{down*2}"n" records in file "
1640 PRINT"{down*2} loading record #":FORy=1TOn
1650 INPUT#8,aa$(y):PRINT"{up}"TAB(18)y
1655 IFLEN(aa$(y))>32THENaa$(y)=LEFT$(aa$(y),32)
1660 NEXT y
1670 CLOSE8:GOTO970
1680 DATA"{green}"
1690 DATA"U{sh asterisk*17}I"
1700 DATA"B{space*17}B"
1710 DATA"B{space*2}sort 'n sweet{space*2}B"
1720 DATA"B{space*5}64{space*2}v5{space*6}B"
1730 DATA"B{space*17}B"
1740 DATA"J{sh asterisk*17}K"
1750 DATA"{cyan}","* * * by: * * *","{light blue}"
1760 DATA"U{sh asterisk*15}I"
1770 DATA"B keith coleman B"
1780 DATA"J{sh asterisk*15}K"
1790 DATA end
1800 a$="":PRINTmTAB(6)"{cm p}"
1810 GETb$:IFb$=""ORb$="{home}"ORb$="{clear}"ORb$="{right}"ORb$="{left}"ORb$="{up}"ORb$="{down}"THEN1810
1820 IFLEN(a$)>0ANDb$=CHR$(20)THENa$=LEFT$(a$,LEN(a$)-1):GOTO1860
1830 IFLEN(a$)=0ANDb$=CHR$(20)THEN1810
1840 IFb$=CHR$(13)THENPRINT"{up}"mTAB(6)a$" ":RETURN
1850 a$=a$+b$:a=LEN(a$):IFa=32THENa$=LEFT$(a$,LEN(a$)-1)
1860 PRINT"{up}"mTAB(6)a$"{cm p} ":GOTO1810
1870 PRINT"{clear}{down*2} {reverse on}f1{reverse off}-search":PRINT"{down*2} {reverse on}f3{reverse off}-list all "
1880 GETg$:IFg$=""THEN1880
1890 IFg$="{f3}"THEN1920
1900 IFg$="{f1}"THEN 2360
1910 GOTO1880
1920 PRINT"{blue}{clear}{reverse on}{down*2}{space*2}record numbers of mispelled entries{space*3}";
1930 PRINT"{reverse on}{space*5}hold space bar to list records{space*5}"
1940 FORw=1TOn
1950 PRINTwTAB(6)aa$(w)
1960 GETg$:IFg$=""THEN1960
1970 NEXTw
1980 PRINT"{down*2}{reverse on} that's all "
1990 GETg$:IFg$<>CHR$(13)THEN1990
2000 PRINT"{clear}{down*2}{reverse on} are there any errors? (y/n) "
2010 GETg$:IFg$="y"THEN2040
2020 IFg$="n"THEN970
2030 GOTO 2010
2040 PRINT"{clear}{down*2}{reverse on} what is the number? {down}":GOSUB2150:mw$=a$
2050 mw=VAL(mw$):IFmw<1ORmw>nTHEN230
2060 PRINT"{down}"aa$(mw):PRINT"{down}{reverse on} enter the correct spelling here "
2070 PRINT"{reverse on}{space*2}enter '*' to delete entry "
2080 GOSUB2150:IFa$=""THEN 2110
2090 aa$(mw)=a$
2100 IFaa$(mw)="*"THENFORk=mwTOn-1:aa$(k)=aa$(k+1):NEXT:aa$(n)="":n=n-1
2110 PRINT"{reverse on}{down*2} are there any more? (y/n) "
2120 GETg$:IFg$="y"THEN2040
2130 IFg$="n"THEN970
2140 GOTO2120
2150 a$="":PRINT"{cm p}"
2160 GETb$:IFb$=""ORb$="{home}"ORb$="{clear}"ORb$="{left}"ORb$="{up}"ORb$="{down}"ORb$="{right}"THEN2160
2170 IFLEN(a$)>0ANDb$=CHR$(20)THENa$=LEFT$(a$,LEN(a$)-1):GOTO2210
2180 IFLEN(a$)=0ANDb$=CHR$(20)THEN2160
2190 IFb$=CHR$(13)THENPRINT"{up}"a$" ":RETURN
2200 a$=a$+b$:a=LEN(a$):IFa=32THENa$=LEFT$(a$,LEN(a$)-1)
2210 PRINT"{up}"a$"{cm p} ":GOTO2160
2220 :
2230 IFn=0THENCLR:PRINT"{clear}{down*3}":GOTO120
2235 PRINT"{blue}{clear}{down*2} this will erase list in memory-":PRINT" go ahead? (y/n)"
2240 GETg$:IFg$=""THEN2240
2250 IFg$="y"THENCLR:GOTO120
2260 IFg$="n"THEN970
2270 GOTO2240
2280 PRINT"{reverse on}{black}{clear}{down*2} enter file name to be scratched {down*2}":GOSUB 2150:sf$=a$
2290 PRINT"{down*2} scratch {reverse on} {left} "sf$" {reverse off} ?(y/n)"
2300 GETg$:IFg$=""THEN2300
2310 IFg$="y"THENOPEN15,8,15,"s0:S"+sf$:GOTO 2340
2320 IFg$="n"THEN 970
2330 GOTO2300
2340 INPUT#15,er,er$,t,s:CLOSE15
2350 PRINT"{down*3}"er", "er$","t","s:FORde=1TO2000:NEXT:GOTO970
2360 PRINT"{reverse on}{clear}{down*2} input search string{down*2}"
2370 GOSUB 2150:ss$=a$:le=LEN(ss$)
2380 PRINT"{clear}{down*2}{reverse on} searching{.*3} ":ct=1
2390 IFLEFT$(aa$(ct),le)=ss$THEN2430
2400 ct=ct+1
2410 IFct>nTHEN2540
2420 GOTO 2390
2430 PRINT"{clear}{down*2}"ct"{space*2}"aa$(ct)"{down*2}"
2440 PRINT"{reverse on}{space*3}enter correct spelling{space*14}"
2450 PRINT"{reverse on}{space*5}enter '*' to delete entry{space*9}"
2460 PRINT"{reverse on}{space*5}enter <return> to continue search "
2470 PRINT"{reverse on}{space*5}enter '@' to abort search{space*9}{down*2}"
2480 GOSUB 2150:te$=a$
2490 IFte$="*"THENFORk=ctTOn-1:aa$(k)=aa$(k+1):NEXT:aa$(n)="":n=n-1:GOTO2700
2500 IFte$=""THENPRINT"{clear}{reverse on}{down*2} searching{.*3} ":GOTO2400
2510 IFte$="@"THEN970
2520 aa$(ct)=te$
2530 GOTO 2400
2540 PRINT"{reverse on}{down*3} that's all - hit return "
2550 GETg$:IFg$=""THEN2550
2560 GOTO 970
2570 PRINT"{clear}{down*2}{reverse on} hit space bar to toggle list hold {down*2}":FORx=1TO1000:NEXT
2580 ::@"$:S*=s":PRINT"{down*2}{reverse on} hit any key "
2590 GETg$:IFg$=""THEN2590
2600 GOTO970
2700 PRINT"{clear}{down*2}{reverse on} searching{.*3} ":GOTO2390
stop tok64
(bastext 1.0)