start tok64 d64-5dEOO9
2 POKE45,255:POKE46,32:POKE47,255:POKE48,32:CLR:DIMd$(1600)
10 GOSUB200
11 PRINT:PRINTTAB(12);"your choice?":GETa:IFa=0ORa>7THENPRINT"{up*3}":GOTO11
12 POKEvc+21,0:ONaGOSUB14,51,46,49,59,80,73
13 GOTO10
14 p=0:q=i+1:OPEN2,8,15
15 PRINT"{clear}"
16 OPEN1,8,0,"$0"
17 GET#1,a$,b$
18 GET#1,a$,b$
19 GET#1,a$,b$
20 c=0
21 IFa$<>""THENc=ASC(a$)
22 IFb$<>""THENc=c+ASC(b$)*256
23 PRINTMID$(STR$(c),2);TAB(4);
24 GET#1,b$:IFst<>0THEN34
25 IFb$<>CHR$(34)THEN24
26 GET#1,b$:IF b$<>CHR$(34)THEN PRINTb$;:e$=e$+b$:GOTO26
27 GET#1,b$:IFb$=CHR$(32)THEN27
28 PRINTTAB(18);:c$=""
29 c$=c$+b$:GET#1,b$:IFb$<>""THEN29
30 PRINTTAB(25)LEFT$(c$,3);
31 IFst=0ANDc=0THENe$="":PRINT:GOTO18
32 IFst=0THENINPUT" {green}y{blue}/{red}n{blue}{space*3}y{left*3}";d$:IFd$="y"THENi=i+1:p=p+1:d$(i)=e$
33 e$="":GOTO18
34 PRINT" blocks free"
35 CLOSE1:CLOSE2
36 INPUT"{down}sort (y/n)";a$:IFa$="n"THEN38
37 SYS 4733,p,d$(q)
38 INPUT" disk no.";a$
39 FORj=e+1TOi
40 e$=d$(j)+"{space*42}":d$(j)=LEFT$(e$,18)+a$
41 NEXT:e=i:PRINT"insert next disk ({reverse on}return{reverse off}=finish)"
42 GETa$:IFa$=""THEN42
43 IFa$=CHR$(13)THEN45
44 GOTO14
45 i=i:RETURN
46 INPUT"{clear}filename";a$:i=i+1
47 OPEN2,8,2,"0:"+a$+",s,r":INPUT#2,e:FORj=iTOi+e:INPUT#2,d$(j):NEXT:CLOSE2
48 i=(i+e)-1:e=i:RETURN
49 INPUT"{clear}filename";a$
50 GOSUB 250:RETURN
51 PRINT"{clear}(e)dit or (s)ort ";:INPUT" e{left*3}";a$:IFa$="s"THEN58
52 FORj=1TOiSTEP23:PRINT"{clear}";:FORk=0TO22:PRINT(j+k);TAB(5)d$(j+k):NEXT
53 a$="n":INPUT"edit no.";a$:a=VAL(a$)
54 IFa<jORa>(j+k)ORa$="n"THENNEXT:RETURN
55 PRINT"{clear}";d$(a):OPEN1,0:PRINT"{home}";:INPUT#1,d$(a):CLOSE1:IFd$(a)=""THEN57
56 PRINT"{clear}":FORk=0TO22:PRINT(j+k);TAB(5)d$(j+k):NEXT:GOTO53
57 FORm=aTOi:d$(m)=d$(m+1):NEXT:i=i-1:GOTO56
58 SYS 4733,i,d$(1):RETURN
59 INPUT"{clear}(p)rinter or (s)reen{space*3}s{left*3}";a$
60 IFa$="p"THEN65
61 a$="":FORj=1TOiSTEP23:IFa$<>CHR$(13)THENPRINT"{clear}";:FORk=0TO22:PRINTd$(j+k):NEXT
62 IFa$<>CHR$(13)THENPRINT"{space*2}{reverse on}{black}spacebar{blue}{reverse off} = continue{space*4}{reverse on}{black}return{blue}{reverse off} = menu"
63 IFa$<>CHR$(13)THENGETa$:IFa$<>" "THEN63
64 NEXT:RETURN
65 INPUT"{clear}heading";a$:OPEN4,4
66 q=INT((80-LEN(a$))/2):q$=RIGHT$(STR$(q),2):PRINT#4,CHR$(16)+q$;
67 PRINT#4,a$:PRINT#4:l=60:m=i:GOSUB75
68 FORj=0TOi-1:jj=j*120:FORk=1TOl
69 PRINT#4,CHR$(16)+"10"+d$(jj+k)+CHR$(16)+"45"+d$(jj+k+l)
70 IF(2*k+jj)>iTHEN72
71 NEXTk:m=m-120:GOSUB75:FORk=1TO12:PRINT#4:NEXT:NEXTj
72 PRINT#4:CLOSE4:RETURN
73 PRINT"{clear}";:END
75 IFm<120THENl=INT(m/2):IFm/2<>lTHENl=l+1
76 RETURN
80 PRINT"{clear}{down*25}{reverse on} <space>=continue{space*2}<return>=menu "
81 SYS5678
82 GETa$:IFa$=CHR$(13)THENRETURN
83 GOTO82
100 a=2049
120 PRINTa,:PRINTPEEK(a+2)+256*PEEK(a+3)
130 b=PEEK(a)+256*PEEK(a+1):a=b:GOTO120
200 POKE53280,15:POKE53281,15:PRINT"{clear}{blue}":SYS6421
201 PRINTTAB(7);"**************************"
202 FORx=1TO6
203 PRINTTAB(7);"*{space*24}*":NEXTx
204 PRINTTAB(7);"**************************"
214 PRINTTAB(12);"{red}{down} total"i"names{blue}"
215 PRINTTAB(12);"{down}1. edit disks"
216 PRINTTAB(12);"2. edit names in memory"
217 PRINTTAB(12);"3. load names from disk"
218 PRINTTAB(12);"4. save names to disk"
219 PRINTTAB(12);"5. print names":PRINTTAB(12);"6. directory"
220 PRINTTAB(12);"7. quit":vc=53248
221 FORa=0TO3:POKE2040+a,128+a:POKEvc+1+2*a,69:NEXTa
222 POKEvc,91:POKEvc+2,142:POKEvc+4,190:POKEvc+6,238:POKEvc+23,15:POKEvc+27,15
223 POKEvc+29,15:POKEvc+21,15:POKEvc+39,0:POKEvc+40,2:POKEvc+41,2:POKEvc+42,2
230 RETURN
250 OPEN2,8,2,"0:n"+a$+",s,w":PRINT#2,i
260 FORj=1TOi:PRINT#2,d$(j):NEXT:CLOSE2
270 OPEN15,8,15,"s:"+a$:PRINT#15,"r:"+a$+"=n"+a$:CLOSE15
280 RETURN
stop tok64
(bastext 1.0)