start tok64 NIGHTMARE PLANET
1 GOTO3
2 SAVE"nightmare planet":STOP
3 REM mike grace 8307--
5 REM 831228
100 REM**
110 REM pre-credits
120 REM**
130 PRINT"{clear}":POKE53280,0:POKE53281,0
140 PRINT"{green}{down*3}in the far flung future {.*5}"
150 GOTO280
160 REM**
170 REM you're dead
180 REM**
190 POKEv+21,0:PRINT"{green}{down*2}Well, you blew it that time, didn't you "n$"!"
200 PRINT"{down}Luckily I have the power to revive you{space*2}and you can have";
210 PRINT" another go.":PRINT"{down}Would you like that? (y/n)"
220 GETr$:IFr$<>"y"ANDr$<>"n"THEN220
230 IFr$="y"THEN280
240 IFr$="n"THEN17570
250 REM**
260 REM variables
270 REM**
280 CLR:v=53248:sc=54272:bs=53280:bc=53281
290 pr=0:cv=0:sv=0:ev=0:qv=0:dv=0:es=2:nv=0:na=0:np=0:fv=0:rc=0:yy=0:hh=0:hr=0
300 vo=54296:w1=54276:a1=54277:s1=54278:w2=54283:a2=54284:s2=54285
310 w3=54290:a3=54291:s3=54292
320 h1=54273:l1=54272:h2=54280:l2=54279:h3=54287:l3=54286
330 REM**
340 REM sound effect
350 REM**
360 FORl=0TO24:POKEsc+l,0:NEXTl
370 POKEvo,15:POKEa1,255:POKEa2,255:POKEa3,255
380 POKEs1,255:POKE2,255:POKEs3,255
390 POKEw1,17:POKEw2,33:POKEw3,17
400 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
410 GOSUB35420
970 REM**
980 REM title
990 REM**
1000 POKEbs,0:POKEbc,0:PRINT"{clear}":ss=1024:cs=55296
1010 POKE53272,21
1020 FORi=1TO23
1030 POKEcs+40*i,4:POKEss+40*i,102
1040 POKEcs+40*i+38,4:POKEss+40*i+38,102
1050 NEXTi
1060 PRINT"{right}{156}{cm +*38}"
1070 PRINTTAB(11)"{down*3}{white}nightmare planet"
1080 PRINT"{right*5}{down*3}{green}an adventure in time and space"
1090 PRINT"{down*2}{right*5}{green}{sh -}"
1100 PRINT"{right*4}{reverse on}{sh pound} {cm asterisk}"
1110 PRINT"{right*4}{reverse on}B{sh +}B{reverse off}{space*23}{red}Q"
1120 PRINT"{right*4}{reverse on}{green}BQB"
1130 PRINT"{right*4}{reverse on}{green}BQB"
1140 PRINT"{right*3}{reverse on}{sh pound}BQB{cm asterisk}{reverse off}{space*4}{156}*"
1150 PRINT"{right*3}{green}{cm k}{reverse on}B{sh +}B{cm k}"
1160 PRINT"{right*3}{cm k}{reverse on}B{cm +}B{cm k}{reverse off}{space*27}{yellow}*"
1170 PRINT"{right*3}{green}{cm k}{reverse on}B{cm +}B{cm k}{reverse off}"
1180 PRINT"{right*3}{green}{cm k}{space*3}{reverse on}{cm k}{reverse off}"
1190 PRINT"{right}{down}{156}{cm +*37}"
1200 GOSUB35000
1210 FORm=1TO500
1220 NEXTm
1230 POKEvo,0
1270 REM**
1280 REM script
1290 REM**
1300 POKEbs,9:POKEbc,9
1310 PRINTCHR$(147):REM clear screen
1320 FORm=1TO100
1330 NEXTm
1340 POKE53272,23
1350 PRINTTAB(6)"{black}Alone in the control room of your spaceship you are ";
1360 PRINT"thinking of the girl{space*2}that you have been paid to transport"
1370 PRINT"safely to the planet Zen; the princess{space*2}who has secretly stolen ";
1380 PRINT"your heart but{space*2}who is promised to the cruel ruler of{space*3}Zen ";
1390 PRINT"in a marriage of diplomacy."
1400 PRINTTAB(6)"{down}But your mind is more on princess Aurora than your own ";
1410 PRINT"skill in piloting{space*2}your ship. Suddenly and without any{space*4}";
1420 PRINT" warning you warp into real space too{space*4}close to a mysterious ";
1430 PRINT"planet{space*2}- and are sucked into its gravitational pull."
1440 PRINTTAB(6)"{down}Perhaps your mind is not fully on your task - ";
1450 PRINT"perhaps the planet is too{space*3}strong.{space*2}Either way you cannot ";
1460 PRINT"control{space*2}your ship. As you slip into oblivion{space*4}your last ";
1470 PRINT"memory is the ground rushing{space*2}up to meet you {.*5}"
2000 REM**
2010 REM pregame
2020 REM**
2030 FORl=0TO24:POKEsc+l,0:NEXTl
2040 POKEvo,15:POKEa1,255:POKEa2,255:POKEa3,255
2050 POKEs1,128:POKEs2,128:POKEs3,128:POKEw1,65:POKEw2,129:POKEw3,129
2060 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
2100 PRINTTAB(11)"{down}Press 's' to start"
2110 GETa$:IFa$<>"s"THEN2110
2120 IFa$="s"THENPOKEvo,0
2130 FORm=1TO150:NEXTm
2160 REM crash
2170 FORl=0TO24:POKEsc+l,0:NEXTl
2180 POKEvo,15:POKEa1,140:POKEa2,140:POKEa3,140:POKEs1,0:POKEs2,0:POKEs3,0
2190 POKEw1,33:POKEw2,129:POKEw3,129
2200 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
2210 PRINT"{clear}":POKEbs,0:POKEbc,0
2220 PRINT"{down*2}{right*2}{down*2}{156}I think you may have crashed{!*4}"
2230 FORm=1TO1000:NEXTm
2240 PRINT"{down*3}{right*2}{green}Do you wish to load an existing game{space*4}from tape (y or n)?"
2250 GETa$:IFa$<>"y"ANDa$<>"n"THEN2250
2260 IFa$="y"THENPOKEvo,0:GOSUB16000
2270 PRINT"{green}{down*2}{right*2}Do you need instructions (y or n)?"
2280 GETa$:IFa$<>"y"ANDa$<>"n"THEN2280
2290 IFa$="y"THENPOKEvo,0:GOSUB15000
2300 POKEvo,0:GOSUB35100
2370 REM**
2380 REM victor
2390 REM**
2400 POKEbs,11:POKEbc,11:PRINT"{clear}{down*2}{light blue}Personal Robot Victor reporting:"
2410 PRINT"{down}Throughout this adventure I will be{space*5}here to help you {.*3}"
2420 PRINT"{down}I will tend to appear at moments of{space*5}great stress or danger!!"
2430 PRINT"But I will always be around, even when{space*2}you don't see me."
2440 INPUT"{down*2}Please input your name";n$
2450 GOSUB18000:PRINT"{down}Thanks "n$"! I'll see you around!"
2460 FORm=1TO1000:NEXTm
2470 PRINT"{clear}{down*2}{light blue}{reverse on}The Adventure begins {.*4}"
2480 FORm=1TO2000:NEXTm
2490 POKEv+21,0
3670 REM**
3680 REM objects data
3690 REM**
3700 FORi=1TO9:READob%(i),ob$(i),si$(i):NEXTi
3710 DATA15,rope,"There's a coil of rope lying on the{space*5}ground."
3720 DATA28,crystal,"The energy crystal sparkles as if with ahidden light."
3730 DATA37,nuts,"A few nuts are lying on the ground."
3740 DATA47,wreckage,"You see a piece of wreckage."
3750 DATA53,gem,"The sparkle of a small gem catches{space*6}your eye."
3760 DATA58,spacesuit,"Your spacesuit is here - still intact."
3770 DATA59,blaster,"Your blaster is lying on the ground."
3780 DATA69,knife,"Hidden among the pebbles lies a stone-{space*2}age knife."
3790 DATA92,"Aurora","You can see Aurora safe and sound."
3970 REM**
3980 REM p
3990 REM**
4000 p=59:GOTO4020
4010 p=p2
4020 IFp<11THENONpGOTO20000,20020,20080,20130
4030 IFp<21THENONp-10GOTO20170,20190,20210,20250,20310
4040 IFp<31THENONp-20GOTO0,20360,0,20380,20430,20480,0,20530
4050 IFp<41THENONp-30GOTO0,0,0,0,0,20570,20620,20670
4060 IFp<51THENONp-40GOTO0,20710,20730,20750,0,20770,20820,20870
4070 IFp<61THENONp-50GOTO0,20930,20950,21000,21040,21100,21150,21200,21390
4080 IFp<71THENONp-60GOTO0,21510,21530,21550,21600,0,21650,21700,21750
4090 IFp<81THENONp-70GOTO0,0,0,21800
4100 IFp<91THENONp-80GOTO0,0,0,21860
4110 IFp<101THENONp-90GOTO0,21910,21940,21970
4120 REM**
4130 REM see object
4140 REM**
4150 FORi=1TO9:IFob%(i)=pTHENPRINTsi$(i)
4160 NEXTi
4170 REM**
4180 REM peril pointers
4190 REM**
4200 IFp=24ANDsv<>2THEN30000
4210 IFp=28ANDev<>2THENGOSUB30500
4220 IFp=57ANDfv<>2ANDob%(6)<>-1THEN31000
4230 IFp=59ANDob%(2)<>-1THENGOSUB32000
4240 IFp=59ANDpr<>2THENGOSUB33240
4250 IFp=67ANDqv<>2THEN32600
4260 IFp=74ANDdv<>2THEN32700
4270 IFp=92ANDnv<>2ANDnp=0THEN33000
4280 IFp=92ANDnv<>2ANDnp=1THEN33060
4290 REM**
4300 REM directions
4310 REM**
4320 PRINT"{light blue}{down}You can go";
4330 IFn>0THENPRINT" north";
4340 IFe>0THENPRINT" east";
4350 IFs>0THENPRINT" south";
4360 IFw>0THENPRINT" west";
4970 REM**
4980 REM instruction
4990 REM**
5000 PRINTCHR$(13):x=FRE(0)
5010 INPUT"{cyan}Instructions:{right*2}*{left*3}";i$
5020 POKEv+21,0
5030 IFi$="*"THENPRINT"{up*2}":GOTO5010
5040 REM**
5050 REM loop eel
5060 REM**
5070 IFp=92THEN5290
5080 IFp=67THEN5200
5090 IFp<>28THEN6000
5100 IFev=2THEN6000
5110 IFp=28ANDes=2THEN6500
5120 q=q+1
5130 IFq<5THEN6000
5140 IFq=5THENPRINT"{green}You really {reverse on}are{reverse off} getting weaker {.*3}":GOTO5120
5150 IFq<>10THEN5170
5155 GOSUB19000:PRINT"{green}That's it "n$"!"
5160 PRINT"You have been crushed to death.":GOTO190
5170 REM**
5180 REM loop swamp
5190 REM**
5200 IFp=92THEN5290
5210 IFp<>67THEN6000
5220 IFqv=2THEN6500
5230 q=q+1
5240 IFq<5THEN6000
5250 IFq=5THEN13320
5260 REM**
5270 REM loop natives
5280 REM**
5290 IFp<>92THEN6000
5300 IFnv=2THEN6000
5310 IFp=92ANDpr=2THEN6500
5320 q=q+1
5330 IFq<5THEN6000
5340 IFq=5THENGOSUB18000:PRINT"{green}Keep trying "n$:PRINT"What next?":GOTO5320
5350 IFq=10ANDi$="kiss Aurora"THEN14030
5370 IFq<>10THEN5970
5375 GOSUB18000:PRINT"{green}Too late!{space*2}The natives have pushed you{space*2}";
5380 PRINT"outside the hut - but you can't take{space*4}Aurora ";
5390 PRINT"with you.{space*2}Better go away and{space*4}try to think how to ";
5400 PRINT"rescue her.":q=0:na=1:np=1:GOTO4320
5970 REM**
5980 REM no exits
5990 REM**
6000 IFp=24ANDsv<>2THEN6110
6010 IFp=28ANDes=2THEN6500
6020 IFp=28ANDev<>2THEN6110
6030 IFp=67ANDqv<>2THEN6110
6040 IFp=74ANDdv<>2THEN6170
6050 IFp=92ANDnv<>2ANDna=1THEN6500
6060 IFp=92ANDnv<>2ANDna=0THEN6110
6070 GOTO6500
6110 IFi$="n"ORi$="e"ORi$="s"ORi$="w"THENGOSUB19000:GOTO6130
6120 GOTO6150
6130 PRINT"{156}You can't escape that way!":PRINT"{156}You'll have to think of ";
6140 PRINT"{156}something else!":GOTO5000
6150 IFi$="run"THENGOSUB19000:PRINT"{156}There's no escape that way.":GOTO5000
6160 IFi$="walk"THENGOSUB19000:PRINT"{156}There's no escape that way.":GOTO5000
6170 IFi$<>"south"ANDi$<>"s"THEN6470
6175 GOSUB19000:PRINT"{156}No dice "n$"!"
6180 PRINT"{156}There's a dinosaur in the way!":GOTO5000
6470 REM**
6480 REM i$
6490 REM**
6500 IFi$="north"THENi$="n"
6510 IFi$="east"THENi$="e"
6520 IFi$="south"THENi$="s"
6530 IFi$="west"THENi$="w"
6540 IFi$="n"ORi$="e"ORi$="s"ORi$="w"THEN7070
6550 IFi$="i"ORLEFT$(i$,3)="inv"THEN10000
6560 IFi$="h"ORi$="help"THEN11000
6570 IFi$="instructions"THENGOSUB15000
6580 IFi$="run"ORi$="walk"THENGOSUB18000:PRINT"{156}Which way?":GOTO4320
6590 IFi$="l"ORLEFT$(i$,4)="look"THENGOSUB18000:GOTO6610
6600 GOTO6640
6610 IFp=28ANDyy=1THENPRINT"{green}You can't see much underwater!!":GOTO5000
6620 GOTO4020
6640 q$=LEFT$(i$,4)
6645 IF(q$="jump"ORq$="stru"ORq$="floa"ORq$="swim")ANDp=67THEN13310
6680 IFi$="eat"THENPRINT"What would you like to eat?":GOTO5000
6690 IFi$="open airlock"AND(p=57ORp=58)THEN7100
6710 q$=LEFT$(i$,4)
6715 IF(i$="go lake"ORq$="swim"ORq$="dive")ANDp=28ANDrc=2THEN30650
6740 IFi$="go lake"ANDp=28THEN30510
6750 IFi$="go shore"ANDp<>28THEN7810
6760 IFi$="go shore"ANDp=28THEN6780
6770 GOTO6800
6780 IFes=2THENGOSUB18000:GOTO20540
6790 IFes<>2THENGOSUB19000:GOTO6130
6800 q$=LEFT$(i$,4):IF(q$="swim"ORq$="dive")ANDp=28THEN30510
6820 IFLEFT$(i$,2)="go"THENGOSUB18000:PRINT"{156}Just type direction {.*3}":GOTO4320
6830 IFi$="get knotted"THENGOSUB19000:PRINT"{156}And you "n$"!":GOTO5000
6840 IFi$="save"THEN17000
6850 IFi$="quit"ORi$="end"THEN17500
6860 IFi$="climb"THENGOSUB18000:PRINT"{green}What do you suggest I climb?":GOTO5000
7000 IFi$<>"n"ANDi$<>"e"ANDi$<>"s"ANDi$<>"w"THEN7300
7040 REM**
7050 REM airlock
7060 REM**
7070 IFp=58ANDi$="w"THEN7100
7080 IFp=57ANDi$="e"THEN7100
7090 GOTO7200
7100 PRINT"{black}{down}Airlock opening {.*3}"
7110 FORl=0TO24:POKEsc+l,0:NEXTl
7120 POKEvo,15:POKEa1,17:POKEa2,17:POKEs1,130:POKEs2,130
7130 POKEw1,17:POKEw2,17:POKEh1,13:POKEl1,78:POKEh2,253:POKEl2,46
7140 FORt=1TO1500:NEXTt:PRINT"{up}{space*20}"
7150 FORt=1TO700:NEXTt:PRINT"{up}Airlock open {.*6}"
7160 FORt=1TO700:NEXTt:GOTO7200
7170 REM**
7180 REM movement
7190 REM**
7200 IFi$="n"ANDn>0THENp2=p-10:GOSUB18000:GOTO4010
7210 IFi$="e"ANDe>0THENp2=p+1:GOSUB18000:GOTO4010
7220 IFi$="s"ANDs>0THENp2=p+10:GOSUB18000:GOTO4010
7230 IFi$="w"ANDw>0THENp2=p-1:GOSUB18000:GOTO4010
7240 IFi$="open airlock"ANDp=58THENp2=p-1:GOSUB18000:GOTO4010
7260 GOSUB19000:PRINT"{156}{up}Sorry - but you can't go that way":GOTO4320
7270 REM**
7280 REM check i$ for space
7290 REM**
7300 FORi=1TOLEN(i$)
7310 IFMID$(i$,i,1)=" "THEN7340
7320 NEXTi
7330 PRINT"{green}Please can you use two words":GOSUB19000:GOTO5000
7340 FORi=1TOLEN(i$)
7350 IFMID$(i$,i,2)="{space*2}"THEN7380
7360 NEXTi
7370 GOTO7420
7380 PRINT"{156}Please leave {reverse on}one{reverse off} space between words":GOSUB19000:GOTO5000
7390 REM**
7400 REM i$-ve$ & no$
7410 REM**
7420 FORsp=pi+1TOLEN(i$)
7430 IFMID$(i$,sp,1)=" "THEN7450
7440 NEXTsp
7450 ve$=LEFT$(i$,sp-1)
7460 no$=RIGHT$(i$,LEN(i$)-sp)
7470 REM**
7480 REM ve$
7490 REM**
7500 IFve$="climb"THEN7920
7520 IF(ve$="get"ORve$="take"ORve$="grab")ANDp=28THEN32070
7560 IFve$="find"THENGOSUB18000:PRINT"{156}You'll have to look around.":GOTO5000
7570 IF(ve$="get"ORve$="take"ORve$="grab")ANDp=92THEN33120
7610 IFve$="get"ORve$="take"ORve$="grab"ORve$="carry"THEN11700
7620 IFve$="examine"THENGOSUB18000:GOTO7820
7630 IFve$="drop"ORve$="lose"ORve$="leave"ORve$="remove"THEN12000
7640 IFve$="kill"ORve$="smash"ORve$="destroy"ORve$="waste"THEN12300
7650 IFve$="eat"THEN31600
7660 IFve$="use"THEN11500
7670 IFve$="fire"THEN12700
7680 IFve$="shoot"ORve$="blast"THEN12300
7690 IFve$="stab"ORve$="cut"THEN12760
7700 IFLEFT$(ve$,3)="run"ORLEFT$(ve$,3)="wal"THENPRINT"{156}Which way?":GOTO4320
7710 IFve$="throw"ANDp=67THENGOSUB18000:GOTO13300
7720 IFve$="throw"THENGOSUB18000:GOTO7865
7730 IFve$="kiss"ANDp=92ANDno$="Aurora"THEN14000
7740 IFve$="kiss"ANDob%(9)=-1ANDno$="Aurora"THEN14210
7750 IFve$="kiss"THEN7810
7760 IFp<>92THEN7780
7770 IFve$="hug"ORve$="love"ORve$="cuddle"THEN7800
7780 IFve$="hug"ORve$="love"ORve$="cuddle"THEN7810
7790 GOTO7980
7800 GOSUB18000:PRINT"{green}That's not friendly enough.Try somethingelse.":GOTO5000
7810 GOSUB19000:PRINT"{156}You're acting a bit strange "n$:GOTO5000
7820 IFp=25ANDLEFT$(no$,3)="doo"THENPRINT"{156}Only an empty building{.*3}":GOTO5000
7830 IFp=28ANDno$="lake"THENPRINT"{156}The crystal is definitely there.":GOTO5000
7840 IFp=37ANDno$="bush"THENPRINT"{156}the nuts look edible.":GOTO5000
7850 IFp=37ANDno$="fruit"THENPRINT"{156}They look good to eat.":GOTO5000
7860 PRINT"{156}There's nothing helpful here.":GOTO5000
7865 IFno$="Victor"THENhr=2:GOTO11300
7870 FORi=1TO9:IFob$(i)=no$THEN7900
7880 NEXTi
7890 PRINT"{156}Stop fooling around!!":GOTO5000
7900 IFob%(i)=-1THENPRINT"{156}Can't see much point in that!!":GOTO12090
7910 PRINT"{156}You haven't got it!!":GOTO5000
7920 IFno$<>"tree"THEN7970
7930 IFp=42ORp=43ORp=44THEN32500
7940 IFp=52ORp=53ORp=54ORp=55THEN32520
7950 IFp=62ORp=63ORp=64ORp=65THEN32520
7960 IFp=74THEN13580
7970 GOSUB19000:PRINT"{156}You can't really climb "no$".":GOTO5000
7980 GOSUB19000:PRINT"{156}Sorry!{space*2}But I do not know how to ":PRINTve$".":GOTO5000
9970 REM**
9980 REM inventory
9990 REM**
10000 PRINT:PRINT"{156}Your inventory is:":iv=0
10010 FORi=1TO9
10020 IFob%(i)=-1THENPRINT"{green}"ob$(i):GOSUB18000:iv=iv+1
10030 NEXTi
10040 IFiv=0THENPRINT"{green}Nothing I'm afraid."
10050 GOTO5000
10970 REM**
10980 REM help
10990 REM**
11000 IFhr=2THEN11250
11005 IFp=24THENGOSUB35100:PRINT"{clear}":GOTO11090
11010 IFp=58THENGOSUB35100:PRINT"{clear}":GOTO11100
11020 IFp=67THENGOSUB35100:PRINT"{clear}":GOTO11120
11030 IFp=92THENGOSUB35100:PRINT"{clear}":GOTO11140
11040 IFp=1ORp=2ORp=11ORp=12ORp=22THENGOSUB35100:PRINT"{clear}":GOTO11190
11050 IFp=42ORp=62ORp=63THENGOSUB35100:PRINT"{clear}":GOTO11170
11060 GOSUB35100:PRINT"{clear}"
11070 PRINT"{light blue}I'm having a little circuit trouble{space*5}myself "n$"."
11080 PRINT"Try to cope on your own for a bit {.*3}":GOTO5000
11090 PRINT"{light blue}Try killing it "n$:PRINT"before it kills you!!":GOTO5000
11100 PRINT"{light blue}Now think hard "n$"!":PRINT"There must be something lying ";
11110 PRINT"around{space*4}that could help you {.*3}":GOTO5000
11120 PRINT"{light blue}Sticky situation this "n$".":PRINT"I suggest throwing something ";
11130 PRINT"to pull{space*4}yourself out.":GOTO5000
11140 PRINT"{light blue}As the natives think Aurora is their{space*4}queen{space*2}";
11150 PRINT"it might help if you showed them your quite ";
11160 PRINT"friendly with Aurora.":GOTO5000
11170 PRINT"{light blue}Lost in the forest, eh? Why don't you{space*3}climb a ";
11180 PRINT"tree and take a look around.":GOTO5000
11190 PRINT"{light blue}We both appear to be lost "n$".":PRINT"Better just ";
11200 PRINT"keep walking and you're sure tofind the way eventually.":GOTO4320
11250 GOSUB35100:PRINT"{clear}{light blue}We're not friends at the moment "n$".":GOTO11310
11280 GOSUB35100:PRINT"{clear}{light blue}You can't kill me "n$"."
11290 PRINT"{light blue}I'm the new invulnerable model. But {.*3}":GOTO11310
11300 GOSUB35100:PRINT"{clear}{light blue}That wasn't very nice "n$"."
11310 PRINT"I shan't {reverse on}help{reverse off} you anymore now."
11320 PRINT"You can cope on your own.":GOTO5000
11470 REM**
11480 REM use
11490 REM**
11500 IFp<>24ORp<>74ANDno$="blaster"THEN11580
11510 IFp<>24ORp<>74THEN11610
11520 IFp=24ORp=74ANDno$="blaster"THEN11580
11530 IFp=24ORp=74ANDno$="knife"THEN11550
11540 GOTO11660
11550 IFob%(8)<>-1THENGOSUB19000:PRINT"{156}You haven't got it!!":GOTO5000
11560 IFob%(8)<>-1THEN11580
11565 GOSUB35100:PRINT"{clear}{light blue}Just a knife "n$"?"
11570 PRINT"{light blue}That's a little ambitious isn't it?":GOTO5000
11580 IFob%(7)<>-1THENGOSUB19000:PRINT"{156}You haven't got it!!":GOTO5000
11590 IFp=24ANDob%(7)=-1THENGOSUB18000:PRINT"{156}Good thinking!":GOTO13030
11600 IFp=74ANDob%(7)=-1THENGOSUB35100:PRINT"{clear}{light blue}Good thinking!":GOTO13510
11610 FORi=1TO9
11620 IFob$(i)<>no$THEN11640
11630 IFob%(i)=-1THEN11660
11640 NEXTi
11650 GOSUB19000:PRINT"{green}There's no point in using that!":GOTO5000
11660 PRINT"{green}How do you want to use the "no$"?":GOSUB18000:GOTO5000
11670 REM**
11680 REM get
11690 REM**
11700 FORi=1TO9:IFob$(i)=no$THEN11740
11710 NEXTi
11720 IFp=37ANDno$="fruit"THEN11860
11730 IFob$(i)<>no$THEN11850
11740 IFob%(i)=-1THENPRINT"{green}You've already got it!!":GOSUB19000:GOTO5000
11750 IFp=37ANDno$<>"nuts"THEN11800
11760 IFp=37ANDno$<>"fruit"THEN11800
11770 IFp=37ANDno$="nuts"THEN11790
11780 GOTO11800
11790 IFp=37ANDz=1THEN11880
11800 IFob%(i)<>pTHENPRINT"{156}I don't see any "no$" here.":GOSUB19000:GOTO5000
11810 IFg<=4THEN11830
11815 PRINT"You are carrying too much - "
11820 PRINT"you had better drop something!!":GOSUB19000:GOTO5000
11830 PRINT"{green}Okay.":GOSUB18000:ob%(i)=-1:g=g+1
11840 GOTO5000
11850 GOSUB18000:PRINT"{156}I wouldn't bother doing that "n$"!!":GOTO5000
11860 IFz=1THEN11880
11870 GOTO11830
11880 GOSUB18000:PRINT"{156}Try just eating them "n$".":GOTO5000
11970 REM**
11980 REM drop
11990 REM**
12000 FORi=1TO9:IFob$(i)=no$THEN12040
12010 NEXTi
12020 IFp=28ANDno$="spacesuit"THENGOSUB19000:GOTO30510
12030 IFob$(i)<>no$THENGOSUB18000:PRINT"{156}No point in that.":GOTO5000
12040 IFob%(i)<>-1THENPRINT"{green}You haven't got it yet{!*3}":GOSUB19000:GOTO5000
12050 IFp=28ANDno$="spacesuit"THENGOSUB19000:PRINT"{156}You're sinking.":GOTO30540
12060 IFob%(6)=-1ANDno$="spacesuit"THEN31500
12070 IFp=59ANDno$="Aurora"THEN33350
12080 PRINT"{green}Okay.":GOSUB18000
12090 ob%(i)=p:g=g-1:GOTO5000
12270 REM**
12280 REM kill
12290 REM**
12300 IFno$="Aurora"THENGOSUB19000:PRINT"{reverse on}{yellow}You must be joking{!*3}":GOTO190
12305 IFno$="Victor"THENhr=2:GOTO11280
12310 IFp=24THEN13000
12320 IFp=28THEN12500
12330 IFp=74THEN13500
12340 IFp=92THEN13700
12350 GOSUB18000:PRINT"{green}I don't really see anything to "ve$".":GOTO5000
12470 REM**
12480 REM eel peril
12490 REM**
12500 IFve$="shoot"ORve$="blast"THEN12520
12510 IFob%(8)=-1THENPRINT"{green}Good. You used the knife.":GOSUB18000:GOTO12610
12520 IFob%(7)<>-1THEN12550
12525 GOSUB18000:PRINT"{156}Your blaster doesn't work underwater {.*3}";
12530 PRINT"and you'd better do something pretty{space*4}smartish {.*3}"
12540 PRINT"You are getting weaker {.*3}":GOTO5000
12550 PRINT"{black}The eel has you in its grip ans is{space*6}squeezing tighter ";
12560 PRINT"and tighter{.*4} you{space*3}are losing control of your senses{.*3}"
12570 FORm=1TO2000:NEXTm
12580 GOSUB19000:PRINT"{green}{down}Tough cookies!!{space*2}You're dead!"
12590 PRINT"{down}You should have brought something to{space*4}kill it with!!"
12600 GOSUB19000:GOTO190
12610 PRINT"{black}The eel thrashes wildly in its death{space*4}throes - then sinks to ";
12620 PRINT"the bottom of{space*4}the lake.":GOSUB18000
12630 PRINT"Don't forget the crystal {.*3}":ev=2:es=2:rc=0:yy=0:GOTO5000
12670 REM**
12680 REM fire/stab
12690 REM**
12700 IFp=24ANDob%(7)=-1ANDno$="blaster"THEN13030
12710 IFp=28ANDob%(7)=-1ANDno$="blaster"THEN12520
12720 IFp=74ANDob%(7)=-1ANDno$="blaster"THEN13510
12730 IFp=92ANDob%(7)=-1ANDno$="blaster"THEN13730
12740 IFno$="blaster"ANDob%(7)<>-1THENPRINT"{156}You haven't got it!":GOTO5000
12750 GOSUB1{120}000:PRINT"{green}That's not going to help you.":GOTO5000
12760 IFp=28ANDob%(8)=-1THEN12500
12770 IFno$="knife"ANDob%(8)<>-1THENPRINT"{156}You haven't got it!":GOTO5000
12780 GOTO12750
12970 REM**
12980 REM snake
12990 REM**
13000 IFob%(7)=-1THENPRINT"{green}Okay.":GOSUB18000:GOTO13030
13010 IFob%(8)=-1THENPRINT"{156}You've only got a knife - not enough!":GOTO5000
13020 PRINT"{156}You haven't anything to "ve$" it with{.*3}What now?":GOTO5000
13030 PRINT"{black}The snake crashes into a nearby house{space*3}sending clouds of ";
13040 PRINT"choking dust into the air as it dies."
13050 PRINT"{156}Luckily you had that blaster "n$:sv=2:GOTO4320
13270 REM**
13280 REM quicksand
13290 REM**
13300 IFob%(1)=-1ANDno$="rope"THENPRINT"{green}Smart move "n$".":GOTO13305
13302 GOTO7865
13305 PRINT"The rope catches on a tree and you haul yourself out.":qv=2:GOTO4320
13310 GOSUB19000:PRINT"{156}You aren't helping yourself that way{space*2}"n$".":GOTO5000
13320 PRINT"{156}You are sinking further and further!"
13330 FORm=1TO1000:NEXTm
13340 GOSUB19000:PRINT"Glug{.*3}{space*3}Glug{.*4}You've gone.":GOTO190
13470 REM**
13480 REM dinosaur
13490 REM**
13500 IFob%(7)=-1THENGOSUB18000:GOTO13540
13510 GOSUB19000:PRINT"{156}Although you fire repeatedly at the{space*5}beast - your ";
13520 PRINT"shots just bounce off its{space*2}armour-plated skin{!*4}"
13530 PRINT"What now "n$"?":GOTO5000
13540 PRINT"{green}You don't appear to have anything really";
13550 PRINT"substantial to kill a beast of that size";
13560 PRINT"I think you'll be able to dodge it and{space*2}keep ";
13570 PRINT"alive!!{space*2}But the problem is gettingpast!!":GOTO5000
13580 GOSUB35100:PRINT"{clear}{light blue}Smart move there "n$"."
13590 PRINT"Now you can swing through the trees ";
13600 PRINT"and get past.{space*2}You climb down again further along.":dv=2:GOTO4320
13670 REM**
13680 REM natives
13690 REM**
13700 IFob%(7)=-1THEN13730
13710 GOSUB18000:PRINT"{green}There are far too many for you to kill. Best try ";
13720 PRINT"another way.{space*2}Perhaps Aurora{space*3}could help {.*3}":GOTO5000
13730 GOSUB18000:PRINT"{green}Your blaster will take several hours to ";
13740 PRINT"recharge after the battle with the{space*6}dinosaur.";
13750 PRINT"{space*2}You must think of something{space*2}else.":GOTO5000
13970 REM**
13980 REM kiss princess
13990 REM**
14000 IFob%(6)=-1THENGOSUB19000:PRINT"{green}You can't kiss her wearing a spacesuit";
14010 IFob%(6)=-1THENPRINT"{space*2}can you?{space*2}I'd have thought you'd know{space*3}that!"
14020 IFob%(6)=-1THENPRINT"She's pointing at her mouth {.*3}":GOTO5000
14030 FORl=0TO24:POKEsc+l,0:NEXTl
14040 POKEl3,3:POKEw3,16:POKEsc+3,3:POKEvo,143:POKEs1,240:POKEsc+4,65
14050 fr=5389:FORt=1TO200:fq=fr+PEEK(sc+27)*225
14060 hf=INT(fq/256):lf=fq-hf*256
14070 POKEl1,lf:POKEh1,hf
14080 NEXTt
14090 PRINTCHR$(13)
14100 FORt=1TO5
14110 PRINT"{reverse on}{cyan}{up}TERRIFIC{reverse off} {reverse on}MAN{reverse off} {reverse on}{!*3}{reverse off}"
14120 FORm=1TO500:NEXTm
14130 PRINT"{up}{space*16}"
14140 FORm=1TO500:NEXTm
14150 NEXTt
14160 POKEvo,0
14170 PRINT"{green}That not only did you a power of good{space*3}but the natives ";
14180 PRINT"are smiling now. You canescape with Aurora.":nv=2:pr=2
14190 PRINT"{156}{down}Now you must return to the ship and{space*5}complete your ";
14200 PRINT"mission. Don't forget to{space*2}take Aurora!":GOTO4320
14210 GOSUB18000:PRINT"{cyan}Mm!{space*2}Nice. But you should keep ";
14220 PRINT"your mindon the game "n$:GOTO4320
14970 REM**
14980 REM instructions
14990 REM**
15000 POKEbs,11:POKEbc,11:PRINT"{clear}{black}{down}{space*12}{reverse on}Instructions{reverse off}"
15010 PRINT"{down}{right*2}{green}You are entering a world of fantasy{space*3}and adventure";
15020 PRINT" with your computer as yourguide. To solve this";
15030 PRINT" adventure you must give the computer commands: always"
15040 PRINT"a {cyan}verb{green} and in some cases a {cyan}noun{green}."
15050 PRINT"For example:- {light blue}get blaster {green}or {light blue}climb tree{green}."
15060 PRINT"{green}{right*2}{down}You will be given a description of thelocation you are ";
15070 PRINT"in and also the direct-ions in which you may move. You can only";
15080 PRINT"go {cyan}north{green}, {cyan}south{green}, {cyan}east{green} or {cyan}west{green}."
15090 PRINT"{down}{right*2}At times you may chance upon an objectwhich could be of use ";
15100 PRINT"to you later in{space*3}the game and you should pick it up (by{space*2}using ";
15110 PRINT"the word {cyan}'get'{green} or {cyan}'take'{green}).{space*2}This{space*2}will also apply to ";
15120 PRINT"{cyan}'getting'{green} your space-suit or {cyan}'getting'{green} the princess back."
15130 PRINTTAB(8)"{white}{reverse on}{down}Press any key to go on"
15140 GETa$:IFa$=""THEN15140
15150 PRINT"{clear}{green}{down}{right*2}You may also {cyan}'drop'{green} or {cyan}'remove'{green} an{space*4}object at any time ";
15160 PRINT"and that object will remain in that location for you to pick ";
15170 PRINT"up should you need it again."
15180 PRINT"{right*2}{green}Special key letters will save you{space*5}time. For example:-"
15190 PRINT"{light blue}{down}{right*2}{reverse on}n{reverse off} {reverse on}e{reverse off} {reverse on}s{reverse off} {green}or {light blue}{reverse on}w{reverse off} {green}will take you ";
15200 PRINT"{light blue}north{green}, {light blue}east{green}, {light blue}south{green} or {light blue}west{green}."
15210 PRINT"{right*2}{light blue}{reverse on}i{reverse off} {green}will display an {light blue}inventory {green}of objectsyou are carrying."
15220 PRINT"{right*2}{light blue}{reverse on}l{reverse off} {green}will let you {light blue}look{green} around."
15230 PRINT"{right*2}{light blue}{reverse on}h{reverse off} {pink}may {green}give you some {light blue}help {white}!!"
15240 PRINT"{right*2}{down}{green}Type {light blue}instructions{green} for the general{space*5}instructions printout."
15250 PRINT"{green}If you wish to {light blue}save{green} the game to cassettetype {light blue}save"
15260 PRINT"{green}If you wish to {light blue}end{green} the game type {light blue}quit"
15270 PRINT"{green}or {light blue}end{green}."
15280 PRINTTAB(8)"{white}{reverse on}{down}Press any key to go on"
15290 GETa$:IFa$=""THEN15290
15330 PRINT"{clear}{green}{down}A few hints:-":PRINT"{down}1. Stop to {light blue}save{green} your game frequently."
15340 PRINT"2. Try to draw a {light blue}map{green} as you explore the{space*4}planet."
15350 PRINT"3. Be selective in your {light blue}inventory{green} as you{space*3}can only carry a";
15360 PRINT" few objects at any{space*5}one time."
15370 PRINT"4. If you need help try {light blue}examining{green} things{space*3}as you go along."
15380 PRINT"5. Remember to type {light blue}instructions{green} if you{space*4}want to return to ";
15390 PRINT"these pages."
15400 PRINT"{green}{down}{right*2}Good luck in your search for princess Aurora";
15410 PRINT" and watch out for the natives!!"
15420 PRINT"{white}{reverse on}{down*2}{right*4}Press 'L' to return to the game"
15430 GETi$:IFi$<>"l"THEN15430
15440 IFi$="l"THENPRINT"{clear}":RETURN
15970 REM**
15980 REM load
15990 REM**
16000 PRINT"{clear}{down*2}{green}Place tape in recorder and rewind:"
16010 INPUT"Press {reverse off}RETURN{reverse off}:";q$
16020 OPEN1,1,0,"planet"
16030 INPUT#1,pr,cv,sv,ev,es,qw,dv,nv,fv
16040 INPUT#1,z,n$,m,i,p,n,e,s,w,i$,pi,sp
16050 INPUT#1,ve$,no$,g,p2,np,na,rc,yy,hh,hr
16060 FORi=1TO9:INPUT#1,ob%(i):NEXTi
16070 FORi=1TO9:INPUT#1,ob$(i):NEXTi
16080 FORi=1TO9:INPUT#1,si$(i):NEXTi
16090 CLOSE1
16100 GOSUB35420
16110 PRINT"{clear}":POKEbs,11:POKEbc,11:GOTO4020
16970 REM**
16980 REM save
16990 REM**
17000 PRINT"{clear}{down*2}{black}Are you sure you wish to save":PRINTTAB(15)"your game?"
17010 PRINT"{down}Press {reverse on}y{reverse off} or {reverse on}n{reverse off}:"
17020 GETa$:IFa$<>"y"ANDa$<>"n"THEN17020
17030 IFa$="n"THENPRINT"{clear}":GOTO4020
17040 INPUT"{down}Position tape then press {reverse on}RETURN{reverse off}:";q$:r$=CHR$(13)
17050 OPEN1,1,1,"planet"
17060 PRINT#1,pr;r$;cv;r$;sv;r$;ev;r$;es;r$;qv;r$;dv;r$;nv;r$;fv
17070 PRINT#1,z;r$;n$;r$;m;r$;i;r$;p;r$;n;r$;e;r$;s;r$;w;r$;i$;r$;pi;r$;sp
17080 PRINT#1,ve$;r$;no$;r$;g;r$;p2;r$;np;r$;na;r$;rc;r$;yy;r$;hh;r$;hr
17090 FORi=1TO9:PRINT#1,ob%(i):NEXTi
17100 FORi=1TO9:PRINT#1,ob$(i):NEXTi
17110 FORi=1TO9:PRINT#1,si$(i):NEXTi
17120 CLOSE1
17130 GOSUB35420
17140 PRINT"{clear}":GOTO4020
17470 REM**
17480 REM quit
17490 REM**
17500 POKEbs,2:POKEbc,2
17510 PRINT"{clear}":PRINTTAB(5)"{down*5}{reverse on}{white}Are you sure "n$"?":GOSUB19000
17520 PRINTTAB(5)"{down*2}Press {reverse on}c{reverse off} to {reverse on}c{reverse off}ontinue the game:"
17530 PRINTTAB(5)"{down}Press {reverse on}q{reverse off} to {reverse on}q{reverse off}uit the game:"
17540 GETa$:IFa$<>"c"ANDa$<>"q"THEN17540
17550 IFa$="q"THEN17570
17560 POKEbs,11:POKEbc,11:PRINT"{clear}":GOTO4020
17570 PRINT"{down}Okay.{down}":END
17970 REM**
17980 REM beep
17990 REM**
18000 FORl=0TO24:POKEsc+l,0:NEXTl
18010 POKEvo,15:POKEa1,17:POKEa2,17:POKEs1,64:POKEs2,64
18020 POKEw1,17:POKEw2,17:POKEh1,17:POKEl1,195:POKEh2,179:POKEl2,6
18030 FORt=1TO100:NEXTt:POKEvo,0
18040 RETURN
18970 REM**
18980 REM burp
18990 REM**
19000 FORl=0TO24:POKEsc+l,0:NEXTl
19010 POKEvo,15:POKEa1,17:POKEa2,64:POKEa3,17:POKEs1,128:POKEs2,128:POKEs3,128
19020 POKEw1,33:POKEw2,33:POKEw3,129
19030 POKEh1,189:POKEl1,172:POKEh2,7:POKEl2,233:POKEh3,1:POKEl3,119
19040 FORt=1TO200:NEXTt:POKEvo,0
19050 RETURN
19970 REM**
19980 REM locations
19990 REM**
20000 REM 1
20010 GOSUB22050:n=0:e=2:s=11:w=0:GOTO4150
20020 REM 2
20030 PRINT"{black}As you penetrate ever deeper a tiny{space*5}scrap of paper catches{space*2}";
20040 PRINT"your eye. In a{space*2}cleft in the wall is a message hastily{space*2}scrawled ";
20050 PRINT"in Aurora's handwriting. In theflickering gloom you ";
20060 PRINT"can just make out{space*2}the words {pink}eat nuts{black}."
20070 n=0:e=3:s=12:w=1:GOTO4150
20080 REM 3
20090 PRINT"{black}As you enter deeper and deeper into the heart of the ";
20100 PRINT"temple it becomes damp and wet. The walls are covered with ";
20110 PRINT"an evil-smelling slime that seemes to pulse witha malignant ";
20120 PRINT"light {.*3}":n=0:e=4:s=13:w=2:GOTO4150
20130 REM 4
20140 PRINT"{black}It's very dark inside the temple. The{space*3}ground is uneven ";
20150 PRINT"and several times you{space*2}stumble and fall.{space*2}A passage appears ";
20160 PRINT"to the west.":n=0:e=0:s=0:w=3:GOTO4150
20170 REM 11
20180 GOSUB22050:n=1:e=12:s=0:w=0:GOTO4150
20190 REM 12
20200 GOSUB22050:n=2:e=13:s=22:w=11:GOTO4150
20210 REM 13
20220 PRINT"{black}Inside the temple it is too dark to{space*5}see much. Passages ";
20230 PRINT"seem to stretch in{space*3}several directions.{space*2}Which way is best?"
20240 n=3:e=14:s=0:w=12:GOTO4150
20250 REM 14
20260 PRINT"{black}You are outside a building shaped like{space*2}a temple. ";
20270 PRINT"On the ground outside the doorare some marks ";
20280 PRINT"scratched in the dirt of the pathway.{space*2}It looks like an ";
20290 PRINT"arrow{space*4}pointing west into the temple."
20300 n=0:e=15:s=24:w=13:GOTO4150
20310 REM 15
20320 PRINT"{black}The scrabbling of taloned feet makes{space*4}you swirl - ready for ";
20330 PRINT"anything. But onlythe stones stand impassive - oblivious{space*2}";
20340 PRINT"to your fear.{space*2}Perhaps they are not deadbut only sleeping .."
20350 n=0:e=0:s=25:w=14:GOTO4150
20360 REM 22
20370 GOSUB22050:n=12:e=0:s=0:w=0:GOTO4150
20380 REM 24
20390 PRINT"{black}You have the impression something is{space*4}watching you from the ";
20400 PRINT"shadows.{space*3}In the silence you want to shout, to call out, to ";
20410 PRINT"do anything to make you feel there issomething alive in ";
20420 PRINT"this dead place.":n=14:e=25:s=0:w=0:GOTO4150
20430 REM 25
20440 PRINT"{black}The wind whistles a mocking, eerie tune between the stone ";
20450 PRINT"walls as you move pastempty doors and gaping windows.{space*2}Is this";
20460 PRINT"all that remains of civilisation here?"
20470 n=15:e=26:s=0:w=24:GOTO4150
20480 REM 26
20490 PRINT"{black}Inside the city you wonder where to{space*5}look!{space*2}If only ";
20500 PRINT"you could find a clue butthe crumbling walls of huge houses ";
20510 PRINT"blockany exploration apart from a hive of{space*4}alleys leading west."
20520 n=0:e=0:s=36:w=25:GOTO4150
20530 REM 28
20540 PRINT"{black}You are at the edge of the lake.{space*2}The{space*3}stones in the water ";
20550 PRINT"seem to be sparklingin the sunlight as if with a magic ";
20560 PRINT"powerof their own.":n=0:e=0:s=38:w=0:GOTO4150
20570 REM 36
20580 PRINT"{black}From here you can see quite clearly{space*5}that the towers and ";
20590 PRINT"spires are the{space*6}jagged ruins of a once-proud city now ";
20600 PRINT"{space*2}deserted by its former inhabitants."
20610 n=26:e=37:s=46:w=0:GOTO4150
20620 REM 37
20630 PRINT"{black}At last the sand is giving way to more{space*2}pebbles and stones -";
20640 PRINT" it must be the out-skirts of the desert.{space*2}There are ";
20650 PRINT"some{space*3}scrub-like bushes with fruit like coco- nuts hanging ";
20660 PRINT"from them.":n=0:e=38:s=47:w=36:GOTO4150
20670 REM 38
20680 PRINT"{black}You are still in the desert.{space*2}To the{space*4}north you can see ";
20690 PRINT"a lake.{space*2}To the east{space*2}the desert stretches to the horizon."
20700 n=28:e=0:s=38:w=37:GOTO4150
20710 REM 42
20720 GOSUB22110:n=0:e=43:s=52:w=0:GOTO4150
20730 REM 43
20740 GOSUB22070:n=0:e=44:s=53:w=42:GOTO4150
20750 REM 44
20760 GOSUB22110:n=0:e=0:s=54:w=43:GOTO4150
20770 REM 46
20780 PRINT"{black}Even though the sun is starting to burn a haze of ";
20790 PRINT"confusion into your brain -{space*3}on the north horizon gleam the ";
20800 PRINT"spires{space*3}and towers of a city. Or is it only a{space*3}mirage ";
20810 PRINT"to torment you??":n=36:e=37:s=56:w=0:GOTO4150
20820 REM 47
20830 PRINT"{black}As you trudge wearily across the burningsand you can";
20840 PRINT" see score marks where your ship crashed on landing. You ";
20850 PRINT"wonder how you managed to hold the ship together."
20860 n=37:e=46:s=57:w=46:GOTO4150
20870 REM 48
20880 PRINT"{black}You have been walking for hours now and can see";
20890 PRINT" no end to the vast expanse of{space*3}sand. In fact you know that ";
20900 PRINT"if you don'tturn back soon you will probably die{space*4}from ";
20910 PRINT"exposure under the sun which seems to hang motionless in the sky."
20920 n=38:e=0:s=0:w=47:GOTO4150
20930 REM 52
20940 GOSUB22070:n=42:e=53:s=62:w=0:GOTO4150
20950 REM 53
20960 PRINT"{black}You are in a small clearing amidst the{space*2}trees.{space*2}Soft moss-";
20970 PRINT"covered banks surroundan azure pool of silent, still ";
20980 PRINT"water andyou rest for a moment before continuing your ";
20990 PRINT"quest.":n=43:e=54:s=63:w=52:GOTO4150
21000 REM 54
21010 PRINT"{black}As you fight through brambles and thick foliage you catch ";
21020 PRINT"tantalising glimpses{space*2}of a clearing to the west - but you can-";
21030 PRINT"not seem to be able to get to it!!":n=44:e=55:s=64:w=0:GOTO4150
21040 REM 55
21050 PRINT"{black}You are just in the forest now, with{space*4}trees as thick as houses ";
21060 PRINT"towering into{space*2}the sky and blotting out the sun.{space*2}Small";
21070 PRINT"animals skitter and run around and aboveyou."
21080 PRINT"Two paths lead deeper - one to the southand one to the west."
21090 n=0:e=56:s=65:w=54:GOTO4150
21100 REM 56
21110 PRINT"{black}You are at the edge of the desert{space*2}-{space*4}for the sand soon ";
21120 PRINT"changes to scrub-like grass.{space*2}Towards the west ";
21130 PRINT"a huge forest{space*2}fills the skyline like a massive carpet of ";
21140 PRINT"green.":n=46:e=57:s=0:w=55:GOTO4150
21150 REM 57
21160 PRINT"{black}You are now outside your spaceship.{space*5}Around you lie the ";
21170 PRINT"scorch marks and{space*5}scarred charred fragments of your ship. You ";
21180 PRINT"have crashed in an arid desert of{space*3}purple sand."
21190 n=47:e=58:s=67:w=56:GOTO4150
21200 REM 58
21205 IFob%(2)=-1ANDob%(9)=-1THEN33280
21210 IFob%(2)<>-1THEN21240
21220 IFob%(2)=-1THENPRINT"{156}Great!{space*2}You've got the crystal.":cv=2
21230 PRINT"{156}Better just slip it into the pod in the main cabin.":GOTO21380
21240 IFpr=2ANDob%(9)=-1THEN21330
21250 IFhh=2THEN21270
21260 IFpr=2ANDob%(9)<>-1THEN21350
21270 PRINT"{black}You are in the airlock."
21280 IFpr=2THEN21380
21290 PRINT"{black}One of the spacesuits is missing. ";
21300 PRINT"On thefloor you see a small shred of cloth{space*4}which you ";
21310 PRINT"recognise as a piece of the{space*3}royal gown princess Aurora was ";
21320 PRINT"wearing{space*2}when you last saw her {.*3}":GOTO21380
21330 PRINT"{156}Back with Aurora - I should take her{space*4}into the main cabin ";
21340 PRINT"and give her a nice cup of tea!!":GOTO21380
21350 GOSUB19000:PRINT"{green}You forgot to {reverse on}get{reverse off} Aurora back in the ";
21360 PRINT"{space*3}native village "n$"."
21370 PRINT"Bit stupid that!! You'll have to go backfor her."
21380 n=0:e=59:s=0:w=57:GOTO4150
21390 REM 59
21400 IFcv=2ANDpr=2THEN33280
21410 IFcv=2ANDpr<>2THEN33400
21420 IFcv=0ANDpr=2THEN33460
21430 PRINT"{black}{down}You are in the cabin of your spaceship{space*2}and the crash has ";
21440 PRINT"emptied the contents{space*2}of your locker all over the floor."
21450 IFpr=2THEN21500
21460 PRINT"Even so you realise that there are the{space*2}signs of a struggle."
21470 PRINT"{down}{156}***The princess has gone!***"
21480 PRINT"{down}{black}The airlock dial registers that the air-lock has been ";
21490 PRINT"opened from the outside{space*3}and then resealed {.*3}"
21500 n=0:e=0:s=0:w=58:GOTO4150
21510 REM 62
21520 GOSUB22070:n=52:e=63:s=0:w=0:GOTO4150
21530 REM 63
21540 GOSUB22110:n=0:e=64:s=0:w=62:GOTO4150
21550 REM 64
21560 PRINT"{black}The forest is definitely too large for{space*2}you to ever find ";
21570 PRINT"your way out again, andyou are beginning to worry as well as ";
21580 PRINT"{space*2}beginning to wonder how you will ever{space*3}succeed."
21590 n=54:e=65:s=74:w=63:GOTO4150
21600 REM 65
21610 PRINT"{black}This path seems to be heading away{space*6}from the sun and into a ";
21620 PRINT" gloom{space*2}you{space*5}would never have thought possible in{space*4}the ";
21630 PRINT"daylight.{space*2}Behind you are heavy{space*5}rustlings, as though some ";
21640 PRINT"massive beast is following you.":n=55:e=0:s=0:w=64:GOTO4150
21650 REM 67
21660 PRINT"{black}The desert soon becomes lush with thick mauve vegetation";
21670 PRINT" that seems to thicken{space*2}with every step.{space*2}Better watch yourself ";
21680 PRINT"around here - the ground is starting to get very boggy."
21690 n=57:e=68:s=0:w=0:GOTO4150
21700 REM 68
21710 PRINT"{black}You are in swampland, hot, sticky and{space*3}unpleasant. ";
21720 PRINT"You can hear the roar of a{space*2}river, seemingly huge and rushing.";
21730 PRINT"{space*2}To{space*2}the east lies the river -{space*2}to the west{space*2}the swamp."
21740 n=0:e=69:s=0:w=67:GOTO4150
21750 REM 69
21760 PRINT"{black}It's so refreshing to sit on the bank{space*3}of the river and ";
21770 PRINT"dangle your steaming{space*3}feet in the ice-cold spray.{space*2}But the ";
21780 PRINT"{space*3}river is vast, like a churning sea to{space*3}the horizon.{space*2}It would ";
21790 PRINT"be impossible to cross.":n=0:e=0:s=0:w=68:GOTO4150
21800 REM 74
21810 PRINT"{black}You are on a road to the south of the{space*3}forest.{space*2}The smooth ";
21820 PRINT"polished surface{space*4}suggests it was made by a civilisation{space*2}far ";
21830 PRINT"superior to any you have known.{space*2}Butis this road still used {.*3} ";
21840 PRINT" or is it{space*3}just a relic of past glory?"
21850 n=64:e=0:s=84:w=0:GOTO4150
21860 REM 84
21870 PRINT"{black}The road winds on across the grasslands - stretching north ";
21880 PRINT"and south like some{space*2}huge ribbon tossed down by a giant ";
21890 PRINT"hand.On either side the vegetation closes in at times {.*3}"
21900 n=74:e=0:s=94:w=0:GOTO4150
21910 REM 92
21920 PRINT"{black}You are inside the mud hut.{space*2}Several{space*4}items of primitive ";
21930 PRINT"crockery crunch underyour feet.":n=0:e=93:s=0:w=0:GOTO4150
21940 REM 93
21950 PRINT"{black}You make you way through the village{space*4}hoping the natives ";
21960 PRINT"remain friendly.":n=0:e=94:s=0:w=92:GOTO4150
21970 REM 94
21980 PRINT"{black}You are in the outskirts of a native{space*4}village.{space*2}Mud huts ";
21990 PRINT"are scattered around in a haphazard fashion."
22000 IFpr<>2THEN22020
22010 GOTO22040
22020 PRINT"The village seems deserted, but you can hear a woman ";
22030 PRINT"singing sadly to herself ina hut."
22040 n=84:e=0:s=0:w=93:GOTO4150
22050 PRINT"{black}There's such a labyrinth of twists and{space*2}turns that you are";
22060 PRINT" getting just a littleafraid you are lost {.*3}":RETURN
22070 PRINT"{black}You must be lost in the forest.{space*2}You{space*4}keep catching glimpses of";
22080 PRINT" the clearing, sometimes to the east, sometimes the{space*4}south{.*3}";
22090 PRINT"and all the time the{space*2}noises of some fearsome beast echo and ";
22100 PRINT"vibrate in the foliage around you.":RETURN
22110 PRINT"{black}Some forest - this! You definitely{space*6}seem to be lost.";
22120 PRINT" Perhaps you should havestayed at home and never offered ";
22130 PRINT"to giveAurora a ride in your ship!":RETURN
29970 REM**
29980 REM snake
29990 REM**
30000 PRINT"{black}{down}Out of the ruins slithers a gigantic{space*4}snake - its body twice ";
30010 PRINT"the thickness of your own. It blocks your only exit.":GOTO5000
30470 REM**
30480 REM eel
30490 REM**
30500 PRINT"{down}{black}It is fairly deep in the water.":RETURN
30510 IFob%(6)<>-1THEN30540
30515 IFev=2THENGOSUB18000:PRINT"{156}Nice day for a dip!{space*2}What now?":GOTO4320
30520 IFob%(4)<>-1THEN30560
30530 GOTO30590
30540 GOSUB19000:PRINT"{156}You haven't got your spacesuit, have you"n$"."
30550 PRINT"Too bad!!{space*3}You've drowned!!":FORm=1TO2000:NEXTm:GOTO190
30560 GOSUB18000:PRINT"{156}You bob on the surface like a cork. You need ";
30570 PRINT"something heavy to let you sink{space*4}";
30580 PRINT"down to get the crystal.":GOTO5000
30590 IFob%(2)=-1THENGOSUB18000:PRINT"{156}Nice day for a dip{!*3}":GOTO4320
30610 es=1:PRINT"{black}At first you sink down until the crystalis almost ";
30620 PRINT"in your grasp.{space*2}Suddenly out{space*2}of the depths a gigantic eel ";
30630 PRINT"looms{space*2}up{space*2}and winds itself around you."
30640 PRINT"It starts to squeeze {.*3}":GOSUB19000:rc=2:q=0:yy=1:GOTO5000
30650 GOSUB18000:PRINT"{156}The beast has you gripped too tightly{space*3}";
30660 PRINT"for you to escape!":GOTO5000
30970 REM**
30980 REM poisonous air
30990 REM**
31000 PRINT"{down}{black}Suddenly you become aware that you are{space*2}choking.{space*2}The ";
31010 PRINT"atmosphere is poisonous.{space*2}Unless you do something ";
31020 PRINT"very quickly youwill die {.*3}"
31030 FORm=1TO5000:NEXTm
31040 PRINT"{156}Start thinking "n$"!":PRINT"{156}*";
31050 FORl=0TO24:POKEsc+l,0:NEXTl
31060 FORi=1TO30:PRINT"*";
31070 POKEvo,15:POKEa1,41:POKEs1,89:POKEw1,17:POKEh1,56:POKEl1,99
31080 FORt=1TO200:NEXTt:POKEvo,0:POKEa1,0:POKEw1,0:POKEs1,0
31090 NEXTi
31100 PRINTCHR$(13):PRINT"{green}{down}Too late!!":PRINT"Too late!!":GOTO190
31470 REM**
31480 REM if remove spacesuit
31490 REM**
31500 IFp=58THEN12080
31510 IFp=59THEN12080
31520 IFfv<>2THEN31000
31530 IFfv=2THEN12080
31570 REM**
31580 REM if eat nuts
31590 REM**
31600 IFno$="nuts"ORno$="fruit"THEN31620
31610 GOSUB19000:PRINT"{156}Ugh!{space*2}Why do you want to eat {reverse on}that{reverse on}?":GOTO5000
31620 IFp=37THENPRINT"Okay.Mm! Tastes nice "n$"!":GOTO31650
31630 IFob%(3)=-1THENPRINT"{green}Okay - tastes nice!":GOTO31650
31640 IFob%(3)<>-1THENGOSUB19000:PRINT"{156}You haven't got any "no$"!":GOTO5000
31650 IFz=1THEN31700
31660 GOSUB35100:PRINT"{clear}":PRINT"{light blue}Inspired move there "n$"!"
31670 PRINT"You should be feeling a strange sensa-{space*2}tion running through ";
31680 PRINT"your body - and{space*4}now you can breathe (happily) without{space*3}your ";
31690 PRINT"spacesuit.{space*2}You can remove it.":ob%(3)=0:z=1:fv=2:g=g-1:GOTO5000
31700 GOSUB18000:PRINT"{black}{down}This time you feel no different.{space*2}";
31710 PRINT"Still it does stop you feeling hungry.":ob%(3)=0:GOTO5000
31970 REM**
31980 REM crystal
31990 REM**
32000 PRINT"{down}{black}You notice that the energy crystal is{space*3}missing from the ";
32010 PRINT"energy pod.{space*2}Without ityou cannot fly the ship!!{space*2}It must have ";
32020 PRINT"been taken by some-one! You have to findit before you can escape."
32030 RETURN
32040 REM**
32050 REM cannot get crystal
32060 REM**
32070 IFno$="crystal"THEN32090
32080 GOTO11700
32090 IFev<>2THENGOSUB19000:PRINT"{156}You can't {.*5}";:FORm=1TO500:NEXTm
32100 IFev<>2THENPRINT"{.*4}yet!!":PRINT"It's {reverse on}under{reverse off} the water.":GOTO4320
32110 IFev=2THEN11700
32470 REM**
32480 REM climb tree
32490 REM**
32500 GOSUB18000:PRINT"{156}To the north lies a ruined city - to thesouth more ";
32510 PRINT"trees stretching toward the horizon. You climb down.":GOTO4320
32520 GOSUB18000:PRINT"{156}To the east you can see your ship -{space*5}elsewhere ";
32530 PRINT"just trees and more trees {.*3} You climb down.":GOTO4320
32540 GOSUB18000:PRINT"{156}To the south you can see smoke curling{space*2}in the sky. T";
32550 "here must be life of some{space*2}sort that way. You climb down.":GOTO4320
32570 REM**
32580 REM quicksand
32590 REM**
32600 PRINT"{down}{black}You are sinking into quicksand.{space*9}In seconds it is about ";
32610 PRINT"your knees.Betterthink of something!!":q=0:GOTO5000
32670 REM**
32680 REM dinosaur
32690 REM**
32700 PRINT"{down}{black}From the trees at the side of the road amassive ";
32710 PRINT"dinosaur moves into your path.{space*2}You cannot get past.":GOTO5000
32970 REM**
32980 REM natives
32990 REM**
33000 PRINT"{down}{black}A bunch of hostile natives appear at theentrance to the ";
33010 PRINT"hut - blocking the way. They advance - spears pointing at ";
33020 PRINT"your{space*2}throat.{space*2}They mean business "n$"!":q=0:GOTO5000
33030 REM**
33040 REM back to hut again
33050 REM**
33060 PRINT"{black}Back again!!{space*2}I hope you've worked out{space*2}how to give Aurora ";
33070 PRINT"that little kiss thatwill help get her out of there!!"
33080 na=0:q=0:GOTO5000
33090 REM**
33100 REM illegal get of aurora
33110 REM**
33120 IFnv<>2ANDno$="Aurora"THEN33170
33130 IFnv<>2ANDno$="princess"THEN33170
33140 IFnv<>2ANDno$="Princess"THEN33170
33150 GOTO11700
33170 GOSUB35100
33180 PRINT"{clear}{156}Sorry "n$".":PRINT"but the natives don't like a pusher!! ";
33190 PRINT"{space*2}and they did warn you not to try and{space*4}take her."
33200 PRINT"They've killed you!{space*2}Still that's the{space*3}way it goes!!":GOTO190
33210 REM**
33220 REM no aurora
33230 REM**
33240 PRINT"{black}With Aurora missing you cannot compleat your mission.":RETURN
33250 REM**
33260 REM found aurora
33270 REM**
33280 GOSUB35100
33290 PRINT"{clear}{156}{clear}{down*2}Congratulations!!{space*3}You have succeeded{space*2}in your mission!!"
33300 PRINT"{down}After only a few hours work you can{space*5}take off in your ship ";
33310 PRINT"and head for deep space."
33320 PRINT"{down}And princess Aurora has decided she{space*5}doesn't want to marry ";
33330 PRINT"the cruel ruler ofZen after all!":PRINT"She much prefers you "n$"!"
33340 PRINT"{down}Pretty neat eh?":POKEv+21,0:END
33350 GOSUB18000:PRINT"{156}{down}Aurora gives you a kiss for luck as youset out once ";
33360 PRINT"more to find the crystal.":hh=2:GOTO12090
33370 REM**
33380 REM found crystal
33390 REM**
33400 GOSUB35100:PRINT"{clear}{black}Okay.{space*2}so you've got the energy crystal.";
33410 PRINT"Now all you've got to do is find the{space*4}princess!"
33420 PRINT"Don't forget to leave the crystal here.":GOTO21500
33430 REM**
33440 REM no crystal
33450 REM**
33460 GOSUB35100:PRINT"{clear}{black}Okay.{space*2}Aurora is safe and you can ";
33470 PRINT"leave her here if you wish.":GOTO21500
34970 REM**
34980 REM mealy bug
34990 REM**
35000 POKEv+39,2:POKEv+27,1:POKEv+23,1:POKEv+29,1
35010 POKEv+1,100:POKEv,0:POKEv+21,1
35020 FORx=0TO255:POKEv,x:NEXTx:POKEv+16,1
35030 FORx=0TO95:POKEv,x:NEXTx:POKEv+16,0:POKEv+21,0
35040 RETURN
35070 REM**
35080 REM victor
35090 REM**
35100 FORl=0TO24:POKEsc+l,0:NEXTl
35110 POKEvo,15:POKEa1,190:POKEa2,190:POKEa3,190:POKEw1,33:POKEw2,33:POKEw3,129
35120 POKEh1,75:POKEl1,69:POKEh2,212:POKEl2,230:POKEh3,1:POKEl3,123
35130 FORm=1TO200STEP.25:NEXTm
35140 POKEv+40,4:POKEv+29,2:POKEv+23,2
35150 POKEv+2,80:POKEv+3,0:POKEv+21,2
35160 FORy=0TO190:POKEv+3,y:NEXTy
35170 POKEw1,0:POKEa1,0:POKEw2,0:POKEa2,0:POKEw3,0:POKEa3,0
35180 RETURN
35200 DATA99999
35210 REM**
35220 REM data sprite 1
35230 REM**
35240 DATA255,128,0,255,128,0,1,128,0,1,128
35250 DATA0,3,252,0,31,255,224,255,252,32,63
35260 DATA252,63,63,255,255,224,0,1,63,255,240
35270 DATA63,255,240,3,1,0,3,25,0,3,31
35280 DATA0,227,0,0,255,0,0,0,0,0,0
35290 DATA0,0,0,0,0,0,0,0,0
35300 REM**
35310 REM data sprite 2
35320 REM**
35330 DATA0,112,0,0,248,0,1,252,0,1,172
35340 DATA0,1,172,0,3,254,0,3,222,20,1
35350 DATA116,20,1,4,28,1,252,8,0,112,8
35360 DATA7,255,8,7,255,8,127,255,248,68,1
35370 DATA0,229,253,0,165,253,0,4,1,0,7
35380 DATA255,0,7,255,0,1,36,0
35390 REM**
35400 REM set up sprites
35410 REM**
35420 RESTORE:FORll=1TO1000:READa$:IFa$="{9*5}"THENll=10^6
35430 NEXTll
35440 POKE2041,14:POKE2040,13
35450 FORll=0TO126:READq:POKE832+ll,q:NEXTll
35460 RESTORE
35470 RETURN
stop tok64
(bastext 1.1)

start tok64 MARDR\MSPLANETEN
130 PRINT"{clear}":POKE53280,0:POKE53281,0:IFPEEK(60334)=92THEN140
131 IFPEEK(49152)<>120THENGOSUB60000
132 SYS49152
140 PRINT"{ct n}{ct h}{green}{down*3}I en avl[gsen framtid{.*3}"
150 GOTO280
190 POKEv+21,0:PRINT"{yellow}{down*2} Du hade otur den h[r g]ngen, eller hur "n$"?"
200 PRINT"{down}Som tur [r har jag makten att ]terupp-{space*2}liva dig s] att du kan";
210 PRINT" spela igen.":PRINT"{down}Skulle du tycka om det? (j/n)"
220 GETr$:IFr$<>"j"ANDr$<>"n"THEN220
230 IFr$="j"THEN280
240 IFr$="n"THEN17570
280 CLR:v=53248:sc=54272:bs=53280:bc=53281:DIMq$(1)
290 pr=0:cv=0:sv=0:ev=0:qv=0:dv=0:es=2:nv=0:na=0:np=0:fv=0:rc=0:yy=0:hh=0:hr=0
300 vo=54296:w1=54276:a1=54277:s1=54278:w2=54283:a2=54284:s2=54285
310 w3=54290:a3=54291:s3=54292
320 h1=54273:l1=54272:h2=54280:l2=54279:h3=54287:l3=54286
360 FORl=0TO24:POKEsc+l,0:NEXTl
370 POKEvo,15:POKEa1,255:POKEa2,255:POKEa3,255
380 POKEs1,255:POKE2,255:POKEs3,255
390 POKEw1,17:POKEw2,33:POKEw3,17
400 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
410 GOSUB35420
1000 POKEbs,0:POKEbc,0:PRINT"{clear}{142}":cs=55296:ss=PEEK(648)*256
1020 FORi=1TO23
1030 POKEcs+40*i,4:POKEss+40*i,102
1040 POKEcs+40*i+38,4:POKEss+40*i+38,102
1045 POKEcs+40*i+39,0:POKEss+40*i+39,160
1050 NEXTi
1060 PRINT"{right}{156}{cm +*38}"
1070 PRINTTAB(12)"{down*3}{white}mardr{pound}msplaneten"
1080 PRINT"{right*7}{down*3}{green}ett [ventyr i tid och rum"
1090 PRINT"{down*2}{right*5}{green}{sh -}"
1100 PRINT"{right*4}{reverse on}{sh pound} {cm asterisk}"
1110 PRINT"{right*4}{reverse on}B{sh +}B{reverse off}{space*23}{red}Q"
1120 PRINT"{right*4}{reverse on}{green}BQB"
1130 PRINT"{right*4}{reverse on}{green}BQB"
1140 PRINT"{right*3}{reverse on}{sh pound}BQB{cm asterisk}{reverse off}{space*4}{156}*"
1150 PRINT"{right*3}{green}{cm k}{reverse on}B{sh +}B{cm k}"
1160 PRINT"{right*3}{cm k}{reverse on}B{cm +}B{cm k}{reverse off}{space*27}{yellow}*"
1170 PRINT"{right*3}{green}{cm k}{reverse on}B{cm +}B{cm k}{reverse off}"
1180 PRINT"{right*3}{green}{cm k}{space*3}{reverse on}{cm k}{reverse off}"
1190 PRINT"{right}{down}{156}{cm +*37}"
1200 GOSUB35000
1210 FORm=1TO500
1220 NEXTm
1127 POKEvo,0
1300 POKEbs,9:POKEbc,9
1310 PRINT"{clear}{ct n}"
1320 FORm=1TO100
1330 NEXTm
1350 PRINTTAB(6)"{yellow}Du [r ensam i kontrollrummet p]{space*3}ditt rymdskepp, du ";
1360 PRINT"t[nker p] flickan somdu betalt f{pound}r att transportera s[kert{space*3}till";
1370 PRINT" planeten Zen. Prinsessan som du [r f{pound}rtjust i all hemlighet men ";
1380 PRINT"som [r{space*5}lovad till den grymme h[rskaren av Zen iett [ktenskap ";
1390 PRINT"p] diplomatiska grunder."
1400 PRINTTAB(6)"{down}Du t[nker mer p] prinsessan Auro- rora [n p] sj[lva flygningen ";
1410 PRINT"av skeppet.Pl{pound}tsligt, utan n]gon som helst varning leds du p] ";
1420 PRINT"villov[gar alltf{pound}r n[ra en{space*3}mystisk planet - och sugs in i dess ";
1430 PRINT"gra-vitationsf[lt."
1440 PRINTTAB(6)"{down}Du kanske inte [r helt koncen-{space*4}trerad p] din uppgift, ";
1450 PRINT"planeten kanske{space*2}[r f{pound}r stark. P] endera s[ttet lyckas duinte ";
1460 PRINT"kontrollera ditt skepp. Eftersom dur]kar glida in i gl{pound}mska ";
1470 PRINT"[r ditt sista{space*2}minne marken som rusar mot dig{.*4}"
2030 FORl=0TO24:POKEsc+l,0:NEXTl
2040 POKEvo,15:POKEa1,255:POKEa2,255:POKEa3,255
2050 POKEs1,128:POKEs2,128:POKEs3,128:POKEw1,65:POKEw2,129:POKEw3,129
2060 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
2100 PRINTTAB(11)"{down}Tryck 's' f{pound}r start"
2110 GETa$:IFa$<>"s"THEN2110
2120 IFa$="s"THENPOKEvo,0
2130 FORm=1TO150:NEXTm
2170 FORl=0TO24:POKEsc+l,0:NEXTl
2180 POKEvo,15:POKEa1,140:POKEa2,140:POKEa3,140:POKEs1,0:POKEs2,0:POKEs3,0
2190 POKEw1,33:POKEw2,129:POKEw3,129
2200 POKEh1,37:POKEl1,162:POKEh2,1:POKEl2,12:POKEh3,2:POKEl3,187
2210 PRINT"{clear}":POKEbs,0:POKEbc,0
2220 PRINT"{down*2}{right*5}{down*2}{156}Jag tror du har kraschat {!*4}"
2230 FORm=1TO1000:NEXTm
2240 PRINT"{down*3}{right*2}{green}{cm -}nskar du ladda ett befintligt spel{space*5}fr]n band (j eller n)?"
2250 GETa$:IFa$<>"j"ANDa$<>"n"THEN2250
2260 IFa$="j"THENPOKEvo,0:GOSUB16000
2270 PRINT"{green}{down*2}{right*2}Beh{pound}ver du instruktioner (j eller n)?"
2280 GETa$:IFa$<>"j"ANDa$<>"n"THEN2280
2290 IFa$="j"THENPOKEvo,0:GOSUB15000
2300 POKEvo,0:GOSUB35100
2400 POKEbs,11:POKEbc,11:PRINT"{clear}{down*2}{gray}Personliga roboten Victor:"
2410 PRINT"{down}Jag kommer att vara till din hj[lp genomdet h[r [ventyret{.*3}"
2420 PRINT"{down}Jag kommer fram vid tillf[llen av stor{space*2}stress och fara !!"
2430 PRINT"Men jag finns alltid i n[rheten,[ven n[rdu inte kan se mig."
2440 INPUT"{down*2}Vad heter du";n$
2450 GOSUB18000:PRINT"{down}Tackar "n$"! Jag ser dig!"
2460 FORm=1TO1000:NEXTm
2470 PRINT"{clear}{down}{yellow}{cm @*22}":PRINT"{reverse on} {sh +}ventyret b{pound}rjar{.*4} {down*2}"
2480 FORm=1TO2000:NEXTm
2490 POKEv+21,0
3700 nt=9:FORi=1TOnt:READob%(i),ob$(i),si$(i):NEXTi
3710 DATA15,rep,"En r]tta springer iv[g fr]n det upprul- lade repet i h{pound}rnet.
3720 DATA28,kristall,"Energikristallen gnistrar med ett hem-{space*2}ligt sken.
3730 DATA37,n{pound}tter,"N]gra f] n{pound}tter ligger p] marken.
3740 DATA47,vrakspillror,"Du st{pound}ter dina t]r i n]gra varkspillror.
3750 DATA53,[delsten,"Ljusreflexer fr]n en [delsten f]ngar dinuppm[rksamhet.
3760 DATA58,rymddr[kt,"Din rymddr[kt [r h[r - fortfarande hel.
3770 DATA59,laserpistol,"Din laserpistol ligger p] marken.
3780 DATA69,kniv,"G{pound}md bland sm]stenar ligger en sten-{space*4}]lderskniv.
3790 DATA92,"Aurora","Du kan se Aurora s[ker och sund.
4000 p=59:GOTO4020
4010 p=p2
4020 IFp<11THENONpGOTO20000,20020,20080,20130
4030 IFp<21THENONp-10GOTO20170,20190,20210,20250,20310
4040 IFp<31THENONp-20GOTO0,20360,0,20380,20430,20480,0,20530
4050 IFp<41THENONp-30GOTO0,0,0,0,0,20570,20620,20670
4060 IFp<51THENONp-40GOTO0,20710,20730,20750,0,20770,20820,20870
4070 IFp<61THENONp-50GOTO0,20930,20950,21000,21040,21100,21150,21200,21390
4080 IFp<71THENONp-60GOTO0,21510,21530,21550,21600,0,21650,21700,21750
4090 IFp<81THENONp-70GOTO0,0,0,21800
4100 IFp<91THENONp-80GOTO0,0,0,21860
4110 IFp<101THENONp-90GOTO0,21910,21940,21970
4150 FORi=1TOnt:IFob%(i)=pTHENPRINTsi$(i)
4160 NEXTi
4200 IFp=24ANDsv<>2THEN30000
4210 IFp=28ANDev<>2THENGOSUB30500
4220 IFp=57ANDfv<>2ANDob%(6)<>-1THEN31000
4230 IFp=59ANDob%(2)<>-1THENGOSUB32000
4240 IFp=59ANDpr<>2THENGOSUB33240
4250 IFp=67ANDqv<>2THEN32600
4260 IFp=74ANDdv<>2THEN32700
4270 IFp=92ANDnv<>2ANDnp=0THEN33000
4280 IFp=92ANDnv<>2ANDnp=1THEN33060
4320 PRINT"{white}{down}Du kan g] ";:qz=0:q$(1)=","
4330 IFn>0THENPRINT"norr";:qz=1
4340 IFe>0THENPRINTq$(qz)"{pound}st";:qz=1
4350 IFs>0THENPRINTq$(qz)"syd";:qz=1
4360 IFw>0THENPRINTq$(qz)"v[st";
4370 PRINT"."
5000 PRINTCHR$(13):x=FRE(0)
5010 INPUT"{cyan}Instruktioner:{yellow}{right*2}*{left*3}";i$
5020 POKEv+21,0
5030 IFi$="*"THENPRINT"{up*2}":GOTO5010
5070 IFp=92THEN5290
5080 IFp=67THEN5200
5090 IFp<>28THEN6000
5100 IFev=2THEN6000
5110 IFp=28ANDes=2THEN6500
5120 q=q+1
5130 IFq<5THEN6000
5140 IFq=5THENPRINT"{green}Du b{pound}rjar {reverse on}verkligen{reverse off} bli svagare{.*3}":GOTO5120
5150 IFq<>10THEN5170
5155 GOSUB19000:PRINT"{green}Det var det,"n$"!"
5160 PRINT"Du har tryckts ihop och d{pound}dats!":GOTO190
5200 IFp=92THEN5290
5210 IFp<>67THEN6000
5220 IFqv=2THEN6500
5230 q=q+1
5240 IFq<5THEN6000
5250 IFq=5THEN13320
5290 IFp<>92THEN6000
5300 IFnv=2THEN6000
5310 IFp=92ANDpr=2THEN6500
5320 q=q+1
5330 IFq<5THEN6000
5340 IFq<>5THEN5350
5345 PRINT"{green}Forts[tt att f{pound}rs{pound}ka,"n$".":PRINT"Vad h[nder nu?":GOTO5320
5350 IFq=10ANDi$="kyss Aurora"THEN14030
5370 IFq<>10THEN5970
5375 GOSUB18000:PRINT"{green}F{pound}r sent!{space*2}Inv]narna har sl[ngt ut dig"
5380 PRINT"ur hyddan och du kan inte ta Aurora med"
5390 PRINT"dig. B[st att g] ]t sidan och fundera ut";
5400 PRINT"hur du ska r[dda henne.":q=0:na=1:np=1:GOTO4320
6000 IFp=24ANDsv<>2THEN6110
6010 IFp=28ANDes=2THEN6500
6020 IFp=28ANDev<>2THEN6110
6030 IFp=67ANDqv<>2THEN6110
6040 IFp=74ANDdv<>2THEN6170
6050 IFp=92ANDnv<>2ANDna=1THEN6500
6060 IFp=92ANDnv<>2ANDna=0THEN6110
6070 GOTO6500
6110 IFi$="n"ORi$="o"ORi$="s"ORi$="v"THENGOSUB19000:GOTO6130
6120 GOTO6150
6130 PRINT"{cyan}Du kan inte rymma den v[gen!":PRINT"Du m]ste t[nka ut n]got ";
6140 PRINT"annat!":GOTO5000
6150 IFi$="spring"THENGOSUB19000:PRINT"{white}Det finns ingen flyktv[g d[r.":GOTO5000
6160 IFi$="g]"THENGOSUB19000:PRINT"{black}Du kan inte komma ut den v[gen.":GOTO5000
6170 IFi$<>"syd"ANDi$<>"s"THEN6500
6175 GOSUB19000:PRINT"{cyan}Ingen chans,"n$"!"
6180 PRINT"{green}Det [r st]r {white}dinosaur{green} p] v[gen!":GOTO5000
6500 IFi$="norr"THENi$="n"
6510 IFi$="{pound}st"THENi$="o"
6520 IFi$="syd"THENi$="s"
6530 IFi$="v[st"THENi$="v"
6540 IFi$="n"ORi$="o"ORi$="s"ORi$="v"THEN7070
6550 IFi$="i"ORLEFT$(i$,3)="inv"THEN10000
6560 IFi$="h"ORi$="hj[lp"THEN11000
6570 IFi$="instruktioner"THENGOSUB15000
6580 IFi$="springa"ORi$="g]"THENGOSUB18000:PRINT"{yellow}Vilken v[g ?":GOTO4320
6590 IFi$="t"ORLEFT$(i$,5)="titta"THENGOSUB18000:GOTO6610
6600 GOTO6640
6610 IFp=28ANDyy=1THENPRINT"{green}Du ser inte mycket under vattnet!!":GOTO5000
6620 GOTO4020
6640 q$=LEFT$(i$,4)
6645 IF(q$="hopp"ORq$="k[mp"ORq$="flyt"ORq$="simm")ANDp=67THEN13310
6680 IFi$="[t"ORi$="[ta"THENPRINT"Vad vill du [ta? K{pound}ttbullar?":GOTO5000
6690 IFi$="{pound}ppna luftventil"AND(p=57ORp=58)THEN7100
6710 q$=LEFT$(i$,4)
6715 IF(i$="g] i sj{pound}n"ORq$="simm"ORi$="hoppa i")ANDp=28ANDrc=2THEN30650
6740 IFi$="g] i sj{pound}n"ANDp=28THEN30510
6750 IFi$="g] till stranden"ANDp<>28THEN7810
6760 IFi$="g] till stranden"ANDp=28THEN6780
6770 GOTO6800
6780 IFes=2THENGOSUB18000:GOTO20540
6790 IFes<>2THENGOSUB19000:GOTO6130
6800 q$=LEFT$(i$,4):IF(q$="simm"ORq$="hopp")ANDp=28THEN30510
6820 IFLEFT$(i$,2)="g]"THENGOSUB18000:PRINT"{yellow}Skriv bara riktning {.*3}":GOTO4320
6825 q$=LEFT$(i$,1)
6830 IFi$="f{pound}rst]r ej"ORq$="?"THENGOSUB19000:PRINT"{yellow}Eller hur,"n$"?":GOTO5000
6835 IFi$="drick"ORi$="dricka"THENPRINT"{yellow}Vad ska jag dricka?":GOTO5000
6840 IFi$="save"THEN17000
6850 IFi$="quit"ORi$="end"ORi$="sluta"THEN17500
6860 IFi$="kl[ttra"THENGOSUB18000:PRINT"{green}Vad ska jag kl[ttra i?":GOTO5000
7000 IFi$<>"n"ANDi$<>"e"ANDi$<>"s"ANDi$<>"w"THEN7300
7070 IFp=58ANDi$="v"THEN7100
7080 IFp=57ANDi$="o"THEN7100
7090 GOTO7200
7100 PRINT"{black}{down}Luftventil {pound}ppnas {.*4}"
7110 FORl=0TO24:POKEsc+l,0:NEXTl
7120 POKEvo,15:POKEa1,17:POKEa2,17:POKEs1,130:POKEs2,130
7130 POKEw1,17:POKEw2,17:POKEh1,13:POKEl1,78:POKEh2,253:POKEl2,46
7140 FORt=1TO1500:NEXTt:PRINT"{up}{space*22}"
7150 FORt=1TO700:NEXTt:PRINT"{up}Luftventilen {pound}ppen {.*6}"
7160 FORt=1TO700:NEXTt:GOTO7200
7200 IFi$="n"ANDn>0THENp2=p-10:GOSUB18000:GOTO4010
7210 IFi$="o"ANDe>0THENp2=p+1:GOSUB18000:GOTO4010
7220 IFi$="s"ANDs>0THENp2=p+10:GOSUB18000:GOTO4010
7230 IFi$="v"ANDw>0THENp2=p-1:GOSUB18000:GOTO4010
7240 IFi$="{pound}ppna luftventil"ANDp=58THENp2=p-1:GOSUB18000:GOTO4010
7250 IFi$="{pound}ppna luftventil"ANDp=57THENp2=p+1:GOSUB18000:GOTO4010
7260 GOSUB19000:PRINT"{yellow}{up}Tyv[rr - men du kan inte g] den v[gen.":GOTO4320
7300 FORi=1TOLEN(i$)
7310 IFMID$(i$,i,1)=" "THEN7340
7320 NEXTi
7330 PRINT"{green}Var v[nlig anv[nd TV{sh -} ord":GOSUB19000:GOTO5000
7340 FORi=1TOLEN(i$)
7350 IFMID$(i$,i,2)="{space*2}"THEN7380
7360 NEXTi
7370 GOTO7420
7380 PRINT"{white}L[mna {reverse on}ETT{reverse off} mellanrum mellan orden":GOSUB19000:GOTO5000
7420 FORsp=pi+1TOLEN(i$)
7430 IFMID$(i$,sp,1)=" "THEN7450
7440 NEXTsp
7450 ve$=LEFT$(i$,sp-1)
7460 no$=RIGHT$(i$,LEN(i$)-sp)
7500 IFve$="kl[ttra"THEN7920
7520 IF(ve$="ta"ORve$="f]nga"ORve$="grip")ANDp=28THEN32070
7560 IFve$="hitta"THENGOSUB18000:PRINT"{green}Du m]ste se dig omkring {white}!!":GOTO5000
7570 IF(ve$="ta"ORve$="f]nga"ORve$="gripa")ANDp=92THEN33120
7610 IFve$="ta"ORve$="f]nga"ORve$="grip"ORve$="lyft"THEN11700
7620 IFve$="unders{pound}k"THENGOSUB18000:GOTO7820
7625 IFve$="drick"ORve$="dricka"THENGOTO12800
7630 IFve$="tappa"ORve$="l[mna"ORve$="l[gg"ORve$="sl[pp"THEN12000
7640 IFve$="d{pound}da"ORve$="m{pound}rda"ORve$="f{pound}rst{pound}r"ORve$="{pound}del[gg"THEN12300
7650 IFve$="[t"ORve$="[ta"THEN31600
7660 IFve$="anv[nd"THEN11500
7670 IFve$="avfyra"THEN12700
7680 IFve$="skjut"ORve$="laser"ORve$="avfyra"THEN12300
7690 IFve$="stick"ORve$="knivm{pound}rda"ORve$="hugg"THEN12760
7700 IFLEFT$(ve$,6)="spring"ORLEFT$(ve$,2)="g]"THENPRINT"{yellow}Vilken v[g?":GOTO4320
7710 IFve$="kasta"ANDp=67THENGOSUB18000:GOTO13300
7720 IFve$="kasta"THENGOSUB18000:GOTO7865
7730 IFve$="kyss"ANDp=92ANDno$="Aurora"THEN14000
7740 IFve$="kyss"ANDob%(9)=-1ANDno$="Aurora"THEN14210
7750 IFve$="kyss"THEN7810
7760 IFp<>92THEN7780
7770 IFve$="krama"ORve$="[lska"ORve$="kela"THEN7800
7780 IFve$="krama"ORve$="[lska"ORve$="kela"THEN7810
7790 GOTO7980
7800 GOSUB18000:PRINT"{green}Det [r inte tillr[ckligt intimt.F{pound}rs{pound}k"
7805 PRINT"n]got annat.":GOTO5000
7810 GOSUB19000:PRINT"{white}Du beter dig underligt,"n$:GOTO5000
7820 IFp=25ANDLEFT$(no$,3)="d{pound}r"THENPRINT"{green}Bara en tom byggnad..":GOTO5000
7830 IFp=28ANDno$="sj{pound}"THENPRINT"{green}Kristallen [r definitivt d[r.":GOTO5000
7840 IFp=37ANDno$="buske"THENPRINT"{green}N{pound}tterna ser [tbara ut.":GOTO5000
7850 IFp=37ANDno$="frukt"ORno$="n{pound}tter"THENPRINT"{green}De ser goda ut.":GOTO5000
7860 PRINT"{yellow}Det finns ingen hj[lp h[r.":GOTO5000
7865 IFno$="Victor"THENhr=2:GOTO11300
7870 FORi=1TOnt:IFob$(i)=no$THEN7900
7880 NEXTi
7890 PRINT"{white}Sluta larva dig !!":GOTO5000
7900 IFob%(i)=-1THENPRINT"{green}Kan inte se n]gon mening med det!!":GOTO12090
7910 PRINT"{white}Du har det inte !":GOTO5000
7920 IFno$<>"tr[d"THEN7970
7930 IFp=42ORp=43ORp=44THEN32500
7940 IFp=52ORp=53ORp=54ORp=55THEN32520
7950 IFp=62ORp=63ORp=64ORp=65THEN32520
7960 IFp=74THEN13580
7970 GOSUB19000:PRINT"{green}Du kan inte kl[ttra {yellow}"no$"{green}.":GOTO5000
7980 GOSUB19000:PRINT"{cyan}Tyv[rr! Jag vet inte hur jag ska":PRINTve$".":GOTO5000
10000 PRINT:PRINT"{yellow}Ditt inventarium [r:":iv=0
10010 FORi=1TOnt
10020 IFob%(i)=-1THENPRINT"{green}"ob$(i):GOSUB18000:iv=iv+1
10030 NEXTi
10040 IFiv=0THENPRINT"{green}Ingenting [r jag r[dd."
10050 GOTO5000
11000 IFhr=2THEN11250
11005 IFp=24THENGOSUB35100:PRINT"{clear}":GOTO11090
11010 IFp=58THENGOSUB35100:PRINT"{clear}":GOTO11100
11020 IFp=67THENGOSUB35100:PRINT"{clear}":GOTO11120
11030 IFp=92THENGOSUB35100:PRINT"{clear}":GOTO11140
11040 IFp=1ORp=2ORp=11ORp=12ORp=22THENGOSUB35100:PRINT"{clear}":GOTO11190
11050 IFp=42ORp=62ORp=63THENGOSUB35100:PRINT"{clear}":GOTO11170
11060 GOSUB35100:PRINT"{clear}"
11070 PRINT"{white}Jag har nog med egna bekymmer,{space*10}"n$
11080 PRINT"F{pound}rs{pound}k ta itu med dina egna.":GOTO5000
11090 PRINT"{white}F{pound}rs{pound}k d{pound}da den,"n$",":PRINT"innan den d{pound}dar dig.":GOTO5000
11100 PRINT"{white}T[nk nu,"n$",":PRINT"det m]ste finnas n]got i n[rheten ";
11110 PRINT"som dukan ha anv[ndning f{pound}r {.*3}":GOTO5000
11120 PRINT"{white}Besv[rlig situation det h[r. Jag f{pound}re-{space*2}sl]r att du tar ";
11130 PRINT"dig ut ur det h[r!":GOTO5000
11140 PRINT"{white}Eftersom inv]narna tror Aurora [r deras drottning, kanske det ";
11150 PRINT"skulle hj[lpt om{space*2}du visade dem att du [r v[nligt sinnad{space*2}mot ";
11160 PRINT"Aurora.":GOTO5000
11170 PRINT"{white}F{pound}rlorad i skogen? Varf{pound}r inte f{pound}rs{pound}ka{space*2}kl[ttra upp i ett ";
11180 PRINT"tr[d och se dig omk-{space*2}ring?":GOTO5000
11190 PRINT"{white}Vi [r b]da f{pound}rlorade,"n$".":PRINT"Forts[tt g] om du eventuellt ";
11200 PRINT"skulle hit-ta v[gen.":GOTO4320
11250 GOSUB35100:PRINT"{clear}{white}Vi [r inte v[nner f{pound}r tillf[llet,"n$".":GOTO11310
11280 GOSUB35100:PRINT"{clear}{white}Du kan inte d{pound}da mig "n$"."
11290 PRINT"Jag [r den nya os]rbara modellen. Men{.*3}":GOTO11310
11300 GOSUB35100:PRINT"{clear}{white}Det var inte tervligt,"n$"."
11310 PRINT"Jag ska inte {reverse on}hj[lpa{reverse off} dig n]got mer nu."
11320 PRINT"Du f]r klara dig sj[lv!":GOTO5000
11500 IFp<>24ORp<>74ANDno$="laserpistol"THEN11580
11510 IFp<>24ORp<>74THEN11610
11520 IFp=24ORp=74ANDno$="laserpistol"THEN11580
11530 IFp=24ORp=74ANDno$="kniv"THEN11550
11540 GOTO11660
11550 IFob%(8)<>-1THENGOSUB19000:PRINT"{white}Du har det inte!!":GOTO5000
11560 IFob%(8)<>-1THEN11580
11565 GOSUB35100:PRINT"{clear}{white}Med bra en kniv,"n$"?"
11570 PRINT"Det [r lite v[l amibiti{pound}st,eller hur ?":GOTO5000
11580 IFob%(7)<>-1THENGOSUB19000:PRINT"{white}Du har det inte!!":GOTO5000
11590 IFp=24ANDob%(7)=-1THENGOSUB18000:PRINT"{yellow}Bra t[nkt!":GOTO13030
11600 IFp=74ANDob%(7)=-1THENGOSUB35100:PRINT"{clear}{white}bra t[nkt!":GOTO13510
11610 FORi=1TOnt
11620 IFob$(i)<>no$THEN11640
11630 IFob%(i)=-1THEN11660
11640 NEXTi
11650 GOSUB19000:PRINT"{green}Det [r ingen ide att anv[nda det!":GOTO5000
11660 PRINT"{green}Hur vill du anv[nda det,"no$"?":GOSUB18000:GOTO5000
11700 FORi=1TOnt:IFob$(i)=no$THEN11740
11710 NEXTi
11711 IF(no$="meddelande"ORno$="papperslapp"ORno$="papper")ANDp=1THEN11713
11712 GOTO11720
11713 PRINT"{cyan}Den [r f{pound}r h{pound}gt uppe!":GOSUB19000:GOTO5000
11720 IFp=37ANDno$="frukt"THEN11860
11730 IFob$(i)<>no$THEN11850
11740 IFob%(i)=-1THENPRINT"{green}Du har det redan !!":GOSUB19000:GOTO5000
11750 IFp=37ANDno$<>"n{pound}tter"THEN11800
11760 IFp=37ANDno$<>"frukt"THEN11800
11770 IFp=37ANDno$="n{pound}tter"THEN11790
11780 GOTO11800
11790 IFp=37ANDz=1THEN11880
11800 IFob%(i)<>pTHENPRINT"{white}Jag ser inte "no$" h[r.":GOSUB19000:GOTO5000
11810 IFg<=4THEN11830
11815 PRINT"Du b[r f{pound}r mycket -"
11820 PRINT"det [r b[st du l[mnar n]got!!":GOSUB19000:GOTO5000
11830 PRINT"{green}Okay.":GOSUB18000:ob%(i)=-1:g=g+1
11840 GOTO5000
11850 GOSUB18000:PRINT"{yellow}Jag skulle inte besv[ra med att g{pound}ra det"n$"!!":GOTO5000
11860 IFz=1THEN11880
11870 GOTO11830
11880 GOSUB18000:PRINT"{yellow}Bara [t dem,"n$".":GOTO5000
12000 FORi=1TOnt:IFob$(i)=no$THEN12040
12010 NEXTi
12020 IFp=28ANDno$="rymddr[kt"THENGOSUB19000:GOTO30510
12030 IFob$(i)<>no$THENGOSUB18000:PRINT"{green}Ingen mening med det.":GOTO5000
12040 IFob%(i)<>-1THENPRINT"{green}Du har inte f]t det [nnu{!*3}":GOSUB19000:GOTO5000
12050 IFp=28ANDno$="rymddr[kt"THENGOSUB19000:PRINT"{green}Du sjunker{.*5}":GOTO30540
12060 IFob%(6)=-1ANDno$="rymddr[kt"THEN31500
12070 IFp=59ANDno$="Aurora"THEN33350
12080 PRINT"{green}Okay.":GOSUB18000
12090 ob%(i)=p:g=g-1:GOTO5000
12300 IFno$="Aurora"THENGOSUB19000:PRINT"{reverse on}{yellow}Du m]ste skoja{!*3}":GOTO190
12305 IFno$="Victor"THENhr=2:GOTO11280
12310 IFp=24THEN13000
12320 IFp=28THEN12500
12330 IFp=74THEN13500
12340 IFp=92THEN13700
12350 GOSUB18000:PRINT"{green}Hur d{pound}dar jag "ve$".":GOTO5000
12500 IFve$="skjut"ORve$="tryck"THEN12520
12510 IFob%(8)=-1THENPRINT"{green}Bra. Du anv[nde kniven.":GOSUB18000:GOTO12610
12520 IFob%(7)<>-1THEN12550
12525 GOSUB18000:PRINT"{cyan}Din laserpistol fungerar inte under vat-ten{.*3} ";
12530 PRINT"Du m]ste hitta p] n]got smartare.";
12540 PRINT"Men fort, du b{pound}rjar bli svagare {.*3}":GOTO5000
12550 PRINT"{black}{sh -}len har dig i sitt grepp och kramar digh]rdare ";
12560 PRINT"och h]rdare{.*4} Du b{pound}rjar f{pound}rloramedvetandet{.*3}"
12570 FORm=1TO2000:NEXTm
12580 GOSUB19000:PRINT"{green}{down}H]rda bud!!{space*2}Du [r d{pound}d!!"
12590 PRINT"{down}Du skulle ha skaffat n]got att d{pound}da den med!!"
12600 GOSUB19000:GOTO190
12610 PRINT"{black}{sh -}len [r besegrad och sjunker sakta till sj{pound}botten{.*4}"
12620 GOSUB18000
12630 PRINT"Gl{pound}m inte kristallen{.*3}":ev=2:es=2:rc=0:yy=0:GOTO5000
12700 IFp=24ANDob%(7)=-1ANDno$="laserpistol"THEN13030
12710 IFp=28ANDob%(7)=-1ANDno$="laserpistol"THEN12520
12720 IFp=74ANDob%(7)=-1ANDno$="laserpistol"THEN13510
12730 IFp=92ANDob%(7)=-1ANDno$="laserpistol"THEN13730
12740 IFno$="laserpistol"ANDob%(7)<>-1THENPRINT"{white}Du har inte den!":GOTO5000
12750 GOSUB18000:PRINT"{green}Det hj[lper dig inte.":GOTO5000
12760 IFp=28ANDob%(8)=-1THEN12500
12770 IFno$="kniv"ANDob%(8)<>-1THENPRINT"{white}Du har den inte!":GOTO5000
12780 GOTO12750
12800 IFno$="vatten"ANDNOT(p=69ORp=28)THENGOSUB19000:PRINT"Jag ser inget!!":GOTO5000
12810 IFno$<>"vatten"THEN7810
12820 PRINT"A{h*3}{.*3} Det k[ndes verkligen uppfriskan-de{.*3} Forts[tt nu!!{cm t*9}"
12830 GOTO5000
13000 IFob%(7)=-1THENPRINT"{green}Okay.":GOSUB18000:GOTO13030
13010 IFob%(8)=-1THENPRINT"{white}Du har bara en kniv - det r[cker inte!":GOTO5000
13020 PRINT"{green}Du har inget att d{pound}da den med{.*4}{space*6}{ct p}Vad h[nder nu?":GOTO5000
13030 PRINT"{black}Ormen krossas i ett n[rliggande hus och dammoln virvlas upp ";
13040 PRINT"n[r den krampaktigt vrider sig innan den d{pound}r."
13050 PRINT"{green}Tur att du hade den d[r laserpistolen,{space*2}"n$"!":sv=2:GOTO4320
13300 IFob%(1)=-1ANDno$="rep"THENPRINT"{green}Smart drag "n$"!":GOTO13305
13302 GOTO7865
13305 PRINT"Repet f]ngas av tr[det och du drar dig{space*2}sj[lv upp.":qv=2:GOTO4320
13310 GOSUB19000:PRINT"{yellow}Du hj[lper dig inte p] det s[ttet,"n$".":GOTO5000
13320 PRINT"{green}Du sjunker l[ngre och l[ngre ner{.*3}"
13330 FORm=1TO1000:NEXTm
13340 GOSUB19000:PRINT"Glug{.*3}{space*3}Glug{.*4}Du [r borta!":GOTO190
13500 IFob%(7)=-1THENGOSUB18000:GOTO13540
13510 GOSUB19000:PRINT"{white} {sh +}ven om du skjuter j[ttesnabbt mot bes-ten s] ";
13520 PRINT"studsar dina skott bara mot dess skinn."
13530 PRINT"Vad g{pound}r du nu "n$"?":GOTO5000
13540 PRINT"{green}Det tycks som om du inte har n]got som{space*2}du kan d{pound}da en best av ";
13560 PRINT"den h[r storlekenmed. Jag tror du kan springa ifr]n den{space*2}och ";
13570 PRINT"vara kvar i livet. Problemet [r baraatt komma f{pound}rbi.":GOTO5000
13580 GOSUB35100:PRINT"{clear}{white}Smart drag d[r "n$".{black}"
13590 PRINT"Nu kan du svinga dig genom tr[den och"
13600 PRINT"komma f{pound}rbi. Du kliver ned lite l[ngre{space*2}bort.":dv=2:GOTO4320
13700 IFob%(7)=-1THEN13730
13710 GOSUB18000:PRINT"{green}De [r alldeles f{pound}r m]nga f{pound}r att d{pound}da."
13720 PRINT"F{pound}rs{pound}k med n]got annat, kanska Aurora{space*3}kan hj[lpa dig{.*3}":GOTO5000
13730 GOSUB18000:PRINT"{green}Din laserpistol tar timmar att ladda upp";
13740 PRINT"igen efter striden med dinosauren. Du"
13750 PRINT"m]ste hitta p] n]gonting annat.":GOTO5000
14000 IFob%(6)<>-1THEN14030
14010 PRINT"Du kan inte kyssa henne n[r du har rymd-dr[kt p] dig. Jag trodde ";
14020 PRINT"du visste det. Hon pekar p] sin mun{.*3}":GOTO5000
14030 FORl=0TO24:POKEsc+l,0:NEXTl
14040 POKEl3,3:POKEw3,16:POKEsc+3,3:POKEvo,143:POKEs1,240:POKEsc+4,65
14050 fr=5389:FORt=1TO200:fq=fr+PEEK(sc+27)*225
14060 hf=INT(fq/256):lf=fq-hf*256
14070 POKEl1,lf:POKEh1,hf
14080 NEXTt:POKEl1,0:POKEh1,0
14090 PRINTCHR$(13)
14100 FORt=1TO5
14110 PRINT"{reverse on}{cyan}{up}FANTASTISK{reverse off} {reverse on}MAN{reverse off} {reverse on}{!*3}{reverse off}"
14120 FORm=1TO500:NEXTm
14130 PRINT"{up}{space*18}"
14140 FORm=1TO500:NEXTm
14150 NEXTt
14160 POKEvo,0
14170 PRINT"{green}Det gjorde dig inte bara till en god manutan inv]narna ler nu. ";
14180 PRINT"Du kan rymma med Aurora.":nv=2:pr=2
14190 PRINT"{green}{down}Du m]ste till skeppet och slutf{pound}ra din{space*2}uppgift. ";
14200 PRINT"Gl{pound}m inte att ta Auorora!":GOTO4320
14210 GOSUB18000:PRINT"{yellow}Mm! Sk{pound}nt. Men gl{pound}m inte bort spelet,{space*3}"n$:GOTO4320
15000 POKEbs,11:POKEbc,11:PRINT"{clear}"TAB(13)"{black}{down}{reverse on}Instruktioner{reverse off}"
15010 PRINT"{down}{right*2}{green}Du tr[der in i en v[rld av fantasi och[ventyr med ";
15020 PRINT"din dator som guide. F{pound}r attl{pound}sa det h[r [ventyret";
15030 PRINT" m]ste du ge{space*6}datorn kommandon: ";
15040 PRINT"alltid {cyan}verb{green} och i{space*5}vissa fall ett {cyan}substantiv{green}. ";
15050 PRINT"Till exempel:{light blue}ta laserpistol{green} eller {light blue}kl[ttra tr[d{green}."
15060 PRINT"Du f]r en beskrivning av den position du[r i och ocks] ";
15070 PRINT"riktningen f{pound}r vart du{space*3}kan g]. Du kan bara g] {cyan}norr{green},{cyan}syd{green},";
15080 PRINT"{cyan}{pound}st{green}{space*5}eller {cyan}v[st{green}."
15090 PRINT" Ibland f]r du tillf[lle att ta ett{space*5}f{pound}rem]l som du kan f] ";
15100 PRINT"anv[ndning av{space*5}senare i spelet du kan d] ta det genom{space*2}att ";
15110 PRINT"anv[nda ordet {cyan}'ta'{green}. T.ex.: {cyan}ta prin- sessan{green}.{down}
15120 PRINT"{down}{white}{right}{reverse on} Tryck p] n]gon tangent och forts[tt {reverse off}"
15140 GETa$:IFa$=""THEN15140
15150 PRINT"{clear}{green}Du kanske ocks] {cyan}'sl[pper'{green} eller {cyan}'l[gger'{green}ett objekt vid ";
15160 PRINT"n]got tillf[lle och det{space*2}f{pound}rem]let kommer att finnas kvar i ";
15170 PRINT"posi-tionen och du kan ta upp det om du skul-le beh{pound}va det igen."
15180 PRINT" Speciella tangentbokst[ver kommer att{space*2}spara din tid, till exempel ";
15190 PRINT"{light blue}{reverse on}n{right}o{right}s{green}{reverse off} och {light blue}{reverse on}v{reverse off}{green} kommer att ta dig ";
15200 PRINT"{light blue}norr{green},{right}{light blue}{pound}st{green},{right}{light blue}syd{green} och{space*4}{light blue}v[st{green}."
15210 PRINT"{down}{light blue}{reverse on}i{reverse off}{green} kommer att visa ditt inventarium."
15220 PRINT"{light blue}{reverse on}t{reverse off}{green} kommer att l]ta dig se dig omkring."
15230 PRINT"{light blue}{reverse on}h{reverse off}{green} ger dig (kanske) lite hj[lp {white}!!{green}"
15240 PRINT"{down}Skriv {light blue}instruktioner{green} f{pound}r utskrift av all-m[nna instruktioner."
15250 PRINT"Om du vill spara spelet till kassett s] skriver du {light blue}save{green}."
15260 PRINT"Om du {pound}nskar sluta skriv {light blue}quit{green}."
15280 PRINT"{down}{white}{reverse on}Tryck p] n]gon tangent f{pound}r att forts[tta{reverse off}{green}"
15290 GETa$:IFa$=""THEN15290
15330 PRINT"{clear}{green}N]gra tips:- ":PRINT"{down}{cyan}1.{green} F{pound}rs{pound}k att spara ditt spel ofta."
15340 PRINT"{cyan}2.{green} F{pound}rs{pound}k rita en karta n[r du utforskar{space*3}planeten."
15350 PRINT"{cyan}3.{green} Var nogrann med dina saker eftersom{space*5}du inte kan b[ra ";
15360 PRINT"hur mycket som{space*9}helst."
15370 PRINT"{cyan}4.{green} Om du beh{pound}ver hj[lp, unders{pound}k saker{space*5}n[r du g]r vidare."
15380 PRINT"{cyan}5.{green} Kom ih]g att skriva instruktioner{space*7}n[r du vill ]ter";
15390 PRINT"v[nda till dessa{space*8}sidor."
15400 PRINT"{down}Lycka till i ditt s{pound}kande efter Aurora, och du{.*3} se upp f{pound}r in";
15410 PRINT"f{pound}dingarna!"
15420 PRINT"{down}{white}{reverse on}Tryck 'L' f{pound}r att ]terv[nda till spelet{reverse off}"
15430 GETi$:IFi$<>"l"THEN15430
15440 IFi$="l"THENPRINT"{clear}":RETURN
16000 PRINT"{clear}{down*2}{green}Spola r[tt band till r[tt plats."
16010 INPUT"Tryck {reverse off}RETURN{reverse off}:";q$
16020 OPEN1,1,0,"planet"
16030 INPUT#1,pr,cv,sv,ev,es,qw,dv,nv,fv
16040 INPUT#1,z,n$,m,i,p,n,e,s,w,i$,pi,sp
16050 INPUT#1,ve$,no$,g,p2,np,na,rc,yy,hh,hr
16060 FORi=1TOnt:INPUT#1,ob%(i):NEXTi
16070 FORi=1TOnt:INPUT#1,ob$(i):NEXTi
16080 FORi=1TOnt:INPUT#1,si$(i):NEXTi
16090 CLOSE1
16100 GOSUB35420
16110 PRINT"{clear}":POKEbs,11:POKEbc,11:GOTO4020
17000 PRINT"{clear}{down*2}{black}{sh +}r du s[ker p] att du vill spara":PRINTTAB(15)"ditt spel?"
17010 PRINT"{down}Tryck {reverse on}j{reverse off} or {reverse on}n{reverse off}:"
17020 GETa$:IFa$<>"j"ANDa$<>"n"THEN17020
17030 IFa$="n"THENPRINT"{clear}":GOTO4020
17040 INPUT"{down}Spola r[tt band till r[tt plats,tryck{space*3}{reverse on}RETURN{reverse off}:";q$:r$=CHR$(13)
17050 OPEN1,1,1,"planet"
17060 PRINT#1,pr;r$;cv;r$;sv;r$;ev;r$;es;r$;qv;r$;dv;r$;nv;r$;fv
17070 PRINT#1,z;r$;n$;r$;m;r$;i;r$;p;r$;n;r$;e;r$;s;r$;w;r$;i$;r$;pi;r$;sp
17080 PRINT#1,ve$;r$;no$;r$;g;r$;p2;r$;np;r$;na;r$;rc;r$;yy;r$;hh;r$;hr
17090 FORi=1TOnt:PRINT#1,ob%(i):NEXTi
17100 FORi=1TOnt:PRINT#1,ob$(i):NEXTi
17110 FORi=1TOnt:PRINT#1,)i$(i):NEXTi
17120 CLOSE1
17130 GOSUB35420
17140 PRINT"{clear}":GOTO4020
17500 POKEbs,2:POKEbc,2
17510 PRINT"{clear}":PRINTTAB(5)"{down*5}{reverse on}{pink}{sh +}r du s[ker,"n$" ??":GOSUB19000
17520 PRINTTAB(5)"{down*2}Tryck {reverse on}f{reverse off} f{pound}r att {reverse on}f{reverse off}orts[tta."
17530 PRINTTAB(5)"{down}Tryck {reverse on}a{reverse off} f{pound}r att {reverse on}a{reverse off}vsluta spelet."
17540 GETa$:IFa$<>"f"ANDa$<>"a"THEN17540
17550 IFa$="a"THEN17570
17560 POKEbs,11:POKEbc,11:PRINT"{clear}":GOSUB18000:GOTO4020
17570 POKEbs,14:POKEbc,6:PRINT"{light blue}{clear}Okay.":GOSUB18000:END
18000 FORl=0TO24:POKEsc+l,0:NEXTl
18010 POKEvo,15:POKEa1,17:POKEa2,17:POKEs1,64:POKEs2,64
18020 POKEw1,17:POKEw2,17:POKEh1,17:POKEl1,195:POKEh2,179:POKEl2,6
18030 FORt=1TO100:NEXTt:POKEvo,0
18040 RETURN
19000 FORl=0TO24:POKEsc+l,0:NEXTl
19010 POKEvo,15:POKEa1,17:POKEa2,64:POKEa3,17:POKEs1,128:POKEs2,128:POKEs3,128
19020 POKEw1,33:POKEw2,33:POKEw3,129
19030 POKEh1,189:POKEl1,172:POKEh2,7:POKEl2,233:POKEh3,1:POKEl3,119
19040 FORt=1TO200:NEXTt:POKEvo,0
19050 RETURN
20000 REM 1
20010 GOSUB22050:n=0:e=2:s=11:w=0:GOTO4150
20020 REM 2
20030 PRINT"{black} N[r du tr[nger djupare in f]ngar en{space*4}liten papperslapp din ";
20040 PRINT"uppm[rksamhet. P] en liten hylla i v[ggen finns ett med-{space*2}delande";
20050 PRINT" nedklottlrat i all hast med Au- roras handstil. I det svaga ";
20060 PRINT"ljuset kan{space*2}du bara se orden {pink}[t n{pound}tter{black}."
20070 n=0:e=3:s=12:w=1:GOTO4150
20080 REM 3
20090 PRINT"{black} Allteftersom du g]r l[ngre in i hj[rtatav templet blir det ";
20100 PRINT"fuktigare och v]tt. V[ggarna [r t[ckta med ett illaluktande slem ";
20110 PRINT"som tycks vibrera med ett olycksb]-dande ljus {.*3}"
20120 n=0:e=4:s=13:w=2:GOTO4150
20130 REM 4
20140 PRINT"{black} Det [r mycket m{pound}rkt i templet. Marken{space*2}[r oj[mn och flera ";
20150 PRINT"g]nger snubblar och{space*2}faller du. En passage {pound}ppnar sig i v[s- ter."
20160 n=0:e=0:s=0:w=3:GOTO4150
20170 REM 11
20180 GOSUB22050:n=1:e=12:s=0:w=0:GOTO4150
20190 REM 12
20200 GOSUB22050:n=2:e=13:s=22:w=11:GOTO4150
20210 REM 13
20220 PRINT"{black} I templet [r det f{pound}r m{pound}rkt att se.{space*5}Passager tycks g] ";
20230 PRINT"i olika riktningar.{space*3}Vilken v[r [r b[st ?"
20240 n=3:e=14:s=0:w=12:GOTO4150
20250 REM 14
20260 PRINT"{black} Du [r utanf{pound}r en byggnad som ser ut somett tempel. ";
20270 PRINT"P] marken utanf{pound}r d{pound}rren{space*4}finns n]gra m[rken inristade i ";
20280 PRINT"dammet p]g]ngstigen. Det liknar en pil som pekar v[sterut in i ";
20290 PRINT"templet."
20300 n=0:e=15:s=24:w=13:GOTO4150
20310 REM 15
20320 PRINT"{black} Klottret av rovf]gelsklor g{pound}r dig yr - beredd p] n]nting. ";
20330 PRINT"Men bara stenarna{space*4}st]r op]verkade - ober{pound}rda inf{pound}r din ";
20340 PRINT"{space*3}fruktan. De kanske inte [r d{pound}da utan{space*4}bara sovande."
20350 n=0:e=0:s=25:w=14:GOTO4150
20360 REM 22
20370 GOSUB22050:n=12:e=0:s=0:w=0:GOTO4150
20380 REM 24
20390 PRINT"{black} Du f]r intrycket av att n]gonting ser{space*2}p] dig fr]n skuggorna. ";
20400 PRINT"Du vill skrika i tystnaden, g{pound}ra n]got, f] dig att k[nna att det ";
20410 PRINT"finns liv p] den d{pound}da planeten."
20420 n=14:e=25:s=0:w=0:GOTO4150
20430 REM 25
20440 PRINT"{black} Vinden viner sp{pound}kligt mellan stenv[g-{space*2}garna n[r du g]r ";
20450 PRINT"f{pound}rbi {pound}ppna d{pound}rrar och tomma f{pound}nster. {sh +}r det h[r allt som ]ter-";
20460 PRINT"st]r av civilisationen h[r ?"
20470 n=15:e=26:s=0:w=24:GOTO4150
20480 REM 26
20490 PRINT"{black} Inne i staden undrar undrar du vart du skall se. Om du bara ";
20500 PRINT"kunde hitta en led-tr]d men de kantiga v[ggarna blockerar{space*2}";
20510 PRINT"varje unders{pound}kning fr]nsett en alle som leder v[sterut."
20520 n=0:e=0:s=36:w=25:GOTO4150
20530 REM 28
20540 PRINT"{black} Du [r vid kanten av sj{pound}n. Stenarna i{space*3}vattnet verkar gnistra ";
20550 PRINT"i solskenet som{space*2}om de hade en egen magisk kraft."
20560 n=0:e=0:s=38:w=0:GOTO4150
20570 REM 36
20580 PRINT"{black} H[rifr]n kan du se ganska klart att{space*4}tornen och spirorna ";
20590 PRINT"[r spillror av en{space*3}svunnen tid. Nu {pound}delagda av sina forna{space*2}";
20600 PRINT"inv]nare."
20610 n=26:e=37:s=46:w=0:GOTO4150
20620 REM 37
20630 PRINT"{black} Till sist {pound}verg]r sanden till sm]- och st{pound}rre stenar - ";
20640 PRINT"det m]ste vara utkanten av {pound}knen. Det finns n]gra l]ga buskar{space*3}";
20650 PRINT"med frukter som liknar kokosn{pound}tter vilkah[nger ner fr]n grenarna."
20660 n=0:e=38:s=47:w=36:GOTO4150
20670 REM 38
20680 PRINT"{black} Du [r fortfarande i {pound}knen.I norr kan duse en sj{pound}. I {pound}st ";
20690 PRINT"kan du se att {pound}knen{space*4}forts[tter mot horisonten."
20700 n=28:e=0:s=38:w=37:GOTO4150
20710 REM 42
20720 GOSUB22110:n=0:e=43:s=52:w=0:GOTO4150
20730 REM 43
20740 GOSUB22070:n=0:e=44:s=53:w=42:GOTO4150
20750 REM 44
20760 GOSUB22110:n=0:e=0:s=54:w=43:GOTO4150
20770 REM 46
20780 PRINT"{black} {sh +}ven om du b{pound}rjar bli omt{pound}cknad av{space*5}solens heta str]lar s] ";
20790 PRINT"glimmar det l]ngtborta i horisonten norrut av spiror och torn ";
20800 PRINT"fr]n en stad. Eller [r det bara en h[gring f{pound}r att pl]ga dig??"
20810 n=36:e=37:s=56:w=0:GOTO4150
20820 REM 47
20830 PRINT"{black} N[r du traskar f{pound}rsiktigt {pound}ver den{space*5}br[nnheta sanden kan du ";
20840 PRINT"se tydliga m[r- ken d[r du kraschade med rymdskeppet. Duundrar ";
20850 PRINT"hur du lyckades klara rymdskeppeti landningen."
20860 n=37:e=46:s=57:w=46:GOTO4150
20870 REM 48
20880 PRINT"{black} Du har vandrat i timmar och kan inte sen]got slut p] den ";
20890 PRINT"[ndl{pound}sa sanden. Du in-ser att om du inte ]terv[nder snart s]{space*2}";
20900 PRINT"du att d{pound} av solens heta str]lar."
20920 n=38:e=0:s=0:w=47:GOTO4150
20930 REM 52
20940 GOSUB22070:n=42:e=53:s=62:w=0:GOTO4150
20950 REM 53
20960 PRINT"{black} Du [r i en liten gl[nta bland tr[den.{space*2}Mjuk mossa t[cker ";
20970 PRINT"sluttningarna som lig-ger inb[ddade i tystnaden, stilla vattenoch";
20980 PRINT" du vilar dig en stund innan du fort-s[tter ditt s{pound}kande."
20990 n=43:e=54:s=63:w=52:GOTO4150
21000 REM 54
21010 PRINT"{black} N[r du sl]r dig genom taggiga buskar{space*3}ser du en skymt av en ";
21020 PRINT"{pound}ppning i v[ster -men du vet inte hur du skall ta dig dit."
21030 n=44:e=55:s=64:w=0:GOTO4150
21040 REM 55
21050 PRINT"{black} Du [r bland tr[d grova som hus som tor-nar upp sig mot himlen ";
21060 PRINT"och skymmer so-{space*2}len. Sm] djur springer omkring dig."
21080 PRINT"Tv] g]ngstigar leder djupare in - en mots{pound}der och en mot v[ster."
21090 n=0:e=56:s=65:w=54:GOTO4150
21100 REM 56
21110 PRINT"{black} Du [r vid utkanten av {pound}knen - d[r san- den snart {pound}verg]r till ";
21120 PRINT"buskliknande{space*5}gr[s. V[sterut t[cker den h{pound}ga skogen{space*3}himlen ";
21130 PRINT"som en gr{pound}n matta."
21140 n=46:e=57:s=0:w=55:GOTO4150
21150 REM 57
21160 PRINT"{black} Du [r nu utanf{pound}r ditt rymdskepp. Runt{space*2}dig ligger svedda ";
21170 PRINT"m[rken och f{pound}rkolnade fragment av ditt skepp. Du har kraschat ";
21180 PRINT"i en stor {pound}ken med lila sand."
21190 n=47:e=58:s=67:w=56:GOTO4150
21200 REM 58
21205 IFob%(2)=-1ANDob%(9)=-1THEN33280
21210 IFob%(2)<>-1THEN21240
21220 PRINT"{yellow}Bravo!{space*2}{green}Du har tagit kristallen.":cv=2
21230 PRINT"{yellow}Det [r b[st att l]ta den glida in i kap-seln i kabinen.":GOTO21380
21240 IFpr=2ANDob%(9)=-1THEN21330
21250 IFhh=2THEN21270
21260 IFpr=2ANDob%(9)<>-1THEN21350
21270 PRINT"{black} Du [r i luftventilen."
21280 IFpr=2THEN21380
21290 PRINT"{black}En av rymddr[kterna saknas. P] golvet{space*3}ser du ett litet ";
21300 PRINT"stycke tyg som du k[n- ner igen som en del av den kungliga{space*5}";
21310 PRINT"kl[nningen som prinsessan Aurora bar n[rdu senast s]g henne{.*4}"
21320 GOTO21380
21330 PRINT"{green}Tillbaka med Aurora - jag skulle ta hen-ne in i kabinen och ";
21340 PRINT"ge henne en kopp{space*4}v[lsmakande te !!":GOTO21380
21350 GOSUB19000:PRINT"{green}Du gl{pound}mde {reverse on}ta{reverse off} Aurora i inf{pound}dingsbyn,"
21360 PRINTn$"!"
21370 PRINT"Dumt! Du m]ste g] tillbaka efter henne."
21380 n=0:e=59:s=0:w=57:GOTO4150
21390 REM 59
21400 IFcv=2ANDpr=2THEN33280
21410 IFcv=2ANDpr<>2THEN33400
21420 IFcv=0ANDpr=2THEN33460
21430 PRINT"{black} Du [r i rymdskeppets kabin och kraschenhar t{pound}mt inneh]llet i ";
21440 PRINT"din l]da {pound}ver helagolvet."
21450 IFpr=2THEN21500
21460 PRINT"Du ser [ven sp]r av en strid."
21470 PRINT"{down}{right}{white}*** Prinsessan [r borta!! ***"
21480 PRINT"{black}{down}Luftventilen visar att den har {pound}ppnats{space*2}utifr]n och sedan ";
21490 PRINT"st[ngt igen{.*3}"
21500 n=0:e=0:s=0:w=58:GOTO4150
21510 REM 62
21520 GOSUB22070:n=52:e=63:s=0:w=0:GOTO4150
21530 REM 63
21540 GOSUB22110:n=0:e=64:s=0:w=62:GOTO4150
21550 REM 64
21560 PRINT"{black} Skogen [r alldeles f{pound}r stor f{pound}r dig f{pound}ratt hitta v[gen ut igen ";
21570 PRINT"och du b{pound}rjar{space*3}undra om du n]gonsin kommer att lyckas."
21590 n=54:e=65:s=74:w=63:GOTO4150
21600 REM 65
21610 PRINT"{black} Den [r g]ngstigen tycks leda bort fr]n solen och in i skuggan ";
21620 PRINT"som du aldrig{space*4}trodde fanns i dagsljuset. Bakom dig h{pound}rdu steg";
21630 PRINT" ett kraftigt rasslande som lju- det av stora rovdjur som ";
21640 PRINT"f{pound}rf{pound}ljer dig.":n=55:e=0:s=0:w=64:GOTO4150
21650 REM 67
21660 PRINT"{black} {cm -}knen blir snart lite yppig av gr{pound}n{space*4}vegetation som blir ";
21670 PRINT"t[tare f{pound}r varje{space*4}steg. Det [r b[st att se sig omkring h[r- ";
21680 PRINT"marken b{pound}rjar bli mycket sank."
21690 n=57:e=68:s=0:w=0:GOTO4150
21700 REM 68
21710 PRINT"{black} Du [r i ett tr[skomr]de, mycket varmt{space*2}och otrivsamt. Du kan ";
21720 PRINT"h{pound}ra bruset av en flod som [r ofantlig och v]ldsam."
21730 PRINT"I {pound}ster ligger floden och i v[ster finnstr[sket."
21740 n=0:e=69:s=0:w=67:GOTO4150
21750 REM 69
21760 PRINT"{black} Det [r s] uppfriskande attsitta p]{space*5}flodvallen och dingla ";
21770 PRINT"med dina {pound}mma f{pound}t-ter i det iskalla vattnet. Men floden [rf{pound}r ";
21780 PRINT"vidstr[ckt, som en sj{pound} som str[cker sig mot horisonten. Det ";
21790 PRINT"skulle vara o-{space*2}m{pound}jligt att ta sig {pound}ver dem.":n=0:e=0:s=0:w=68
21795 GOTO4150
21800 REM 74
21810 PRINT"{black} Du [r p] en v[g till s{pound}dra delen av{space*4}skogen. Den j[mna ytan ";
21820 PRINT"ger intryck av{space*3}att v[gen har byggts av en tidigare ci- vilisati";
21830 PRINT"on som varit {pound}verl[gsen varje{space*3}annan civilisation du k[nner till";
21840 PRINT". Men{space*2}anv[nds v[gen fortfarande{.*3} Eller [r{space*3}den bara ett ";
21845 PRINT"minnesm[rke {pound}ver en svunnenstorhetstid?"
21850 n=64:e=0:s=84:w=0:GOTO4150
21860 REM 84
21870 PRINT"{black} V[gen slingrar sig {pound}ver gr[nslandet{space*4}och str[cker sig norrut ";
21880 PRINT"och s{pound}derut som ett v[ldigt band som kastats ner av en{space*2}j[tte. ";
21890 PRINT"P] varje sida omsluts v[gen av{space*3}vegatation {.*3}"
21900 n=74:e=0:s=94:w=0:GOTO4150
21910 REM 92
21920 PRINT"{black} Du [r inne i den smutsiga hyddan. Fleraf{pound}rem]l av primitivt ";
21930 PRINT"lergods krossas un-der dina f{pound}tter.":n=0:e=93:s=0:w=0:GOTO4150
21940 REM 93
21950 PRINT"{black} Du banar v[g genom inf{pound}dingsbyn i hopp om att inv]narna f{pound}rblir";
21960 PRINT" v[nliga.":n=0:e=94:s=0:w=92:GOTO4150
21970 REM 94
21980 PRINT"{black} Du [r utanf{pound}r inf{pound}dingsbyn. Smutsiga{space*3}hyddor [r spridda p] ett";
21990 PRINT" planl{pound}st s[tt."
22000 IFpr<>2THEN22020
22010 GOTO22040
22020 PRINT"Byn verkar vara {pound}delagd, men du kan h{pound}raen kvinna sjunga sorgset ";
22030 PRINT"f{pound}r sig sj[lv{space*2}i en hydda."
22040 n=84:e=0:s=0:w=93:GOTO4150
22050 PRINT"{black} Det [r en s]dan labyrint av g]ngar att du b{pound}rjar bli lite ";
22060 PRINT"r[dd att du [r f{pound}r-{space*2}lorad {.*3}":RETURN
22070 PRINT"{black} Du [r f{pound}rlorad i skogen. Du forts[tter att kasta blickar ";
22080 PRINT"ibland ]t {pound}st, ibland ]t syd{.*3} ";
22090 PRINT"och hela tiden h{pound}r du ekot av ett stort rovdjur och ";
22100 PRINT"l{pound}vverken vibreraromkring dig.":RETURN
22110 PRINT"{black} Vilken skog - den h[r! Du tycks defi-{space*2}nitivt vara f{pound}rlorad. ";
22120 PRINT"Du skulle nog ha{space*2}stannat hemma och aldrig erbjudit Auroraen ";
22130 PRINT"tur i ditt rymdskepp!":RETURN
30000 PRINT"{black}{down}Ut ur ruinerna slingrar sig en gigantiskorm - den [r dubbelt ";
30010 PRINT"s] stor som dig ochblockerar din enda utv[g..":GOTO5000
30500 PRINT"{down}{black}Det [r ganska djupt i vattnet.":RETURN
30510 IFob%(6)<>-1THEN30540
30515 IFev=2THENGOSUB18000:PRINT"{green}Trevlig dag f{pound}r en simtur. Vad nu?":GOTO4320
30520 IFob%(4)<>-1THEN30560
30530 GOTO30590
30540 GOSUB19000:PRINT"{green}Du har tagit av rymddr[kten, eller hur{space*2}"n$"?"
30550 PRINT"Inte illa! Du har drunknat!!":FORm=1TO2000:NEXTm:GOTO190
30560 GOSUB18000:PRINT"{green}Du flyter p] vattnet som en kork. Du be-h{pound}ver ";
30570 PRINT"n]got tungt som g{pound}r att du sjunker";
30580 PRINT"ner f{pound}r att ta kristallen.":GOTO5000
30590 IFob%(2)=-1THENGOSUB18000:PRINT"{green}Trevlig dag f{pound}r en simtur{!*3}":GOTO4320
30610 es=1:PRINT"{black} F{pound}rst sjunker du n[stan ner till kris- tallen. Pl{pound}tsligt ";
30620 PRINT"kommer en gigantisk ]lupp ur djupet och virar sig runt dig."
30630 PRINT"Den b{pound}rjar krama {.*3}"
30640 GOSUB19000:rc=2:q=0:yy=1:GOTO5000
30650 GOSUB18000:PRINT"{green}Besten har f]tt grepp om dig. F{pound}r sv]rt"
30660 PRINT"f{pound}r dig att fly !":GOTO5000
31000 PRINT"{down}{black}Pl{pound}tsligt blir du chockad. Luften [r{space*4}giftig. Om du inte ";
31010 PRINT"g{pound}r n]gonting s] kom-";
31020 PRINT"mer du att d{pound} mycket snart{.*3}"
31030 FORm=1TO5000:NEXTm
31040 PRINT"{white}B{pound}rja t[nka,"n$"!":PRINT"{156}*";
31050 FORl=0TO24:POKEsc+l,0:NEXTl
31060 FORi=1TO30:PRINT"*";
31070 POKEvo,15:POKEa1,41:POKEs1,89:POKEw1,17:POKEh1,56:POKEl1,99
31080 FORt=1TO200:NEXTt:POKEvo,0:POKEa1,0:POKEw1,0:POKEs1,0
31090 NEXTi
31100 PRINTCHR$(13):PRINT"{green}{down}F{pound}r sent!!":PRINT"F{pound}r sent!!":GOTO190
31500 IFp=58THEN12080
31510 IFp=59THEN12080
31520 IFfv<>2THEN31000
31530 IFfv=2THEN12080
31600 IFno$="n{pound}tter"ORno$="frukt"THEN31620
31610 GOSUB19000:PRINT"{white}Urk!{space*2}{yellow}Vill du [ta {reverse on}det{reverse on}?":GOTO5000
31620 IFp=37THENPRINT"Okay,mm! Smakar gott,"n$"!":GOTO31650
31630 IFob%(3)=-1THENPRINT"{green}Okay - smakar gott!":GOTO31650
31640 IFob%(3)<>-1THENGOSUB19000:PRINT"{white}Du har inte n]gra "no$"!":GOTO5000
31650 IFz=1THEN31700
31660 GOSUB35100:PRINT"{clear}":PRINT"{white}Bra drag det d[r,"n$"!"
31670 PRINT" Du k[nner en underlig k[nsla i kroppen - och du kan andas ";
31680 PRINT"utan rymddr[kten."
31690 PRINT"Du kan l[mna den h[r.":ob%(3)=0:z=1:fv=2:g=g-1:GOTO5000
31700 GOSUB18000:PRINT"{black}{down}Du k[nner ingen skillnad den h[r g]ngen.";
31710 PRINT"{sh +}nnu hindrar det dig fr]n att k[nna{space*5}hunger.":ob%(3)=0:GOTO5000
32000 PRINT"{down}{black} Du uppt[cker att energikristallen sak- nas p] energikapseln.";
32010 PRINT" Utan den kan du{space*3}inte flyga med skeppet. Den m]ste ha ta-";
32020 PRINT"gits av n]gon! Du m]ste hitta den innan du kan fly."
32030 RETURN
32070 IFno$="kristall"THEN32090
32080 GOTO11700
32090 IFev=2THEN11700
32100 PRINT"{yellow}Det kan du inte{.*5}";:FORm=1TO500:NEXTm:PRINT"{.*4}[nnu!!"
32110 PRINT"{white}Den [r {reverse on}under{reverse off} vattnet{!*4}":GOTO4320
32500 GOSUB18000:PRINT"{white}I norr ligger en ruinstad - i s{pound}der mer tr[d ";
32510 PRINT"som str[cker sig [nda mot horison- ten. Du kl[ttrar ned.":GOTO4320
32520 GOSUB18000:PRINT"{white}I {pound}st kan du se ditt skepp och sedan [r det bara ";
32530 PRINT"tr[d och mer tr[d {.*3} Du kl[tt-rar ned":GOTO4320
32540 GOSUB1800:PRINT"{white}I s{pound}der kan du se r{pound}k ringla sig upp mothimlen. ";
32550 PRINT"Det m]ste finnas liv h[r av n]- got slag. Du kl[ttrar ned."
32560 GOTO4320
32600 PRINT"{down}{black} Du sjunker ner i kvicksanden. Inom n]g-ra sekunder [r den {pound}ver";
32610 PRINT" dina kn[n. F{pound}r- s{pound}k att komma p] n]got!":q=0:GOTO5000
32700 PRINT"{down}{black} Fr]n tr[den vid sidan av v[gen kommer{space*2}en dinosaur in p] ";
32710 PRINT"din g]ngstig. Du kan{space*2}inte komma f{pound}rbi.":GOTO5000
33000 PRINT"{down}{black} En samling fientliga inf{pound}dingar kommer till hyddan. De ";
33010 PRINT"blockerar din utv[g.{space*4}De r{pound}r sig mot dig med spjut riktade mot";
33020 PRINT"din hals.{space*2}De [mnar g{pound}ra aff[rer,{space*7}"n$"!!":q=0:GOTO5000
33060 PRINT"{black} Tillbaka igen!! Jag hoppas du har t[nktut hur du ska ge Aurora ";
33070 PRINT"kyssen som hj[l-per henne ut."
33080 na=0:q=0:GOTO5000
33120 IFnv<>2ANDno$="Aurora"THEN33170
33130 IFnv<>2ANDno$="prinsessa"THEN33170
33140 IFnv<>2ANDno$="Prinsessa"THEN33170
33150 GOTO11700
33170 GOSUB35100
33180 PRINT"{clear}{yellow}Tyv[rr, "n$".":PRINT"Men inv]narna gillar inte en framfusig"
33190 PRINT"person{!*3} Och de varnade dig att inte{space*3}f{pound}rs{pound}ka ta henne."
33200 PRINT"De har d{pound}dat dig. Det [r s] h[r det g]r.";:GOTO190
33240 PRINT"{black} Utan Aurora kan du inte fullf{pound}lja ditt uppdrag.":RETURN
33280 GOSUB35100
33290 PRINT"{clear}{white}{down*2} Gratulerar!!{space*2}{yellow}Du har lyckats med ditt{space*2}uppdrag!!"
33300 PRINT"{down}Efter bara n]gra timmars arbete kan du{space*2}flyga iv[g ";
33310 PRINT"med ditt rymdskepp och ]ka uti den svarta rymden."
33320 PRINT"{down}Och prinsessan Aurra har best[mt att honinte vill gifta sig ";
33330 PRINT"med den grymme h[rs-skaren av Zen. Hon f{pound}redrar dig,{space*8}";n$
33340 PRINT"Ganska trevligt, eller hur?":POKEv+21,0:END
33350 GOSUB18000:PRINT"{white}{down} Aurora ger dig en kyss innan du ger digiv[g f{pound}r ";
33360 PRINT"att leta efter kristallen.":hh=2:GOTO12090
33400 GOSUB35100:PRINT"{clear}{black} Okay, du har allts] hittat energikris- tallen. ";
33410 PRINT"Det enda du beh{pound}ver g{pound}ra [r att hitta prinsessan."
33420 PRINT"Gl{pound}m inte att l[mna kristallen h[r.":GOTO21500
33460 GOSUB35100:PRINT"{clear}{black}Okay.{space*2}Aurora [r i s[kerhet och du kan"
33470 PRINT"l[mna henne h[r om du vill.":GOTO21500
35000 POKEv+39,2:POKEv+27,1:POKEv+23,1:POKEv+29,1
35010 POKEv+1,100:POKEv,0:POKEv+21,1
35020 FORx=0TO255:POKEv,x:NEXTx:POKEv+16,1
35030 FORx=0TO95:POKEv,x:NEXTx:POKEv+21,0:POKEv+16,0
35040 RETURN
35100 FORl=0TO24:POKEsc+l,0:NEXTl
35110 POKEvo,15:POKEa1,190:POKEa2,190:POKEa3,190:POKEw1,33:POKEw2,33:POKEw3,129
35120 POKEh1,75:POKEl1,69:POKEh2,212:POKEl2,230:POKEh3,1:POKEl3,123
35130 FORm=1TO200STEP.25:NEXTm
35140 POKEv+40,4:POKEv+29,2:POKEv+23,2
35150 POKEv+2,80:POKEv+3,0:POKEv+21,2
35160 FORy=0TO190:POKEv+3,y:NEXTy
35170 POKEw1,0:POKEa1,0:POKEw2,0:POKEa2,0:POKEw3,0:POKEa3,0
35180 RETURN
35200 DATA99999
35240 DATA255,128,0,255,128,0,1,128,0,1,128
35250 DATA0,3,252,0,31,255,224,255,252,32,63
35260 DATA252,63,63,255,255,224,0,1,63,255,240
35270 DATA63,255,240,3,1,0,3,25,0,3,31
35280 DATA0,227,0,0,255,0,0,0,0,0,0
35290 DATA0,0,0,0,0,0,0,0,0
35330 DATA0,112,0,0,248,0,1,252,0,1,172
35340 DATA0,1,172,0,3,254,0,3,222,20,1
35350 DATA116,20,1,4,28,1,252,8,0,112,8
35360 DATA7,255,8,7,255,8,127,255,248,68,1
35370 DATA0,229,253,0,165,253,0,4,1,0,7
35380 DATA255,0,7,255,0,1,36,0
35420 RESTORE:FORll=1TO1000:READa$:IFa$="{9*5}"THENll=10^6
35430 NEXTll
35435 IFPEEK(648)<>4THEN35540
35440 POKE2041,14:POKE2040,13
35450 FORll=0TO126:READq:POKE832+ll,q:NEXTll
35460 RESTORE
35470 RETURN
35540 POKE52216,4:POKE52217,5
35550 FORll=0TO126:READq:POKE49408+ll,q:NEXTll
35560 RESTORE
35570 RETURN
60000 PRINT"initierar svenska tecken";
60002 READq$:PRINT".";:IFq$<>"swe"THEN60002
60005 READy:PRINT".";:IFy<0THEN60015
60010 POKE49152+a,y:s=s-y*(a<178):a=a+1:GOTO 60005
60015 IFs-23434THENPRINT"fel i data{!*5}":END
60020 RETURN
60025 DATAswe
60035 DATA120,169,51,133,1,160,0,185
60040 DATA0,208,153,0,240,200,208,247
60045 DATA238,9,192,238,12,192,208,239
60050 DATA169,208,141,9,192,169,240,141
60055 DATA12,192,169,55,133,1,32,45
60060 DATA192,88,76,68,229,173,2,221
60065 DATA9,3,141,2,221,173,0,221
60070 DATA41,252,141,0,221,169,200,141
60075 DATA136,2,169,45,141,24,208,169
60080 DATA8,133,44,32,139,192,169,89
60085 DATA141,24,3,169,192,141,25,3
60090 DATA96,72,138,72,152,72,169,127
60095 DATA141,13,221,32,188,246,32,225
60100 DATA255,32,163,253,32,24,229,160
60105 DATA3,185,48,253,153,20,3,136
60110 DATA16,247,160,25,185,54,253,153
60115 DATA26,3,136,16,247,32,45,192
60120 DATA108,2,160,160,23,185,178,192
60125 DATA153,216,240,153,216,250,73,255
60130 DATA153,216,244,153,216,254,136,16
60135 DATA236,160,23,185,202,192,153,216
60140 DATA248,73,255,153,216,252,136,16
60145 DATA242,96
60155 DATA102,24,60,102,126,102,102,0
60160 DATA102,60,102,102,102,102,60,0
60165 DATA60,102,60,102,126,102,102,0
60170 DATA102,0,60,6,62,102,62,0
60175 DATA102,0,60,102,102,102,60,0
60180 DATA60,102,60,6,62,102,62,0,-1
stop tok64
(bastext 1.1)